[R] Rechercher plusieurs fois une valeur dans un fichier

[jchd]

Que fait là l'incrémentation ($i = $i + 1) juste après le FOR extérieur ?

Quel code erreur renvoie _SQLite_GetTable2d ?
Si OK, que donne un _ArrayDisplay de $rows ?

[ludoo]

voici le code de la requete :

Code : Tout sélectionner

Func ReqBD_BE_1()
$res = _SQLite_GetTable2d($hDb, "select user as [Utilisateur], (select total(pages * copies) from log G where L.user = G.user and g.paper = 'A3') as [Pages A3 imprimées], (select total(pages * copies) from log G where L.user = G.user and g.paper = 'A4') as [Pages A4 imprimées] from log L where printer = "& X($impBE1)&" group by user ;", $rows, $nrows, $ncols)
EndFunc

la 2eme requête est identique a par le nom de l'imprimante
même erreur avec

Code : Tout sélectionner

For $i = 0 to $rows - 1

[ludoo]

le _ArrayDisplay de $rows s'affiche correctement avec les bonnes info.
je voudrai sortir de ce array les informations (user, pages a4, pages a3), peut être que la boucle For n'est à utiliser ?
je récupère la variable user pour l'envoyer ds "$aUser = _AD_GetUserGroups($user)" (UDF Active Directory) qui me donne les groupes AD de cet utilisateur.

[jchd]

Tu as une incrémentation parasite de $i, juste après ton For extérieur.

[ludoo]

oui le

Code : Tout sélectionner

$i = $i +1

, ce qui permet de passer à la ligne suivante du array , sinon il reste bloqué sur la première.
je tourne en rond dessus

[jchd]

On passe tous à côté, moi le premier... Enfin, c'est la myopie traditionnelle à l'oeuvre ! ( For $i = 0 To $nrows - 1)

► Afficher le textetext

Code : Tout sélectionner

Func ResBE()
    Local $user, $aUser, $pageA4, $pageA3, $filegroup, $rFile, $filecount   ; $MatchGroup
    For $i = 0 To $nrows - 1
;~     $i = $i +1
        $user = $rows[$i][0]
        $pageA4 = $rows[$i][2]
        $pageA3 = $rows[$i][1]
        $aUser = _AD_GetUserGroups($user)
        If @error > 0 Then
            MsgBox(64, "Active Directory Functions - Example 1", "User '" & $user & "' has not been assigned to any group")
        Else
            ; For groups that are inherited, the return is the FQDN of the group or user, and the FQDN(s) of the group(s) it
            ; was inherited from, seperated by '|'
            For $j = 1 To $aUser[0]
                $filegroup = FileOpen("groupBE.txt", 1)
                If $file = -1 Then ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< $file ???
                    MsgBox(0, "Error", "Unable to open file.")
                    Exit
                EndIf
                FileWriteLine($filegroup, $aUser[$j] & @CRLF)
                FileClose($filegroup)
            Next
        EndIf
        $filegroup = FileOpen("groupBE.txt", 0)
        While 1
            If $file = -1 Then ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< $file ???
                MsgBox(0, "Error", "Unable to open file.")
                Exit
            EndIf
            $rFile = FileReadLine($filegroup)
            If @error = -1 Then ExitLoop
            $cn = StringSplit($rFile, ",")
            If $cn[1] = "CN=xxxx" Then
                $filecount = FileOpen("countBE.txt", 1)
                FileWriteLine($filecount, $pageA4)
                FileWriteLine($filecount, $pageA3)
                FileClose($filecount)
                ExitLoop
            EndIf
        WEnd
        FileClose($filegroup)
    Next
EndFunc   ;==>ResBE
 

Déclare tes variables locales, passe tes $rows, $nrows en byref et règle aussi le cas de ce $file.
Met ça en tête de tous tes modules principaux, ça t'évitera des heures de grattage de cervelas :

Code : Tout sélectionner

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

[ludoo]

je comprend pas comment passé le resultat $nrows et $rows en byref à la fonction ResBE
puis à l'autre fonction BE,
voici le code ds son intégralité.

► Afficher le texte

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <SQLite.au3>
#include <SQLite.Dll.au3>
#include <AD.au3>
#include <Array.au3>
#include <Process.au3>

