[R] Un problème de compte à rebours

[B0B]

Bonjour à tous, j'ai posté, plus tôt dans la journée un autre post sur lequel j'ai été très bien aidé et je remercie encore les deux personnes concernées mais j'ai ENCORE deux autres problèmes:
Voici donc mon code:

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.0.0
 Author:         [BoB]

 Script Function:
    Meteo

#ce ----------------------------------------------------------------------------
#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>

$oIE = _IECreate ("http://www.valdisere.com/fr/val_d_isere/meteo/meteo.php", 0, 0)
$txt = _IEBodyReadText($oIE)

Acceuil()

Func Acceuil()

    GuiCreate("Bonjour!", 900,550,0,0)

    GUICtrlCreateLabel($txt, 10,10,880,450,$WS_BORDER)

    GUISetFont(11,400,4,"Arial Black")
    $quit=GUICtrlCreateButton("QUITTER MAINTNANT",350,500,200)

    $Rebourd = 15

GUISetState()

    While 1
        GUICtrlCreateLabel($Rebourd,440,460)
        $Rebourd=$Rebourd-1
        Sleep(1000)

        If $Rebourd=0 Then
            Exit
        EndIf

        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                Exit
            Case $msg = $quit
                Exit

        EndSelect
    WEnd
EndFunc

1ère question:
Pourquoi je ne peut pas quitter à l'aide de la croix ou du bouton pourvu du même effet?


2ème question:
Comment puis-je supprimer les 5 premières lignes de texte qui s'affichent et n'apportent aucune info importante pour la météo?

[Tlem]

Bonsoir,
Je vous conseil de regarder attentivement votre code et les exemples de construction d'interface graphique. Vous commettez une erreur de base avec la boucle principale.

Quand à la deuxième question, déjà pour commencer, sur ce forum on essaye d'avoir qu'une seule question par sujet afin de s'y retrouver plus facilement, mais en plus vous posez aussi une question de base dont vous aurez rapidement la question en consultant la documentation et/ou le forum.

Bonne soirée.

[sylvanie]

1) Vous gérez votre compte à rebours dans la même boucle While qui est censée gérer les évènements de la fenêtre.
Du coups quand vous arrivez sur le sleep(1000), ce dernier le script pendant 1 seconde, ainsi que tous les messages de la GUI (dont la fermeture, et les l'autre bouton censé faire la même chose). Il faut géré ce compte à rebours par un Adlibregister qui va lancer une fonction à intervalle régulier parallèlement (ou presque ... il ne faut pas faire de gros traîtement). Ensuite pour updater l'affichage de votre label, utilisez guictrlsetdata sur le contrôle du label au lieu de passer votre temps à le recréer. Quand la cuisine est sale, généralement on la nettoie, on ne la refait pas à neuf à chaque fois ...

2) je parse le texte jusqu'à trouver a chaîne "| FRANçais" et je supprime tout ce que j'ai trouvé. Pour l'explication de l'expression régulière, je vous laisse lire les différents posts consacrées à ces dernières.

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.0.0
 Author:         [BoB]

 Script Function:
    Meteo

#ce ----------------------------------------------------------------------------
#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>

$oIE = _IECreate ("http://www.valdisere.com/fr/val_d_isere/meteo/meteo.php", 0, 0)
$txt = _IEBodyReadText($oIE)
$txt=StringRegExpReplace($txt,"(?s).+\|\s+FRAN.AIS","")
$Rebourd=15
Dim $Label_rebourd=0
Acceuil()

Func Acceuil()

    GuiCreate("Bonjour!", 900,550,0,0)

    GUICtrlCreateLabel($txt, 10,10,880,450,$WS_BORDER)

    GUISetFont(11,400,4,"Arial Black")
    $quit=GUICtrlCreateButton("QUITTER MAINTNANT",350,500,200)
    $Label_rebourd=GUICtrlCreateLabel($Rebourd,440,460)

AdlibRegister("Update_compteur",1000)

GUISetState()

    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                Exit
            Case $msg = $quit
                Exit

        EndSelect
    WEnd
EndFunc

Func Update_compteur()
    $Rebourd=$Rebourd-1
    GUICtrlSetData($Label_rebourd,$Rebourd)
    If $Rebourd=0 Then Exit
EndFunc
 

[mikell]

Pour l'explication de l'expression régulière, je vous laisse lire les différents posts consacrées à ces dernières.

ARF le salaud

[B0B]

Un grand merci à tous!!!

[mikell]

Tiens, autant que tu profites de mes balbutiements désespérés en matière d'expressions régulières

Code : Tout sélectionner

$oIE = _IECreate ("http://www.valdisere.com/fr/val_d_isere/meteo/meteo.php", 0, 0)
$txt = _IEBodyReadText($oIE)
$txt = StringRegExpReplace($txt,"(?s).+\sACC.S\s", "")  
$txt = StringRegExpReplace($txt,"(?s)>\sFORF.+", "")
$txt = StringReplace($txt, @crlf&@crlf, @crlf)
Msgbox(0,"", $txt)

EDIT pour ces sacrées regexp

[B0B]

Merci beaucoup!! Et je viens de créer un post afin de demander la création d'un toto sur le parsage de texte!