[..] Webcam Snap

[TommyDDR]

Bonjour,

Je cherche récupérer une image de la webcam mais sans passer par un fichier, je veux récupérer un bitmap ou un handle de bitmap

J'utilise l'UDF Webcam.au3 mais il me permet seulement de prendre une image en l'enregistrant dans un fichier (http://www.autoitscript.com/forum/topic ... ebcam-udf/)

Merci.

[moi]

est ce que l'UDF sur le forum us et le meme que celui poster sur ce forum?

[Tlem]

A première vue, _WebcamOpen() permet l'overlay de l'image dans une GUI, donc on peut imaginer une GUI 'non visible' et la capture de l'image directement à partir de cette GUI.
Par contre, comme la GUI serait 'non visible', je ne suis pas du tout persuadé que cela fonctionne.

Une autre solution, serait de ce procurer la doc complète de avicap32.dll et de voir si il est possible de faire ce que vous souhaitez directement par la dll. Peut être qu'en reprenant la fonction _WebcamSnap(), il serait possible de remplacer

Code : Tout sélectionner

DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", [color=#FF0000]$WM_CAP_FILE_SAVEDIBA[/color], "int", 0, "str", $sFile)

par la sauvegarde en mémoire.

[mikell]

La liste n'est pas très encourageante (WM_CAP_GRAB_FRAME_NOSTOP ?)
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Heu ne pratiquant pas la webcam, je vais peut-être dire une bêtise, mais pourquoi ne pas utiliser le _ScreenCapture_CaptureWnd qui peut sortir un HBitmap ?

[TommyDDR]

Parce que _ScreenCapture_CaptureWnd va attendre le Handle d'une fenêtre qui doit être visible à l'écran
(Ma fenêtre ne sera pas visible)

Pour WM_CAP_GRAB_FRAME_NOSTOP, c'est ce qu'il se passe déjà pour le _Webcam_Snap de l'UDF, (associé à une écriture dans un fichier) si j'ai bien compris, WM_CAP_GRAB_FRAME_NOSTOP va mettre l image actuelle dans un buffer, il faudrait avoir accès à ce buffer...

Je vais me pencher de ce coté.

Edit : Voila ce que j'ai trouvé :
Avec $WM_CAP_SET_CALLBACK_FRAME, je peux mettre une fonction de callback à chaque frame.
J'ai donc créé la fonction dans Webcam.au3 :

Code : Tout sélectionner

Func _WebcamSetCallBackFram($sId, $func)
    $CallBack   = DllCallbackRegister($func, "long", "int;ptr;ptr;ptr")
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_SET_CALLBACK_FRAME, "int", 0, "lparam", DllCallbackGetPtr($CallBack))
    If(@error) Then
        ToolTip("erf")
    EndIf
EndFunc

Je mets ensuite la ligne dans mon code :

Code : Tout sélectionner

_WebcamSetCallBackFram($camera, "frameCallBack")

et la fonction :

Code : Tout sélectionner

Func frameCallBack($Hwnd, $param1, $param2, $param3)
EndFunc

Je ne suis pas sur du "int;ptr;ptr;ptr".
D'apres msdn ca aurai plutot été "int;videohdr" mais videohdr n'existant pas, j'ai du tatoner...

Quoi qu'il en soit, ma fonction est bien appelée à chaque frame généré, j'ai 4 parametres :
Le handle de la fenetre et 3 pointeurs (et oui, je ne sais toujours pas à quoi ils vont me servir)
J'ai essayé des fonctions GDI plus en pensant que ça seraient des hBitmap ou autre mais en vain.

Ô grand Tlem, puissiez vous me venir en aide.

[matwachich]

ça: http://msdn.microsoft.com/en-us/library ... s.85).aspx nous mène à
ça: http://msdn.microsoft.com/en-us/library ... s.85).aspx

Dans le dernier lien, je suis sur que LPBYTE lpData a quelque chose à voir avec la fonction _GDIPlus_BitmapLock