Global $file1 = @ScriptDir & '\log_spooler.txt'
Global $file = @ScriptDir & "\log_spooler_"&@MON&".txt"
Global $nomfile = "papercut-print-log-"&@YEAR&"-"&@MON&".csv"
Global $Patchfile = @ScriptDir


Global Const $impBE1 = "LEXMARK-E352DN-RDC-01"
Global Const $impBE2 = "HP-P2055DN-RDC"
Global Const $impBE3 = "LEXMARK-E360DN-1E"
Global Const $impBE4 = "OCE-3155-1E"
Global Const $impBE5 = "LEXMARK-X363DN-1E-01"

Global Const $impBCR1 = "LEXMARK-E352DN-RDC-03"
Global Const $impBCR2 = "HP-CP3525DN-RDC"
Global Const $impBCR3 = "LEXMARK-E352DN-RDC-04"

Global Const $impBRNE1 = "OCE-3155-2EXT"
Global Const $impBRNE2 = "LEXMARK-E360DN-2EXT"


FileCopy($file1, $file,9)

_SQLite_Startup()
Global $hDb = _SQLite_Open(@ScriptDir & "\SpoolLog_"&@MON&".db3")
_SQLite_Exec($hDb, "CREATE TABLE if not exists Log (" & _
" Id INTEGER NOT NULL PRIMARY KEY AUTOINCREMENT," & _
" Date CHAR," & _
" User CHAR," & _
" Pages INTEGER," & _
" Copies INTEGER," & _
" Printer CHAR," & _
" Document CHAR," & _
" Client CHAR," & _
" Paper CHAR," & _
" Language CHAR," & _
" Height INTEGER," & _
" Width INTEGER," & _
" Duplex BOOLEAN," & _
" Grayscale BOOLEAN," & _
" SizeKb INTEGER," & _
" CONSTRAINT ksUniq UNIQUE(Date, User, Printer, Document) ON CONFLICT REPLACE);" & _
"CREATE INDEX if not exists ixDate ON Log (Date);" & _
"CREATE INDEX if not exists ixUser ON Log (User);" & _
"CREATE INDEX if not exists ixPrinter ON Log (Printer);")

Global $aLines, $res
_FileReadToArray($file, $aLines)
For $line In $aLines
$res = StringRegExp($line, '([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),"([^,]*)",([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*)kb,?', 1)
If Not @error Then
$res[11] = Number($res[1] = 'DUPLEX')
$res[12] = Number($res[12] = 'GRAYSCALE')
_SQLite_Exec($hDb , "insert into log ( date, user, pages, copies, printer, " & _
"document, client, paper, language, height, " & _
" width, duplex, grayscale, sizeKb) " & _
"values (" & X($res[0]) & XX($res[1]) & ZZ($res[2]) & ZZ($res[3]) & XX($res[4]) & _
XX($res[5]) & XX($res[6]) & XX($res[7]) & XX($res[8]) & ZZ($res[9]) & _
ZZ($res[10]) & ZZ($res[11]) & ZZ($res[12]) & ZZ($res[13]) & ");")
EndIf
Next

BE()

_SQLite_Close($hDb)
_SQLite_Shutdown()


Func X($s)
Return ("'" & StringReplace($s, "'", "''", 0, 1) & "'")
EndFunc ;==>X

Func XX($s)
Return (",'" & StringReplace($s, "'", "''", 0, 1) & "'")
EndFunc ;==>XX

Func Y($s)
Return ("X'" & Hex($s) & "'")
EndFunc ;==>Y

Func YY($s)
Return (",X'" & Hex($s) & "'")
EndFunc ;==>YY

Func Z($s)
Return (Number($s))
EndFunc ;==>Z

Func ZZ($s)
Return ("," & Number($s))
EndFunc ;==>ZZ



Func BE()
; Open Connection to the Active Directory
_AD_Open()

ReqBD_BE_1()
ResBE()

; Close Connection to the Active Directory
_AD_Close()
EndFunc ;==>BE

Func ResBE()
Local $user, $aUser, $pageA4, $pageA3, $filegroup, $rFile, $filecount
for $i = 0 To $nrows - 1
;~ MsgBox(0,"user","user "&$rows[$i][0] & " nbs pages "&$rows[$i][2])
$user = $rows[$i][0]
$pageA4 = $rows[$i][2]
$pageA3 = $rows[$i][1]
;~ MsgBox(0,"user","user "&$rows[$i][0])
;~ MsgBox(0,"user","nbs pages "&$page)

