[R] Comment utiliser la "Combo List" ?

[blacksoul305]

Bonjour, bonsoir.

Comme d'habitude, je cherche à utiliser les vastes possibilités d'Autoit, tout comme hier avec la commande "Pixel Search". Afin d'améliorer un exécuteur de programme j'en profite pour installer une "Combo list" avec tout les programmes que j'utilise souvent.
Je suis parvenu à créer ma GUI grâce à Koda, mais je n'arrive pas à créer les évènements.

Par exemple, comment je fais pour que Google Chrome se lance si je sélectionne google chrome dans ma combo list, et que j'appui sur le bouton "Commencer" ?

En vous remerciant.

[TT22]

Tu peux nous donner ton script ?
Ça pourra nous aider

[PandiPanda]

Pour la combo, j'aurai fait quelque chose comme ca ...

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $msg
    GUICreate("My GUI combo")  ; will create a dialog box that when displayed is centered

    Global $combo=GUICtrlCreateCombo("item1", 10, 10) ; create first item
    GUICtrlSetData(-1, "|Exit|google chrome") ; add other item snd set a new default

    GUISetState()

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        Select
            Case $msg=$GUI_EVENT_CLOSE
                Exit
            Case $msg=$combo
                Select
                    Case GUICtrlRead ($combo)="google chrome"
                        MsgBox(0,"","google Chrome :O!")
                    Case GUICtrlRead ($combo)="Exit"
                        MsgBox(0,"","EXIT")
                        Exit
                EndSelect
        EndSelect
    WEnd
EndFunc   ;==>Example

Avec ce code, vous devez pas appuyer sur le bouton commencer. J'editerai si vous avez vraiment besoin d'appuyer sur ce bouton

si vous voulez appuyez sur un bouton "Commencer"

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)

Example()

