[..] Calcul adressage ip

[Shade]

Bonjour à tous,

Je me permet de poster car j'aurais besoin d'une petite application qui me sert à calculer mes plages d'adresse ip ainsi que mes masque de sous réseau.

Un exemple :
http://www.isiweb.org/outils/ipcalc.php

Il me faudrait cette page web en application pour pouvoir l'avoir toujours sur moi.

Merci de votre compréhension.

Bonne journée.

Cordialement.

[Strofe]

Bonjour

Je viens de commencer une formation réseau.

J'ai joué un peu avec autoit.

Si cela peut t'aider.

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.6.1
 Author:         Christophe SONNECK

 Script Function:
    Calcul de l'adressage d'un reseau

#ce ----------------------------------------------------------------------------
#include <GuiConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>
#include <GuiComboBoxEx.au3>
#include <EditConstants.au3>

Global $hIPAddress
Local $hgui, $msg

$hgui = GUICreate("Adressage d'un reseau à partir d'une adresse", 400, 300)
$hIPAddress = _GUICtrlIpAddress_Create ($hgui, 140, 10)
GUICtrlCreateLabel("Adresse IP", 10, 14)

GUICtrlCreateLabel("Longueur du préfixe", 10, 42)
$lg_pref = GUICtrlCreateCombo("", 140, 40,50,15,$CBS_DROPDOWNLIST) ; create first item
GUICtrlSetData($lg_pref, "1|2|3|4|5|6|7|8|9|10|11|12|13|14|15|16|17|18|19|20|21|22|23|24|25|26|27|28|29|30|31|32","24")
$btn_calc = GUICtrlCreateButton("Calculer", 30,70, 120, 40)
$btn_quit = GUICtrlCreateButton("Quitter", 250, 70, 120, 40)
$Edit1 = GUICtrlCreateEdit("", 10, 125, 381, 160, $ES_WANTRETURN)
GUISetState(@SW_SHOW)
_GUICtrlIpAddress_Set ($hIPAddress, "192.168.82.10")

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
;~          MsgBox(0,"CS","Au revoir")
            Exit
        Case $msg = $btn_quit
;~          MsgBox(0,"CS","Au revoir")
            Exit
        Case $msg = $btn_calc
            $ip_array = _GUICtrlIpAddress_GetArray ($hIPAddress)
            $ip = _GUICtrlIpAddress_Get ($hIPAddress)
            $lg = GUICtrlRead ($lg_pref)
            $ch_et = ""
                    
            For $t= 1 to 32
                If $t<=$lg Then 
                        $ch_et &= "1"
                    Else
                        $ch_et &= "0"
                EndIf
            Next ; ==> $t
            GUICtrlSetData($Edit1,"")   
            $ch_et1=_BinToDec(StringMid($ch_et,1,8))
            $ch_et2=_BinToDec(StringMid($ch_et,9,8))
            $ch_et3=_BinToDec(StringMid($ch_et,17,8))
            $ch_et4=_BinToDec(StringMid($ch_et,25,8))
            $ip1 = ($ip_array[0])       
            $ip2 = ($ip_array[1])       
            $ip3 = ($ip_array[2])           
            $ip4 = ($ip_array[3])
            $sortie  = "Masque " & @TAB & $ch_et1 & "." & $ch_et2 & "." & $ch_et3 & "." & $ch_et4 & @CRLF
            $sortie &= "Négatif " & @TAB & BitXOR($ch_et1,255) & "." & BitXOR($ch_et2,255) & "." & BitXOR($ch_et3,255) & "." & BitXOR($ch_et4,255) & @CRLF
            $sortie &= "Réseau " & @TAB & BitAND($ip1,$ch_et1) & "." & BitAND($ip2,$ch_et2) & "." & BitAND($ip3,$ch_et3) & "." & BitAND($ip4,$ch_et4) & @CRLF
            $sortie &= "Diffusion " & @TAB & BitXOR($ch_et1,255)+BitAND($ip1,$ch_et1) & "." & BitXOR($ch_et2,255)+BitAND($ip2,$ch_et2) & "." & BitXOR($ch_et3,255)+BitAND($ip3,$ch_et3) & "." & BitXOR($ch_et4,255)+BitAND($ip4,$ch_et4) & @CRLF
            $sortie &= "Début IP " & @TAB & BitAND($ip1,$ch_et1) & "." & BitAND($ip2,$ch_et2) & "." & BitAND($ip3,$ch_et3) & "." & BitAND($ip4,$ch_et4)+1 & @CRLF
            $sortie &= "Fin IP " & @TAB & BitOR(BitXOR($ch_et1,255),BitAND($ip1,$ch_et1)) & "." & BitOR(BitXOR($ch_et2,255),BitAND($ip2,$ch_et2)) & "." & Bitor(BitXOR($ch_et3,255),BitAND($ip3,$ch_et3)) & "." & BitOR(BitXOR($ch_et4,255),BitAND($ip4,$ch_et4))-1 & @CRLF
            $sortie &= "Nombre d'hôtes utiles " & @TAB & (2^(32-$lg))-2
            GUICtrlSetData($Edit1,$sortie)
            
    EndSelect