$aUser = _AD_GetUserGroups($user)
If @error > 0 Then
MsgBox(64, "Active Directory Functions - Example 1", "User '" & $user & "' has not been assigned to any group")
Else
; For groups that are inherited, the return is the FQDN of the group or user, and the FQDN(s) of the group(s) it
; was inherited from, seperated by '|'
;~ _ArrayDisplay($aUser, "Active Directory Functions - Example 1 - Group names user '" & $user & "' is a member of")
for $j = 1 to $aUser[0]

;~ MsgBox(0,"group user","user member of group "&$aUser[$j])
$filegroup = FileOpen("groupBE.txt",1)
If $filegroup = -1 Then
MsgBox(0, "Error", "Unable to open file.")
Exit
EndIf
FileWriteLine($filegroup, $aUser[$j] & @CRLF)
FileClose($filegroup)
Next
EndIf
$filegroup = FileOpen("groupBE.txt",0)
while 1
If $filegroup = -1 Then
MsgBox(0, "Error", "Unable to open file.")
Exit
EndIf
$rFile = FileReadLine($filegroup)
If @error = -1 Then ExitLoop
$cn = StringSplit($rFile, ",")
;~ MsgBox(0, "group", $rFile)
;~ MsgBox(0, "group cn=", $cn[1])
If $cn[1] = "CN=xxxxx" Then
$filecount = FileOpen("countBE.txt",1)
FileWriteLine($filecount, $pageA4)
FileWriteLine($filecount, $pageA3)
FileClose($filecount)
ExitLoop
EndIf


WEnd
FileClose($filegroup)

Next
EndFunc ;==> ResBE

Func ReqBD_BE_1()
$res = _SQLite_GetTable2d($hDb, "select user as [Utilisateur], (select total(pages * copies) from log G where L.user = G.user and g.paper = 'A3') as [Pages A3 imprimées], (select total(pages * copies) from log G where L.user = G.user and g.paper = 'A4') as [Pages A4 imprimées] from log L where printer = "& X($impBE1)&" group by user ;", $rows, $nrows, $ncols)
_ArrayDisplay($rows, "Copies par utilisateur")
EndFunc ;==>ReqBD_BE_1

merci pour ton aide
pour le $file c une erreur de frappe .

[jchd]

J'ai mis les variables de travail là où elles sont pertinentes et aussi passé le nom de l'imprimante BE en cours de traitement. J'ai fait une boucle sur toutes les BE (je n'ai aucune idée si c'est correct pour toi, mais ça te montre comment bien utiliser des variables en argument de fonction(s).
Ah oui, pense à employer OnAutoitExitRegister pour simplifier ton code, ne rien risquer d'oublier et aussi pour simplifier tes traitements d'erreur fatale. Par exemple, tu fais un "Exit" brutal si tel fichier ne peut être ouvert. En théorie, tu devrais invoquer _AD_Close() et _SQLite_Shutdown() avant la ligne Exit. Ces fonctions-là sont souvent optionnelles et ne pas les appeler ne "casse" rien dans une majorité de cas. Mais il n'en va pas toujours ainsi.
Si une erreur grave survient dans une fonction "enfouie" au nième niveau, cette fonction n'est pas censée avoir connaissance du fait que on utilise AD ou SQLite ou quoi que ce soit d'autre dans les couches au-dessus d'elle. Il n'appartient donc pas à une fonction de niveau N de se permettre de bidouiller des resources qui concernent les niveaux N-1, N-2, ... Un bon désign est de remonter cette erreur pour en informer les fonctions de niveau supérieur et ainsi leur donner une chance de fermer proprement fichiers et autres resources en cours d'utilisation. Un tel design est certes idéal mais lourd en pratique. Le mécanisme d'appel automatique de fonctions à la sortie d'AutoIt simplifie partiellement le problème et il ne faut pas se priver de l'utiliser.

► Afficher le texte

Code : Tout sélectionner

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <SQLite.au3>
#include <SQLite.Dll.au3>
#include <AD.au3>
#include <Array.au3>
#include <Process.au3>

Global $file1 = @ScriptDir & '\log_spooler.txt'
Global $file = @ScriptDir & "\log_spooler_" & @MON & ".txt"
;~ Global $nomfile = "papercut-print-log-" & @YEAR & "-" & @MON & ".csv"
;~ Global $Patchfile = @ScriptDir


