[..] Tableau dans GUI

[ricky]

Hello,

j'ai besoin de votre aide.

J'aimerais afficher un tableau deux dimensions dans une gui. Ensuite sélectionner une entrée et si je presse sur un bouton ça va supprimer cette entrée dans le tableau (donc avec décalage de tous les valeurs en dessous). Qqn aurait un peu de temps pour me montrer ça?

Le tableau contient 3 colonnes, mais il n'y a que les deux premières et avec des entêtes tout en haut.

Merci d'avance pour votre aide!

[mikell]

Comme je ne sais pas exactement ce que tu veux dire par 'tableau 2 dimensions', voilà un script qui affiche un tableau 2D (array) dans un tableau (listview)
Les handles des items de listview sont définis dans une array, c'est plus simple à manipuler

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <ListviewConstants.au3>
#include <Array.au3>

Dim $array[3][3] 
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1" 
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)

Dim $ligne[3]
$ligne[0] = GUICtrlCreateListViewItem("(1)|" &$array[0][1] & "|" & $array[0][2], $listview)
GUICtrlSetImage(-1, @Autoitexe, -1)  
$ligne[1] = GUICtrlCreateListViewItem("(2)|" &$array[1][1] & "|" & $array[1][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -132)
$ligne[2] = GUICtrlCreateListViewItem("(3)|" &$array[2][1] & "|" & $array[2][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -138)
$vire = GuiCtrlCreateButton("supprime", 200, 145, 80, 25)
GUISetState()

While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
        Exit
    Case $vire
        $index = ControlListView($gui, "", $listview, "GetSelected")
        GUICtrlDelete($ligne[$index])
        _ArrayDelete($ligne, $index)
EndSwitch
Wend
 

[legend]

voici un exemple :

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <Array.au3>
GUICreate ("lol")
dim $array[10][2] = [[1, 2], [2, 3], [3, 4], [4, 5], [4, 5], [4, 5], [4, 5], [4, 5]]
dim $array2[10][2]
for $i1 = 0 to UBound ($array) -1
    for $i2 = 0 to UBound ($array, 2) -1
        $array2[$i1][$i2] = GUICtrlCreateButton ($array[$i1][$i2], $i2 * 30, $i1 * 30, 30, 30)
    Next
Next
GUISetState ()
sleep (3000)
GUICtrlSetBkColor ($array2[4][1], 0x323323)
sleep (3000)

avec les évènement de gui et a partir de l'exemple tu pourra créer ce que tu veut.
si tu y arrive pas. je le ferais
bonne journée.

[mikell]

@legend

voici un exemple ... etc

Ah bon ? et un exemple de quoi précisément ?
Tu as lu au moins ce qu'il demande ricky ?
"afficher un tableau deux dimensions dans une gui. Ensuite sélectionner une entrée et si je presse sur un bouton ça va supprimer cette entrée dans le tableau"
Alors c'est quoi ton machin qui ressemble à rien ?

avec les évènement de gui et a partir de l'exemple tu pourra créer ce que tu veut.

Il pourra créer que dalle, oui ^^
Tu es sûr que tu t'es pas trompé de sujet ? ou de forum ? parce que ici c'est les demandes de scripts, et on est censé répondre avec un minimum d'exactitude et de précision au cahier des charges du demandeur...

[legend]

en effet, j'avais compris qu'il voulait supprimer une case et non pas une ligne et cela n'est pas très pratique utilisant une listview. (j'ai mal interprété le règlement d'après ce qu'il parait :p)
sinon j'ai codé cela dans un projet ou j'avais besoin de colorer quelques cases
je vais compléter le code pour te montrer ce que ça donne.

EDIT : code ajouté

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <Array.au3>

Dim $array[10][2] = [[1, 2],[2, 3],[3, 4],[4, 5],[4, 5],[4, 5],[4, 5],[4, 5]]
Dim $array2[10][2]

GUICreate("lol")

For $i1 = 0 To UBound($array) - 1
    For $i2 = 0 To UBound($array, 2) - 1
        $array2[$i1][$i2] = GUICtrlCreateButton($array[$i1][$i2], $i2 * 30, $i1 * 30, 30, 30)
    Next
Next

GUISetState()
While 1
    Sleep(30)
    $msg = GUIGetMsg()
    For $i1 = 0 To UBound($array) - 1
        For $i2 = 0 To UBound($array, 2) - 1
            If $msg = $array2[$i1][$i2] Then
                GUICtrlSetBkColor($array2[$i1][$i2], 0x323323)

                For $i_1 = 0 To UBound($array) - 1
                    For $i_2 = 0 To UBound($array, 2) - 1
                        GUICtrlDelete($array2[$i_1][$i_2])
                    Next
                Next


                for $i__1 = $i1 To UBound ($array)-2
                    $array[$i__1][$i2] = $array[$i__1 +1][$i2]
                Next
                $array[9][$i2] = ""


                For $i1 = 0 To UBound($array) - 1
                    For $i2 = 0 To UBound($array, 2) - 1
                        $array2[$i1][$i2] = GUICtrlCreateButton($array[$i1][$i2], $i2 * 30, $i1 * 30, 30, 30)
                    Next
                Next



            EndIf
        Next
    Next
WEnd





 

[ricky]

@legend : merci pour ton exemple, mais ça ne rentre pas dans ma demande. Car j'ai deux valeur à afficher.

@mikell : merci pour ton exemple, il marche super bien. Il manquait cette ligne _ArrayDelete($array, $index) pour que ça supprime aussi la ligne dans le tableau. Mais c'est parfait.

Je continue mes tests, c'est difficile d'en faire avec avec des cases à cocher et d'en supprimer plusieurs à la fois?

[mikell]

Non pas difficile

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <GuiListview.au3>
#include <Array.au3>

Dim $array[4][3]
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1"
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"
$array[3][1] = "ligne 4, colonne 1"
$array[3][2] = "ligne 4, colonne 2"

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130, -1, $LVS_EX_CHECKBOXES)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)