Après ça... trop fatigué ce soir pour tatoner! je verrais peut être demain

[matwachich]

Voila ce que j'ai fais, mais ça marche pas, et je crois savoir ou est le problème:
C'est qu'il faudrait traduire cet Structure en une chaine compréhensible par DllStructCreate

Code : Tout sélectionner

typedef struct videohdr_tag {
  LPBYTE    lpData;
  DWORD     dwBufferLength;
  DWORD     dwBytesUsed;
  DWORD     dwTimeCaptured;
  DWORD_PTR dwUser;
  DWORD     dwFlags;
  DWORD_PTR dwReserved[4];
} VIDEOHDR, *PVIDEOHDR, *LPVIDEOHDR;

► Afficher le texte

Code : Tout sélectionner

#include <perso\WebCam.au3>

$gui = GuiCreate("test", 640, 480)
$cap = _WebCam_Open($gui, 0, 0, 640, 480) 
_Webcam_SetCallBackFram($cap, "frameCallBack")
;ConsoleWrite($gui & @CRLF)
;ConsoleWrite($cap & @CRLF)

Sleep(2000)
DllCall($WM_CAP_USER_DLL, "int", "SendMessage", "hWnd", $cap, "int", $WM_CAP_GRAB_FRAME_NOSTOP, "int", 0, "int", 0)
Sleep(2000)

Func frameCallBack($Hwnd, $param1);, $param2, $param3)
    ConsoleWrite($Hwnd & @CRLF)
    ConsoleWrite($param1 & @CRLF)
    $videohdr_tag = "LPBYTE lpData;DWORD dwBufferLength;DWORD dwBytesUsed;DWORD dwTimeCaptured;DWORD_PTR dwUser;DWORD dwFlags;DWORD_PTR dwReserved[4]" ; <=== Problème!
    $struct = DllStructCreate($videohdr_tag, $param1)
    $byte = DllStructGetData($struct, 1)
    $struct = 0
    ConsoleWrite($byte & @CRLF)
    ConsoleWrite("Len: " & BinaryLen($byte) & @CRLF)
EndFunc

Func _Webcam_SetCallBackFram($sId, $func)
    Local $CallBack = DllCallbackRegister($func, "long", "HWND;ptr")
    DllCall($WM_CAP_USER_DLL, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_SET_CALLBACK_FRAME, "int", 0, "lparam", DllCallbackGetPtr($CallBack))
    ;If(@error) Then
    ;   ToolTip("erf")
    ;EndIf
EndFunc

[RL77LUC]

Ma solution va peut-être paraître barbare, mais néanmoins je ne vois pas trop d’inconvénients à son utilisation : Il suffit d'enregistrer l'image dans les fichiers temporaires, de l'afficher dans une GUI (ou où vous voulez) et de la supprimer.

[Tlem]

TommyDDR à préciser qu'il ne souhaitait pas passer par un fichier.
Pourquoi lui proposer quelque chose qu'il connait déjà !!!

PS @TommyDDR : J'ai fouiller pas mal, mais rien trouvé qui permet de passer les infos ailleurs que par un fichier. Peut probablement lié à la dll.
Il faudrait sans doute utiliser une autre dll qui intègre une fonction de transfert des données vers autre chose qu'un fichier.

[TommyDDR]

Merci Tlem, j'ai aussi chercher par la DLL mais en vain.

[Jerome]

Coucou,


Peut - être une piste pour toi, je travaille actuellement sur des caméra IP et à récupérer le flux vidéo.


Je pense que pour ta webcam, c'est un peu la même chose (même si c'est différent )


Regarde du côté de l'ActiveX, tu auras peut - être un début de piste.

?



Jérôme

[Ghost911]

bonjour tout le monde quelqu'un a trouver une solution a se problème ? je cherche la même chose mettre l'image de webcam dans un buffer sans fichiers temporaires !

[TommyDDR]

Je me suis repenché sur la question, ce fut un long périple, le code de matwachich m'a mis sur la piste