Global Const $impBE[5] = [ _
    "LEXMARK-E352DN-RDC-01", _
    "HP-P2055DN-RDC", _
    "LEXMARK-E360DN-1E", _
    "OCE-3155-1E", _
    "LEXMARK-X363DN-1E-01" _
]

Global Const $impBCR[3] = [ _
    "LEXMARK-E352DN-RDC-03", _
    "HP-CP3525DN-RDC", _
    "LEXMARK-E352DN-RDC-04" _
]

Global Const $impBRNE[2] = [ _
    "OCE-3155-2EXT", _
    "LEXMARK-E360DN-2EXT" _
]


FileCopy($file1, $file, 9)

_SQLite_Startup()
OnAutoItExitRegister("_SQLite_ShutDown")
Global $hDb = _SQLite_Open(@ScriptDir & "\SpoolLog_" & @MON & ".db3")
; si OK ...
_SQLite_Exec($hDb, "CREATE TABLE if not exists Log (" & _
        " Id INTEGER NOT NULL PRIMARY KEY AUTOINCREMENT," & _
        " Date CHAR," & _
        " User CHAR," & _
        " Pages INTEGER," & _
        " Copies INTEGER," & _
        " Printer CHAR," & _
        " Document CHAR," & _
        " Client CHAR," & _
        " Paper CHAR," & _
        " Language CHAR," & _
        " Height INTEGER," & _
        " Width INTEGER," & _
        " Duplex BOOLEAN," & _
        " Grayscale BOOLEAN," & _
        " SizeKb INTEGER," & _
        " CONSTRAINT ksUniq UNIQUE(Date, User, Printer, Document) ON CONFLICT REPLACE);" & _
        "CREATE INDEX if not exists ixDate ON Log (Date);" & _
        "CREATE INDEX if not exists ixUser ON Log (User);" & _
        "CREATE INDEX if not exists ixPrinter ON Log (Printer);")

Global $aLines, $res
_FileReadToArray($file, $aLines)
_SQLite_SetTimeout($hDb, 60000)         ; on laisse jusqu'à 60 s de timeout, juste au cas où la base serait exploitée/exploitable par un autre process
_SQLite_Exec($hDb, "begin immediate;")  ; on lance une transaction avant l'insertion en boucle, pour la performance
For $line In $aLines
    $res = StringRegExp($line, '([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),"([^,]*)",([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*)kb,?', 1)
    If Not @error Then
        $res[11] = Number($res[1] = 'DUPLEX')
        $res[12] = Number($res[12] = 'GRAYSCALE')
        _SQLite_Exec($hDb, "insert into log ( date, user, pages, copies, printer, " & _
                "document, client, paper, language, height, " & _
                " width, duplex, grayscale, sizeKb) " & _
                "values (" & X($res[0]) & XX($res[1]) & ZZ($res[2]) & ZZ($res[3]) & XX($res[4]) & _
                XX($res[5]) & XX($res[6]) & XX($res[7]) & XX($res[8]) & ZZ($res[9]) & _
                ZZ($res[10]) & ZZ($res[11]) & ZZ($res[12]) & ZZ($res[13]) & ");")
    EndIf
Next
_SQLite_Exec($hDb, "commit;")

; Open Connection to the Active Directory
_AD_Open()
; Close Connection to the Active Directory on Exit
OnAutoItExitRegister("_AD_Close")

BE()

_SQLite_Close($hDb)




Func BE()
    Local $rows, $nrows
    For $printer In $impBE
        ReqBD_BE($printer, $rows, $nrows)
        ResBE($rows, $nrows)
    Next
EndFunc   ;==>BE



Func ResBE(ByRef $rows, ByRef $nrows)
    Local $user, $aUser, $pageA4, $pageA3, $filegroup, $rFile, $filecount
    For $i = 0 To $nrows - 1
;~ MsgBox(0,"user","user "&$rows[$i][0] & " nbs pages "&$rows[$i][2])
        $user = $rows[$i][0]
        $pageA4 = $rows[$i][2]
        $pageA3 = $rows[$i][1]