Func Example()
#Region ### START Koda GUI section ### Form=
Global $_1 = GUICreate("My GUI combo", 258, 186, 201, 138)
Global $combo = GUICtrlCreateCombo("item1", 10, 10, 145, 25)
GUICtrlSetData(-1, "|Exit|google chrome")
Global $Button1 = GUICtrlCreateButton("Commencer", 160, 8, 65, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

    ; Run the GUI until the dialog is closed
    Local $msg
    While 1
        $msg = GUIGetMsg()

        Select
            Case $msg=$GUI_EVENT_CLOSE
                Exit
            Case $Button1=$msg
                QueFaire(GUICtrlRead($combo))
        EndSelect
    WEnd
EndFunc   ;==>Example

Func QueFaire($str)
    Select
        Case $str="google chrome"
            ;faire ce que vous voulez
            MsgBox(0,"","google chrome")
        Case $str="Exit"
            ;faire ce que vous voulez
            MsgBox(0,"","Exit")
            Exit
    EndSelect
EndFunc

[blacksoul305]

Merci tout les deux pour vos réponses rapide.

Pour ce qui est du script, j'l'ai supprimé étant donné que je ne savais pas comment casé ma Combo list, j'ai le script original que je veux modifier.

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=..\..\Bureau\IconExtract\icons\shell32_315.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Process.au3>
#Region ### START Koda GUI section ### Form=c:\documents and settings\jonathan\bureau\programmes\fenêtre koda\programme jojo.kxf
Global $Form1_1 = GUICreate("Liste de programme - Jonathan's Programms©", 633, 447, 192, 124)
GUISetIcon("C:\Documents and Settings\Jonathan\Bureau\IconExtract\icons\shell32_315.ico")
GUISetBkColor(0x000000)
Global $Label1 = GUICtrlCreateLabel("Veuillez cliquer sur le nom du programme que vous désirez lancer.", 120, 8, 313, 17)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Group1 = GUICtrlCreateGroup("Navigateurs de recherches", 0, 64, 185, 145)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Button1 = GUICtrlCreateButton("Internet Explorer", 8, 88, 161, 33, $WS_GROUP)
Global $Button2 = GUICtrlCreateButton("Mozilla Firefox", 8, 128, 161, 33, $WS_GROUP)
Global $Button3 = GUICtrlCreateButton("Google Chrome", 9, 167, 161, 33, $WS_GROUP)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Group2 = GUICtrlCreateGroup("Divertissement", 0, 232, 185, 193)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Button4 = GUICtrlCreateButton("RealPlayer", 8, 256, 161, 33, $WS_GROUP)
Global $Button5 = GUICtrlCreateButton("Windows Media", 8, 296, 161, 33, $WS_GROUP)
Global $Button6 = GUICtrlCreateButton("Scite", 8, 376, 161, 33, $WS_GROUP)
Global $Button7 = GUICtrlCreateButton("Windows Live Messenger", 8, 336, 161, 33, $WS_GROUP)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Group3 = GUICtrlCreateGroup("Jeux", 256, 96, 225, 81)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Button8 = GUICtrlCreateButton("Rise Of Nation", 264, 120, 185, 33, $WS_GROUP)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Label2 = GUICtrlCreateLabel("Jonathan's programms©", 496, 408, 118, 17)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Group4 = GUICtrlCreateGroup("Système", 264, 208, 225, 129)
GUICtrlSetBkColor(-1, 0xFFFFFF)
Global $Button9 = GUICtrlCreateButton("Gestionnaire des tâches", 272, 232, 209, 97, $WS_GROUP)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
   Case $Button1
       Run ("C:\Program Files\Internet Explorer\IEXPLORE.EXE")
       If $Button1 = 0 Then
         MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
     EndIf

   Case $Button2
       Run("C:\Program Files\Mozilla Firefox\firefox.exe")
       If $Button2 = 0 Then
           MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
       EndIf

   Case $Button3
       Run("C:\Documents and Settings\Jonathan\Local Settings\Application Data\Google\Chrome\Application\chrome.exe")
       If $Button3 = 0 Then
           MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
       EndIf

  Case $Button4
       Run("C:\Program Files\Real\RealPlayer\realplay.exe")
       If $Button4 = 0 Then
           MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
       EndIf

  Case $Button5
       Run("C:\Program Files\Windows Media Player\wmplayer.exe")
       If $Button5 = 0 Then
       MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
   EndIf


   Case $Button6
       Run("C:\Program Files\AutoIt3\SciTE\SciTE.exe")
       If $Button6 = 0 Then
       MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
   EndIf


   Case $Button7
       Run("C:\Program Files\Windows Live\Messenger\msnmsgr.exe")
       If $Button7 = 0 Then
           MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
       EndIf

  Case $Button8
       Run("C:\Program Files\Microsoft Games\Rise of Nations\thrones.exe")
       If $Button8 = 0 Then
           MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
       EndIf

   Case $Button9
       Run("taskmgr.exe")
       If $Button9 = 0 Then
           MsgBox(16, "Erreur démarrage", "Le programme suivant n'existe peut être pas ou rencontre des difficultés à s'exécuter normalement.")
       EndIf
 EndSwitch
WEnd
 

A la place de tout ces boutons là, je veux mettre tout simplement une combo list.
Mais c'est pas si simple que ça car ma Combo List a une variable pour tout ces programmes là.

Pour l'exemple que tu m'as donné, il faut que j'le regarde de plus près car là j'comprend rien du tout haha.

Merci encore !

[PandiPanda]

Je pense que ceci devrai vous convenir

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=..\..\Bureau\IconExtract\icons\shell32_315.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Process.au3>
#Region ### START Koda GUI section ### Form=c:\documents and settings\jonathan\bureau\programmes\fenêtre koda\programme jojo.kxf
Global $Form1_1 = GUICreate("Liste de programme - Jonathan's Programms©", 633, 447, 192, 124)
GUISetIcon("C:\Documents and Settings\Jonathan\Bureau\IconExtract\icons\shell32_315.ico")
Global $combo=GUICtrlCreateCombo("",120, 8)
GUICtrlSetData(-1, "Internet Explorer|Mozilla Firefox|Google Chrome|RealPlayer|Windows Media|Scite|Windows Live Messenger|"& _
"Rise Of Nation|Gestionnaire des tâches", "item3")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $combo
            QueFaire(GUICtrlRead($combo))
    EndSwitch
WEnd
Func QueFaire($str)
    Switch $str
        Case "Internet Explorer"
            Run ("C:\Program Files\Internet Explorer\IEXPLORE.EXE")
        Case "Mozilla Firefox"
            Run("C:\Program Files\Mozilla Firefox\firefox.exe")
        Case "Google Chrome"
            Run("C:\Documents and Settings\Jonathan\Local Settings\Application Data\Google\Chrome\Application\chrome.exe")
        Case "RealPlayer"
            Run("C:\Program Files\Real\RealPlayer\realplay.exe")
        Case "Windows Media"
            Run("C:\Program Files\Windows Media Player\wmplayer.exe")
        Case "Scite"
            Run("C:\Program Files\AutoIt3\SciTE\SciTE.exe")
        Case "Windows Live Messenger"
            Run("C:\Program Files\Windows Live\Messenger\msnmsgr.exe")
        Case "Rise Of Nation"
            Run("C:\Program Files\Microsoft Games\Rise of Nations\thrones.exe")
         Case "Gestionnaire des tâches"
            Run("taskmgr.exe")
    EndSwitch
EndFunc

[blacksoul305]

J'vous remercie !

Topic résolu !