J'ai le plaisir de vous informer que... J'ai réussi !!!

@matwachich : en fait, la donnée lpdata était un pointeur vers les octets représentant les couleurs de l'image et de taille dwBufferLength (ouch ^^), j'ai donc du faire une fonction CreateBmpByPixels qui permet de transformer ces couleurs non exploitables (en tout cas je ne sais pas les exploiter comme ça) en une structure BMP.
C'est la que l UDF Bitmap_String.au3 nous sauve

Seul inconvénient, il faut connaitre la taille de l'image par avance, mais je crois que pour toutes les webcam c'est 320*240

EDIT : Au temps pour moi, je viens de faire un test avec une autre webcam... 640*480
Je vais voir comment récupérer la résolution.

EDIT Bis : Et voila, j'ai ajouté _WebcamGetResolution($CamID) qui renvoit un tableau de 2 cases [TailleX, $TailleY]

Attention, si vous laissez

Code : Tout sélectionner

DllCall($user, "int", "SendMessage", "hWnd", $cap[0], "int", $WM_CAP_SET_PREVIEWRATE, "int", 1, "int", 0)

Dans le _WebcamOpen, alors votre callback sera appelé en boucle (parce que le PREVIEWRATE créé des frame et donc le callback est appellé)

► Afficher le texteExemple

Code : Tout sélectionner

(Voir plus bas)

Je vous met aussi à disposition les 2 includes nécéssaires :
Bitmap_String.au3 (disponible sur le forum US mais je ne retrouve plus le lien)
Webcam.au3 (modifié) (Voir plus bas)

[TommyDDR]

Je post un nouveau message pour pas mettre plus le bor**l que ça dans mon précédent post ^^'.

J'ai finalement fait plusieurs tests... certaines webcam font des compressions et... je ne vois pas du tout comment gérer ça.