;~ MsgBox(0,"user","user "&$rows[$i][0])
;~ MsgBox(0,"user","nbs pages "&$page)

        $aUser = _AD_GetUserGroups($user)
        If @error > 0 Then
            MsgBox(64, "Active Directory Functions - Example 1", "User '" & $user & "' has not been assigned to any group")
        Else
            ; For groups that are inherited, the return is the FQDN of the group or user, and the FQDN(s) of the group(s) it
            ; was inherited from, seperated by '|'
;~ _ArrayDisplay($aUser, "Active Directory Functions - Example 1 - Group names user '" & $user & "' is a member of")
            For $j = 1 To $aUser[0]
;~ MsgBox(0,"group user","user member of group "&$aUser[$j])
                $filegroup = FileOpen("groupBE.txt", 1)
                If $filegroup = -1 Then
                    MsgBox(0, "Error", "Unable to open file.")
                    Exit
                EndIf
                FileWriteLine($filegroup, $aUser[$j] & @CRLF)
                FileClose($filegroup)
            Next
        EndIf
        $filegroup = FileOpen("groupBE.txt", 0)
        While 1
            If $filegroup = -1 Then
                MsgBox(0, "Error", "Unable to open file.")
                Exit
            EndIf
            $rFile = FileReadLine($filegroup)
            If @error = -1 Then ExitLoop
            $cn = StringSplit($rFile, ",")
;~ MsgBox(0, "group", $rFile)
;~ MsgBox(0, "group cn=", $cn[1])
            If $cn[1] = "CN=xxxxx" Then
                $filecount = FileOpen("countBE.txt", 1)
                FileWriteLine($filecount, $pageA4)
                FileWriteLine($filecount, $pageA3)
                FileClose($filecount)
                ExitLoop
            EndIf
        WEnd
        FileClose($filegroup)
    Next
EndFunc   ;==>ResBE

Func ReqBD_BE($imp, ByRef $rows, ByRef $nrows)
    Local $ncols
    $res = _SQLite_GetTable2d($hDb, "select user as [Utilisateur], (select total(pages * copies) from log G where L.user = G.user and g.paper = 'A3') as [Pages A3 imprimées], (select total(pages * copies) from log G where L.user = G.user and g.paper = 'A4') as [Pages A4 imprimées] from log L where printer = " & X($imp) & " group by user ;", $rows, $nrows, $ncols)
    _ArrayDisplay($rows, "Copies par utilisateur")
EndFunc   ;==>ReqBD_BE


Func X($s)
    Return ("'" & StringReplace($s, "'", "''", 0, 1) & "'")
EndFunc   ;==>X

Func XX($s)
    Return (",'" & StringReplace($s, "'", "''", 0, 1) & "'")
EndFunc   ;==>XX

Func Y($s)
    Return ("X'" & Hex($s) & "'")
EndFunc   ;==>Y

Func YY($s)
    Return (",X'" & Hex($s) & "'")
EndFunc   ;==>YY

Func Z($s)
    Return (Number($s))
EndFunc   ;==>Z

Func ZZ($s)
    Return ("," & Number($s))
EndFunc   ;==>ZZ
 

[ludoo]

merci pour les explications , sur la fonction ReqBD_BE pourquoi on met 'ByRef $rows, ByRef $nrows' alors qu'il n'existe pas encore ?

l'idéal serait de récupérer l' user du fichier texte , de le passer à la fonction AD ,pour connaitre le groupe , ajouter la fin de chaque ligne le groupe puis de mettre tout cela ds la base sqlite.

merci du temps consacré pour mon probleme.

[jchd]

Byref permet de passer non pas une copie d'une variable, mais une référence à cette variable, dont la fonction appelée peut changer le contenu à loisir (ou pas). Le principe évite de faire des copies de variables potentiellement volumineuses.
Les variables sont déclarées au niveau de la fonction BE() donc elles existent. Peu importe leur contenu (qui existe déjà, du seul fait de leur déclaration) pour la fonction de requête, car celle-ci va en changer le contenu car c'est justement son rôle. Par contre, ta fonction d'exploitation des résultats récupère ce contenu qui est maintenant significatif et agit en conséquence. On pourrait préciser pour celle-ci Const Byref, ce qui empêcherait d'en changer le contenu ou, à tout le moins, indiquerait clairement que ces variables sont "read-only" à ce niveau.

