[Func] _USB_OnEventRegister

[matwachich]

Une fonction toute simple qui permet d'enregistrer une autre fonction qui sera appelée lors de l'insertion/retrait d'un disque USB.
L'utilisation est simple, l'exemple en haut du code suffit largement à la compréhension à mon avis!

J'espère que ça servira!

Code : Tout sélectionner

#include-once

Global $__USB_Detect_OnEventFunction = -1

#cs ----------
    Enregistre une fonction call-back qui sera appelé à l'insertion/éjection
    Elle doit avoir la forme suivante: _func($sPath, $iType)
        $sPath = Chemin du disque USB inséré/éjecté (exemple: "F:")
        $iType = 1 Pour Insertion, = 0 Pour Ejection

    Exemple

    _USB_OnEventRegister("_maFonction")

    While 1
        Sleep(250)
    WEnd

    Func _maFonction($disk, $type)
        Switch $type
            Case 1
                ConsoleWrite("Disque " & $disk & " inséré" & @CRLF)
            Case 0
                ConsoleWrite("Disque " & $disk & " retiré" & @CRLF)
        EndSwitch
    EndFunc
#ce ----------

Func _USB_OnEventRegister($sFunc)
    ; If already registered, just change function name
    If $__USB_Detect_OnEventFunction <> -1 Then 
        $__USB_Detect_OnEventFunction = $sFunc
        Return 1
    EndIf

    Local $strComputer = "."
    Local $objWMIServices = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")

    Local $sink = ObjCreate("WbemScripting.SWbemSink")
    ObjEvent($sink, "__SINK_")

    $objWMIServices.ExecNotificationQueryAsync($sink, "SELECT * FROM __InstanceOperationEvent WITHIN 5 WHERE TargetInstance ISA 'Win32_LogicalDisk'")
    $__USB_Detect_OnEventFunction = $sFunc

    Return 1
EndFunc

Func _USB_OnEventUnRegister()
    $__USB_Detect_OnEventFunction = -1
EndFunc

Func __SINK_OnObjectReady($objObject, $objAsyncContext)
    If $objObject.TargetInstance.DriveType = 2 Then
        Select
            Case $objObject.Path_.Class() = "__InstanceCreationEvent"
                Local $DriveIn = $objObject.TargetInstance.DeviceId
               ; ConsoleWrite("Lecteur " & $DriveIn & " ajouté" & @CRLF)
                Call($__USB_Detect_OnEventFunction, $DriveIn, 1)

            Case $objObject.Path_.Class() = "__InstanceDeletionEvent"
                Local $DriveOut = $objObject.TargetInstance.DeviceId
                ;ConsoleWrite("Lecteur " & $DriveOut & " supprimé" & @CRLF)
                Call($__USB_Detect_OnEventFunction, $DriveOut, 0)

        EndSelect
    EndIf
EndFunc   ;==>SINK_OnObjectReady
 

[cutprod]

Simple, efficace...
Merci a toi pour ce partage qui va faire des heureux:D

[Habibsbib]

Il n'y a pas moyen de connaître le chemin d'accès de la clé USB insérée ?

[matwachich]

Bah si, regarde bien l'exemple!

[Habibsbib]

Ah pardon, je n'avais pas vu
Très beau travail en tout cas.

[ethneldryt]

Bonsoir, je voudrai savoir si cette fonction gère le multi insertion?
C'est a dire si j’insère une 2 eme clef usb, si celle si est détecter? Merci.

[Tlem]

Au lieu de poser bêtement la question, pourquoi n'essayez vous pas !!!

[matwachich]

Oui elle gère cela, mais j'ai remarqué que parfois, y'a des ratés! (très peu heureusement!).

[ricky]

Hello,

merci pour cette fonction, elle est vraiment pas mal. Désolé de la déterrer.
J'ai vu ton autre mais celle-ci marche beaucoup moins bien.

Maintenant, il y a-t-il un moyen de la bloquer en lecture et écriture jusqu'à une certaine action (pression bouton,...)?

Merci d'avance pour ton aide

[matwachich]

J'ai pas vraiment compris la question.
Si vous voulez stopper la détection, il suffit d'utiliser la fonction _USB_OnEventUnRegister()

[TommyDDR]

Je pense qu'il veut bloquer l'accès à la clé.