Je vous met à disposition là où je suis rendu (fonctionne très bien si biCompression = 0) sinon, je force la compression (seulement l'entête du fichier) à 0 pour avoir un pseudo rendu (les formes apparaissent mais les couleurs ne sont pas bonnes et l'image est retournée (le haut est en bas).

Si une âme charitable passe par ici... je suis preneur.

► Afficher le texteExemple

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include "Bitmap_String.au3"
#include "PixelsToBmp.au3"
#include "Webcam.au3"

Opt("GUIOnEventMode", 1)

Global $GuiCam
Global $GuiInterception
Global $camera
Global $Frame

HotKeySet("²", "snap")


_GDIPlus_Startup()
$GuiCam = GUICreate("GUICamera", 320, 240)
GUISetState()

$GuiInterception = GUICreate("GUI interception frames", 320, 240)
$Frame = GUICtrlCreatePic("", 0, 0, 320, 240)
GUISetState()

GUISetOnEvent($GUI_EVENT_CLOSE, "quit", $GuiCam)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit", $GuiInterception)

$camera = _WebcamOpen($GuiCam,0,0,320,240)
_WebcamSetCallBackFram($camera, "frameCallBack")

While(True)
    Sleep(10)
WEnd

Func snap()
    _WebcamGetFrame($camera)
EndFunc

Func frameCallBack($Hwnd, $param1)
    Local $videohdr_tag = "PTR lpData;DWORD dwBufferLength;DWORD dwBytesUsed;DWORD dwTimeCaptured;DWORD_PTR dwUser;DWORD dwFlags;DWORD_PTR dwReserved[4]" ; <=== Problème!
    Local $structParam = DllStructCreate($videohdr_tag, $param1)
    Local $lpDatas = DllStructGetData($structParam, 1)
    Local $size = DllStructGetData($structParam, 2)
    Local $structPixels = DllStructCreate("BYTE datas[" & $size & "]", $lpDatas)
    Local $Pixels = DllStructGetData($structPixels, 1)
    Local $structImage = _WebcamGetVideoFormat($camera)
    Local $stringBitmap = CreateBmpByStructBITMAPINFOAndPixels($structImage, $Pixels) ;     <----- Peut être enregistré dans un fichier
;~  Local $file = FileOpen(@DesktopDir & "\ttest.bmp", 18)
;~  FileWrite($file, $stringBitmap)
;~  FileClose($file)
    Local $Bitmap = _BinaryString2Bitmap($stringBitmap) ;               <----- Objet bitmap exploitable
    Local $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($Bitmap)
    _WinAPI_DeleteObject(GUICtrlSendMsg($Frame, 0x0172, 0, $hBitmap))
EndFunc

Func quit()
    _GDIPlus_Shutdown()
    Exit
EndFunc

 

► Afficher le textePixelsToBmp.au3

Code : Tout sélectionner

Func CreateBmpByStructBITMAPINFOAndPixels($structBITMAPINFO, $Pixels)
    Local $NULL = StringLeft(BinaryToString(0), 1)
    Local $EntetreBMP = "BM"
    Local $Size = $NULL & $NULL & $NULL & $NULL
    Local $ChampReserve = $NULL & $NULL & $NULL & $NULL
    Local $PosDebutImage = $NULL & $NULL & $NULL & $NULL

    Local $NumberCompression = DllStructGetData($structBITMAPINFO, 6)
    $NumberCompression = 0 ; On force le 0 pour avoir le pseudo rendu

    Local $TailleEnteteImage = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 1), 8))
    Local $TailleImageW = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 2), 8))
    Local $TailleImageH = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 3), 8))
    Local $NbPlan = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 4), 4))
    Local $Profondeur = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 5), 4))
    Local $Compression =  LittleEndian(Hex($NumberCompression, 8))
    Local $TailleImage =  LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 7), 8))
    Local $ResolutionHoriz = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 8), 8))
    Local $ResolutionVert = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 9), 8))
    Local $NbCouleurPalette = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 10), 8))
    Local $NbCouleurImportantes = LittleEndian(Hex(DllStructGetData($structBITMAPINFO, 11), 8))

    $PosDebutImage =    BinaryLen($EntetreBMP) + _
                            BinaryLen($Size) + _
                            BinaryLen($ChampReserve) + _
                            BinaryLen($PosDebutImage) + _
                            BinaryLen($TailleEnteteImage) + _
                            BinaryLen($TailleImageW) + _
                            BinaryLen($TailleImageH) + _
                            BinaryLen($NbPlan) + _
                            BinaryLen($Profondeur) + _
                            BinaryLen($Compression) + _
                            BinaryLen($TailleImage) + _
                            BinaryLen($ResolutionHoriz) + _
                            BinaryLen($ResolutionVert) + _
                            BinaryLen($NbCouleurPalette) + _
                            BinaryLen($NbCouleurImportantes)

    Local $TailleTotal = $PosDebutImage + BinaryLen($Pixels)
    $PosDebutImage = LittleEndian(Hex($PosDebutImage, 8))
    $Size = LittleEndian(Hex($TailleTotal, 8))
    Local $Retour = $EntetreBMP & _
                    $Size & _
                    $ChampReserve & _
                    $PosDebutImage & _
                    $TailleEnteteImage & _
                    $TailleImageW & _
                    $TailleImageH & _
                    $NbPlan & _
                    $Profondeur & _
                    $Compression & _
                    $TailleImage & _
                    $ResolutionHoriz & _
                    $ResolutionVert & _
                    $NbCouleurPalette & _
                    $NbCouleurImportantes & BinaryToString($Pixels)
    Return  $Retour

EndFunc

Func LittleEndian($String)
    Local $Retour = ""
    Local $Taille = StringLen($String)
    If(Mod($Taille, 2) = 0) Then
        For $i = 0 To $Taille-1 Step 2
            $Retour &= StringLeft(BinaryToString(Number("0x" & StringMid($String, $Taille-($i+1), 2))), 1)
        Next
    EndIf
    Return $Retour
EndFunc