On ne dispose certes pas avec AutoIt de toute la panoplie des nuances que propose un langage plus subtil, mais on a quand même les moyens d'écrire du code propre et essentiellement maintenable, à condition de s'en donner la peine. Dans l'immense majorité des cas d'outils promis à une durée de vie non météoritique (je veux dire par là : prévus pour durer "un certain temps"), cet effort vaut la peine d'être produit et diminue la fragilité ou plutôt, augmente la stabilité et la dure de vie utile de cet outil/programme. D'un point de vue comptable (professionnel) c'est un gros pourcentage du coût global de la chose qui est ainsi économisé, indépendemment du contexte, du langage, etc.

l'idéal serait de récupérer l' user du fichier texte , de le passer à la fonction AD ,pour connaitre le groupe , ajouter la fin de chaque ligne le groupe puis de mettre tout cela ds la base sqlite.

Bien, et ce qui t'empêche de faire ainsi est ... ?
Bien que mon petit doigt me dit qu'en fait, tu récupères la liste des groupes auquels cet utilisateur appartient, et non pas un seul et unique groupe par utilisateur et que c'est là que tu coinces.
Par ailleurs, comment remets-tu à zéro le fichier groupBE.txt ?

[ludoo]

oui , effectivement je récupère tous les groupes AD dont l'utilisateur fait parti , pour remettre le fichier groupeBE.txt à zéro pas pensé .
je modifie ma stratégie , sortir l'utilisateur du fichier texte , chercher les groupes puis recréer un fichier texte avec toutes les infos et envoyer ds sqlite.
mais je bloque déjà sur le premier , j'arrive bien à lire le fichier texte , à faire le split pour avoir chaque valeur , mais pas à sortir l'utilisateur.
voici le code :

► Afficher le texte

;***** Les includes ****
#include <Array.au3>
;***** Les options *****

;***** Les variables *****
Global $file1 = @ScriptDir & '\log_spooler.txt'
Global $line, $filegroup

;***** Programme principal *****
$filegroup = FileOpen($file1,0)
While 1
$line = FileReadLine($filegroup)
If @error = -1 Then ExitLoop
MsgBox(0, "Line read:", $line)
Local $arr = StringSplit($line, ",")
If IsArray($arr) Then
For $i = 1 to $arr[0]
ConsoleWrite($arr[$i] & @LF)
Next
EndIf
WEnd

je progresse dans le code mais je voudrai l'améliorer ,
pour résumer je récupère bien les groupes AD dont l'utilisateur fait parti mais par contre je connais pas avance le nombres groupe,
une fois les groupe trouvé , je les insère ds un fichier texte avec d'autre information,
j'ai trouvé une solution mais pas très optimisé
voici le code :

► Afficher le texte

;***** Les includes ****
#include <Array.au3>
#include <File.au3>
#include <AD.au3>
;***** Les options *****

;***** Les variables *****
Global $sFilePath = @ScriptDir & '\log_spooler.txt'
Global $line, $filegroup, $var, $ggGroupAD, $j

;***** Les Fonctions *****

;***** Programme principal *****
$iLinesInFile = _FileCountLines($sFilePath) ;Count how many lines are in the file
;~ MsgBox(0, "_FileCountLines", $iLinesInFile)
For $i = 1 To $iLinesInFile ; loop through all the lines in your file

$sReadLine = FileReadLine($sFilePath, $i); read them as you go along

If StringInStr($sReadLine, "PaperCut") Then ; If it finds your string in the file it just read

MsgBox(0, "FileReadLine", "This line will be replaced : " & $sReadLine)

_FileWriteToLine($sFilePath, $i, "", 1) ; Write over that line with new string

EndIf

Next
For $i = 1 To $iLinesInFile ; loop through all the lines in your file

$sReadLine = FileReadLine($sFilePath, $i); read them as you go along

If StringInStr($sReadLine, "Time") Then ; If it finds your string in the file it just read

MsgBox(0, "FileReadLine", "This line will be replaced : " & $sReadLine)

_FileWriteToLine($sFilePath, $i, "", 1) ; Write over that line with new string

EndIf

Next
_AD_Open()
; Close Connection to the Active Directory on Exit
OnAutoItExitRegister("_AD_Close")