Wend


Func _DecToBin($dec)
    if (not IsInt($dec)) or ($dec < 0) Then return -1
    $bin = ""
    If $dec=0 Then Return "0"
    While $dec<>0
        $bin= BitAND ($dec, 1)&$bin
        $dec = BitShift ( $dec,1 )
    WEnd
;~  Sur 8 bit 
    $bin = StringMid("00000000",1,8-stringlen($bin)) & $bin
    Return $bin
EndFunc

Func _BinToDec($bin)
     if (not IsString($bin))  Then return -1
     $end=StringLen($bin)
     $dec=0
     for $cpt=1 to $end
         $char=stringmid($bin,$end+1-$cpt,1)
         Select
         case $char="1"
            $dec=BitXOR($dec,bitshift(1,-($cpt-1)))
        Case $char="0"
        ; nothing
        Case Else
        ;error
            return -1
        EndSelect
    Next
    return $dec
EndFunc
 

A+

[flodiable]

Bonjour !

Bon c'est mon premier post et premier programme essayez d'être indulgents ^^ Merci !

C'est un programme assez simple : tu rentre ton ip et ton masque et il te calcule le réseau et broadcast en appuyant sur Go !.

Avec une Inputbox et une scrollbar on peut trouver tous les masques de 0-32

Il y a une comparaison entre l'ip que l'on a tapé et celle que l'on peut rentrer en bas de la fenêtre (le bouton met oui si c'est sur le même réseau et non autrement).

C'est une première version j'y rajouterai surement un Ping

En espérant que c'est ce que tu recherche !

► Afficher le texte

Code : Tout sélectionner

#cs
    Date : 08/06/2011
    Name : Adressage IPv4

    Description : ce programme a pour but de calcul de façon dynamique les informations sur un réseau
#ce
#include <GuiListBox.au3>
#include <GuiEdit.au3>
#include <Array.au3>
#Include <GuiIPAddress.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

;***************** Variable Globales *************************************************************
;Form
Global $Adressage_ip
;Label
Global $lbl_ip,$lbl_mask,$lbl_net,$lbl_broadcast,$lbl_slash,$lbl_mask_calc,$lbl_ip_compare,$lbl_ip_compare_answer
;InputBox
Global $inpip_ip,$inpip_mask,$inp_level,$inpip_compare
;Bouton
Global $btn_go,$btn_compare
;Group
Global $grp_result_ip,$grp_mask_calc,$grp_Ip_compare,$grp_Ip
;UpDownLevel
Global $UpDownLevel
;*************************************************************************************************
HotKeySet("{ESC}", "Close") ;Permet de quitter lapplication avec la touche Echap
_Main()
Func Create_GUI() ;Fonction de création de la GUI (interface graphique)
    ;Forme principale****************************************************************************
    $Adressage_ip = GUICreate("Adressage IP", 350, 340, 500, 200) ;La forme principal est une fenetre ou on viendra imposer d'autres éléments dessus  
    ;label
    $lbl_ip = GUICtrlCreateLabel("Taper ici votre IP : ",20,20)
    $lbl_mask = GUICtrlCreateLabel("Taper ici votre masque : ",20,50)
    $lbl_net = GUICtrlCreateLabel("Réseau : ",50,120)
    $lbl_broadcast = GUICtrlCreateLabel("Broadcast : ",50,150)
    $lbl_slash = GUICtrlCreateLabel("/ : ", 50,212)
    $lbl_mask_calc = GUICtrlCreateLabel(" ==> 255.255.0.0" ,120,212)
    $lbl_ip_compare = GUICtrlCreateLabel("Que : " ,50,282)  
    ;InputBox
    $inpip_ip = _GUICtrlIpAddress_Create($Adressage_ip,137, 18)
    $inpip_mask = _GUICtrlIpAddress_Create($Adressage_ip,137, 48)
    $inpip_compare = _GUICtrlIpAddress_Create($Adressage_ip,80, 278)
    $inp_level = GUICtrlCreateInput(16, 70, 210, 50, 20, 0x2001)
    ;Bouton
    $btn_go = GUICtrlCreateButton("Go !", 275, 32)
    $btn_compare = GUICtrlCreateButton(" Non ", 225, 277)
    ;Group  
    $grp_result_ip = GUICtrlCreateGroup("Résultat", 40, 80, 227, 95)
    $grp_mask_calc = GUICtrlCreateGroup("Trouver son masque",40,182,200,60)
    $grp_Ip_compare = GUICtrlCreateGroup("Suis-je sur le même réseau ?",40,252,240,60)
    ;UpDownLevel
    $UpDownLevel = GUICtrlSetLimit(GUICtrlCreateUpdown($inp_level), 32, 0)