Dim $ligne[4]
$ligne[0] = GUICtrlCreateListViewItem("(1)|" &$array[0][1] & "|" & $array[0][2], $listview)
GUICtrlSetImage(-1, @Autoitexe, -1)  
$ligne[1] = GUICtrlCreateListViewItem("(2)|" &$array[1][1] & "|" & $array[1][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -132)
$ligne[2] = GUICtrlCreateListViewItem("(3)|" &$array[2][1] & "|" & $array[2][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -138)
$ligne[3] = GUICtrlCreateListViewItem("(4)|" &$array[2][1] & "|" & $array[2][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -166)
$vire = GuiCtrlCreateButton("supprime", 200, 145, 80, 25)
GUISetState()

While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
        Exit
    Case $vire
    $count = ControlListView($gui, "", $listview, "GetItemCount")
    For $index = 0 To $count-1
      If _GUICtrlListView_GetItemChecked($listview, $index) Then
            GUICtrlDelete($ligne[$index])
            _ArrayDelete($ligne, $index)
      EndIf
    Next
EndSwitch
Wend
 

[ricky]

merci, mais il y a un petit soucis, si j'en sélectionne 2, ça marche pas à tous les coups.

[mikell]

Hmpf 2 erreurs d'inattention

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <GuiListview.au3>
#include <Array.au3>

Dim $array[4][3]
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1"
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"
$array[3][1] = "ligne 4, colonne 1"
$array[3][2] = "ligne 4, colonne 2"

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130, -1, $LVS_EX_CHECKBOXES)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)

Dim $ligne[4]
$ligne[0] = GUICtrlCreateListViewItem("(1)|" &$array[0][1] & "|" & $array[0][2], $listview)
GUICtrlSetImage(-1, @Autoitexe, -1)  
$ligne[1] = GUICtrlCreateListViewItem("(2)|" &$array[1][1] & "|" & $array[1][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -132)
$ligne[2] = GUICtrlCreateListViewItem("(3)|" &$array[2][1] & "|" & $array[2][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -138)
$ligne[3] = GUICtrlCreateListViewItem("(4)|" &$array[3][1] & "|" & $array[3][2], $listview)    [color=#FF0000]; <<<<<<<<<<<[/color]
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -166)
$vire = GuiCtrlCreateButton("supprime", 200, 145, 80, 25)
GUISetState()

While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
        Exit
    Case $vire
    $count = ControlListView($gui, "", $listview, "GetItemCount")
    For $index = $count-1 To 0 step -1   [color=#FF0000] ; <<<<<<<<<[/color]
      If _GUICtrlListView_GetItemChecked($listview, $index) Then 
         GUICtrlDelete($ligne[$index])
            _ArrayDelete($ligne, $index)
      EndIf
    Next
EndSwitch
Wend
 

[ricky]

Il y avait une petite erreur, dans la boucle For $index = $count si tu mets -1, ça va poser des problèmes.

[mikell]

$count = 4
$ligne[4] n'existe pas
La boucle For doit aller pour l'index de 3 à 0 step -1
La preuve :

Code : Tout sélectionner

    $count = ControlListView($gui, "", $listview, "GetItemCount")
    For $index = $count To 0 step -1
      Msgbox(0,"", $ligne[$index])  [color=#FF0000]  ; <<<<<<<<<<[/color]
      If _GUICtrlListView_GetItemChecked($listview, $index) Then 
         GUICtrlDelete($ligne[$index])
            _ArrayDelete($ligne, $index)
            _ArrayDelete($array, $index)
    EndIf
    Next
 

[ricky]

Ah oui, mais moi je commence à la ligne 1, c'est pour ça! Je n'ai pas le soucis.

[mikell]

C'est une question de principe
" For $index = $count+17 To 0 step -1 " dans le script ça marche aussi

[ricky]

J'aimerais utiliser la de surligner chaque ligne différemment avec ceci : $GUI_BKCOLOR_LV_ALTERNATE

Mais comment le configure, je comprends pas!!!

[mikell]

► Afficher le texte

Code : Tout sélectionner

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130, -1, $LVS_EX_CHECKBOXES)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)
GUICtrlSetBkColor($listview, 0xaaffff) 
GUICtrlSetBkColor ($listview, $GUI_BKCOLOR_LV_ALTERNATE)

Dim $ligne[4]
$ligne[0] = GUICtrlCreateListViewItem("(1)|" &$array[0][1] & "|" & $array[0][2], $listview)
GUICtrlSetImage(-1, @Autoitexe, -1)  
$ligne[1] = GUICtrlCreateListViewItem("(2)|" &$array[1][1] & "|" & $array[1][2], $listview)
GUICtrlSetBkColor(-1, 0x00ff00) 
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -132)
$ligne[2] = GUICtrlCreateListViewItem("(3)|" &$array[2][1] & "|" & $array[2][2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -138)
$ligne[3] = GUICtrlCreateListViewItem("(4)|" &$array[3][1] & "|" & $array[3][2], $listview)
GUICtrlSetBkColor(-1, 0xff0000) 
GUICtrlSetImage(-1, @SystemDir & "\shell32.dll", -166)
$vire = GuiCtrlCreateButton("supprime", 200, 145, 80, 25)
GUISetState()
 

[ricky]

Ca marche bien.

Comment dois-je faire pour vider le treeview? En pressant par exemple sur un bouton, je le vide.

Merci d'avance pour votre aide

[mikell]

Toujours avec le même type de code

Code : Tout sélectionner

Case $viretout_btn
    $count = ControlListView($gui, "", $listview, "GetItemCount")
    For $index = $count-1 To 0 step -1
          GUICtrlDelete($ligne[$index])
    Next

[ricky]

Effectivement, c'était simple.

J'y avais pas pensé. Je cherche trop loin.

Encore une petite question, est-il possible que sur une longue liste on dise au programme de descendre l'ascenseur pour que la dernière entrée soit visible?

[mikell]

Pas testé mais ça devrait marcher ^^

Code : Tout sélectionner

$count = ControlListView($gui, "", $listview, "GetItemCount")
GUICtrlSendMsg($listview, $LVM_SCROLL, 0, $count*16)