$file = FileOpen("log_spooler.txt", 0)
While 1
$line = FileReadLine($file)
If @error = -1 Then ExitLoop
$var = StringSplit($line, ",")
If StringInStr($line, $var[2]) Then
MsgBox(0, "Users", "user: " & $var[2])
AdUsertoGroup($var[2]) ; <== $var[2] c'est l'user
$filenew = FileOpen("new_log_spooler.txt",1)
if $aUser[$j] = "1" Then
FileWriteLine($filenew, $var[0]&","&$var[1]&","&$var[2]&","&$var[3]&","&$var[4]&","&$var[5]&","&$var[6]&","&$var[7]&","&$var[8]&","&$var[9]&","&$var[10]&","&$var[11]&","&$var[12]&","&$var[13]&","&$var[14]&","&$aUser[1])
EndIf
if $aUser[$j] = "2" Then
FileWriteLine($filenew, $var[0]&","&$var[1]&","&$var[2]&","&$var[3]&","&$var[4]&","&$var[5]&","&$var[6]&","&$var[7]&","&$var[8]&","&$var[9]&","&$var[10]&","&$var[11]&","&$var[12]&","&$var[13]&","&$var[14]&","&$aUser[1]&","&$aUser[2])
EndIf
if $aUser[$j] = "3" Then
FileWriteLine($filenew, $var[0]&","&$var[1]&","&$var[2]&","&$var[3]&","&$var[4]&","&$var[5]&","&$var[6]&","&$var[7]&","&$var[8]&","&$var[9]&","&$var[10]&","&$var[11]&","&$var[12]&","&$var[13]&","&$var[14]&","&$aUser[1]&","&$aUser[2]&","&$aUser[3])
EndIf
if $aUser[$j] = "4" Then
FileWriteLine($filenew, $var[0]&","&$var[1]&","&$var[2]&","&$var[3]&","&$var[4]&","&$var[5]&","&$var[6]&","&$var[7]&","&$var[8]&","&$var[9]&","&$var[10]&","&$var[11]&","&$var[12]&","&$var[13]&","&$var[14]&","&$aUser[1]&","&$aUser[2]&","&$aUser[3]&","&$aUser[4])
EndIf

EndIf
Wend


Func AdUsertoGroup($userAD)
Global $aUser
$aUser = _AD_GetUserGroups($userAD)
If @error > 0 Then
MsgBox(64, "Active Directory Functions - Example 1", "User '" & $userAD & "' has not been assigned to any group")
Else
;~ _ArraySort($aUser, 0, 1)
_ArrayDisplay($aUser, "Active Directory Functions - Example 1 - Group names user '" & $userAD & "' is a member of")
For $j = 1 to $aUser
MsgBox(0, "Groupe " & $j & "/" & $aUser[0] & " de l'utilisateur " & $userAD, "user: "&$UserAD&" est membre du groupe :"&$j)
$cnGroupeAD = StringSplit($j, ",")
if StringInStr($j, $cnGroupeAD[1]) Then
$ggGroupAD = StringTrimLeft($cnGroupeAD[1], 3)
MsgBox(0,"group user","user member of group "&$ggGroupAD)
EndIf
;~ MsgBox(0,"group user","user member of group "&$aUser[$i])
Next
EndIf
EndFunc ;==>AdUsertoGroup

FileClose($sFilePath)

j'ai bien mon nouveau fichier avec les groupesAD , comment les insérer ds Sqlite , à savoir que je connais pas le nombre de groupe.
un champ Sqlite peut avoir plusieurs valeur ?

Dans mon champ GroupeAD , j'ai l"ensemble des groupes , séparé par "|"
maintenant je cherche la requête Sqlite pour chercher sur un seul groupe + copies + pages par user
ex:

► Afficher le texte

SELECT User, Pages, Copies, GroupeAD, fulltextsearch(GroupeAD, 'GG-xxxx', 0) AS GroupeADMatch FROM 'Log' WHERE GroupeADMatch > 0

[jchd]

Désolé, je ne suis plus en mesure de contribuer ici actuellement (suis, grosso modo, SDF et sans internet).

[ludoo]

j'espère que ta situation va s'améliorer , en tout cas merci pour ton aide .

pour la requête j'ai trouvé ça :

► Afficher le texte

SELECT User, GroupeAD, (select total(pages * copies) FROM log G WHERE L.user =
G.user and
g.paper ='A4' and GroupeAD LIKE '%xxx%' ) FROM log L WHERE GroupeAD LIKE '%xxx%' GROUP BY user