;~ **********************************************************************************************************
    Opt("GUIOnEventMode", 1) ;Permet d'utiliser les évènement GUICtrlSetOnEvent
;~  *************** Evenements Boutons ****************************************
    GUICtrlSetOnEvent($btn_go,"IpToNetwork")
;~  *************** Evenements InputBox ************************************
    GUICtrlSetOnEvent($inp_level,"DmaskToBmask")
    GUICtrlSetOnEvent($btn_compare,"IpCompare") 
    GUISetState(@SW_SHOW) ; Affiche la GUI
EndFunc   ;==>Create_GUI

Func IpToNetwork()
    Local $sortie = False
    Local $binary_number_ip[4]
    Local $binary_number_mask[4]
    Local $res_net,$res_broadcast
    
    If _GUICtrlIpAddress_IsBlank($inpip_ip) Then
        MsgBox(48,"Attention ! ","Le champ IP est vide ou incomplet !",10)
        $sortie=True
    EndIf
    If _GUICtrlIpAddress_IsBlank($inpip_mask) Then
        MsgBox(48,"Attention ! ","Le champ masque est vide ou incomplet !",10)
        $sortie=True    
    EndIf
    
    If  $sortie == False Then
        
        Local $ip=_GUICtrlIpAddress_GetArray($inpip_ip)
        Local $mask=_GUICtrlIpAddress_GetArray($inpip_mask)
        
        For $i=0 To 3
            $res_net = $res_net & "." & BitAND($mask[$i],$ip[$i])
            $res_broadcast = $res_broadcast & "." & BitOR($ip[$i],BitXOR($mask[$i],255))
        Next        
        $lbl_net = GUICtrlCreateLabel("Réseau : "& StringMid($res_net,2),50,120)
        $lbl_broadcast = GUICtrlCreateLabel("Masque : "& StringMid($res_broadcast,2),50,150)
    EndIf
EndFunc

Func DmaskToBmask()
    Local $nb_mask = _GUICtrlEdit_GetText($inp_level)
    Local $mem=0,$mem_lbl,$mem_calc
    
    while $nb_mask >= 8
        $nb_mask = $nb_mask - 8 
        $mem = $mem + 1
    WEnd
    $mem_calc = (255-(2^(8-$nb_mask))+1)
    Switch $mem
        Case 4
            $mem_lbl = " ==> 255.255.255.255"
            ;afficher 255.255.255.255
        Case 3 
            $mem_lbl = " ==> 255.255.255." & $mem_calc 
            ;afficher 255.255.255.2^nb_mask
        Case 2 
            $mem_lbl = " ==> 255.255." & $mem_calc & ".0"
            ;afficher 255.255.2^nb_mask.0
        Case 1 
            $mem_lbl = " ==> 255." & $mem_calc & ".0.0"
            ;afficher 255.2^nb_mask.0.0
        Case 0 
            $mem_lbl= " ==> "& $mem_calc &".0.0.0"
            ;afficher 2^nb_mask.0.0.0
    EndSwitch
    $lbl_mask_calc = GUICtrlCreateLabel($mem_lbl,120,212)
EndFunc


Func IpCompare()
    
    Local $sortie = False
    Local $binary_number_ip[4]
    Local $binary_number_mask[4]
    Local $res_net1,$res_net2
    
    If _GUICtrlIpAddress_IsBlank($inpip_ip) Then
        MsgBox(48,"Attention ! ","Le champ IP est vide ou incomplet !",10)
        $sortie=True
    EndIf
    If _GUICtrlIpAddress_IsBlank($inpip_compare) Then
        MsgBox(48,"Attention ! ","Le champ IP a comparer est vide ou incomplet !",10)
        $sortie=True    
    EndIf
    If _GUICtrlIpAddress_IsBlank($inpip_mask) Then
        MsgBox(48,"Attention ! ","Le champ masque est vide ou incomplet !",10)
        $sortie=True    
    EndIf
    
    If  $sortie == False Then       
        Local $ip1=_GUICtrlIpAddress_GetArray($inpip_ip)
        Local $ip2=_GUICtrlIpAddress_GetArray($inpip_compare)
        Local $mask=_GUICtrlIpAddress_GetArray($inpip_mask)     
        For $i=0 To 3
            $res_net1 = $res_net1 & "." & BitAND($mask[$i],$ip1[$i])
        Next    
        For $i=0 To 3
            $res_net2 = $res_net2 & "." & BitAND($mask[$i],$ip2[$i])
        Next        
        If $res_net1 = $res_net2 Then
            GUICtrlSetData($btn_compare,"Oui")
        Else
            GUICtrlSetData($btn_compare,"Non")
        EndIf
        
    EndIf
EndFunc

Func Close()
    Exit
EndFunc

Func _Main()        ; Fonction Principale
    Create_GUI()    ;Création de la Forme graphique
    While True      ;Boucle infini
        Sleep(1000) ;Evite un bouclage trop répétitif du programme
    WEnd            ;fin de boucle
EndFunc   ;==>_Main

Bonne journée