[R] Fenêtre fille sans bord positionnée en xy

#1

Bonjour,
Je cherche à créer une fenêtre fille 'options', sans bord avec juste cinq boutons, que je puisse postionner en x et en y.
Si j'appuie sur le bouton 'DS Files', je voudrais que la fenêtre 'options', se place juste en dessous de ce bouton.
Un autre appuie faisant disparaître la fenêtre 'options'.

Pour l'instant , la fenêtre option reste toujours dans le bord gauche !

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=ds.ico
#AutoIt3Wrapper_outfile=SkinToolDS.exe
#AutoIt3Wrapper_Res_Fileversion=0.1.0.0
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <ButtonConstants.au3>

Dim $version = "0.1", $Profile
Dim $MainGUI, $DebugGUI

$MainGUI = GUICreate("IcarDS Skinner Tool "&$version&"     By: pierrotm777", 500, 603, -1, -1)
$Commands = GUICtrlCreateButton("Commands", 5, 5, 100, 25)
GUICtrlSetState($Commands,$GUI_DISABLE)
$LiveDebugLog = GUICtrlCreateButton("Live Debug Log", 105, 5, 100, 25)
$DSFiles = GUICtrlCreateButton("DS Files", 230, 5, 80, 25)
$Options = GUICtrlCreateButton("Options", 325, 5, 80, 25)
$onTop = GUICtrlCreateCheckbox("On Top?", 420, 10, 120, 20)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUISetState()

;GUI de debug
$DebugGUI = GUICreate("IcarDS Skinner Tool "&$version&"     By: pierrotm777", 500, 603, -1, -1, -1, -1, $MainGUI)
$ReturnToMainGUI = GUICtrlCreateButton("Commands", 5, 5, 100, 25)
GUICtrlSetState($ReturnToMainGUI,$GUI_ENABLE)
GUISetState(@SW_HIDE,$DebugGUI)

;Gui Options
;$OptionsGUI = GUICreate("", 82, 125, -1, -1, $MainGUI,BitOR($WS_SYSMENU,$WS_CAPTION,$WS_POPUP,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS))
$OptionsGUI = GUICreate("", 82, 125, 200, 200, $MainGUI,BitOR($WS_SYSMENU,$WS_DLGFRAME,$WS_POPUP,$WS_CLIPSIBLINGS))
$DSDebug = GUICtrlCreateButton("DS Debug", 1, 1, 79, 25)
$DSExecTBL = GUICtrlCreateButton("DS ExecTBL", 1, 25, 80, 25)
$SkinExecTBL = GUICtrlCreateButton("SkinExecTBL", 1, 49, 80, 25)
$SkinINI = GUICtrlCreateButton("Skin Ini", 1, 73, 80, 25)
$DSDocs = GUICtrlCreateButton("< DS Doc's", 1, 97, 80, 25)
GUISetState(@SW_HIDE,$OptionsGUI)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $DSFiles
            GUISwitch($OptionsGUI)
            GUISetState(@SW_SHOW,$OptionsGUI)

    EndSwitch

Wend

Merci de votre aide

#2

hmmm.... au début j'allais te suggerer plutot d'utiliser un GUICtrlCreateMenu de facon a faire un classique menu déroulant (pourquoi réinventer le fil a couper l'eau tiède...) et gérer toi même tes déroulages de menus...
Et puis bon, finalement il y avait peu de lignes a modifier...
M'est avis qu'il faudrait réviser tes comon_styles et extended_styles...

(j'en ai profité aussi pour refaire l'alignement des boutons, toussa...

)

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=ds.ico
#AutoIt3Wrapper_outfile=SkinToolDS.exe
#AutoIt3Wrapper_Res_Fileversion=0.1.0.0
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <ButtonConstants.au3>

Dim $version = "0.1", $Profile
Dim $MainGUI, $DebugGUI

$MainGUI = GUICreate("IcarDS Skinner Tool "&$version&"     By: pierrotm777", 500, 603, -1, -1)
$Commands = GUICtrlCreateButton("Commands", 5, 5, 100, 25)
GUICtrlSetState($Commands,$GUI_DISABLE)
$LiveDebugLog = GUICtrlCreateButton("Live Debug Log", 105, 5, 100, 25)
$DSFiles = GUICtrlCreateButton("DS Files", 230, 5, 80, 25)
$Options = GUICtrlCreateButton("Options", 325, 5, 80, 25)
$onTop = GUICtrlCreateCheckbox("On Top?", 420, 10, 120, 20)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUISetState()

;GUI de debug
$DebugGUI = GUICreate("IcarDS Skinner Tool "&$version&"     By: pierrotm777", 500, 603, -1, -1, -1, -1, $MainGUI)
$ReturnToMainGUI = GUICtrlCreateButton("Commands", 5, 5, 100, 25)
GUICtrlSetState($ReturnToMainGUI,$GUI_ENABLE)
GUISetState(@SW_HIDE,$DebugGUI)

;Gui Options
;$OptionsGUI = GUICreate("", 82, 125, -1, -1, $MainGUI,BitOR($WS_SYSMENU,$WS_CAPTION,$WS_POPUP,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS))
$CoordsMainGui = WinGetPos($MainGui)
$OptionsGUI = GUICreate("", 81, 126, 230, 31,BitOR($WS_SYSMENU,$WS_DLGFRAME,$WS_POPUP,$WS_CLIPSIBLINGS),bitor($WS_EX_MDICHILD,$WS_EX_CLIENTEDGE),$MainGUI)
$DSDebug = GUICtrlCreateButton("DS Debug", 1, 1, 80, 25)
$DSExecTBL = GUICtrlCreateButton("DS ExecTBL", 1, 26, 80, 25)
$SkinExecTBL = GUICtrlCreateButton("SkinExecTBL", 1, 51, 80, 25)
$SkinINI = GUICtrlCreateButton("Skin Ini", 1, 76, 80, 25)
$DSDocs = GUICtrlCreateButton("< DS Doc's", 1, 101, 80, 25)
GUISetState(@SW_HIDE,$OptionsGUI)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $DSFiles
            GUISwitch($OptionsGUI)
            GUISetState(@SW_SHOW,$OptionsGUI)

    EndSwitch

Wend

#3

D'après la Doc :

Code : Tout sélectionner

GUICreate ( "title" [, width [, height [, left [, top [, style [, exStyle [, parent]]]]]]] )

Or vous avez écrit :

Code : Tout sélectionner

GUICreate("", 82, 125, 200, 200, $MainGUI,BitOR($WS_SYSMENU,$WS_DLGFRAME,$WS_POPUP,$WS_CLIPSIBLINGS))

Que je vais résumer par :

Code : Tout sélectionner

GUICreate("", 82, 125, 200, 200, $MainGUI, $Styles)

Je traduis donc votre ligne :
Titre = ""
width = 82
height = 125
left = 200
top = 200
style = $MainGUI
exStyle = $Styles
parent = 0

Je pense qu'à ce niveau vous avez du trouver votre faute.
Dans le doute :

style = $Styles
exStyle = -1
parent = $MainGUI

Je ne me suis pas trop penché sur le fond de votre GUI mais votre demande ressemble fortement à ce que fait déjà GUICtrlCreateMenu()
(Regardez l'exemple de la doc pour plus d'infos)

Edit : Grillé par zeshrek !!

#4

zeshrek, l'ogre qui code plus vite que son ombre

#5

Evidemment, si je lis la doc à l'envers ça ne va pas !

J'ai donc modifié ainsi

Code : Tout sélectionner

$MainGUI = GUICreate("IcarDS Skinner Tool "&$version&"     By: pierrotm777", 500, 603, -1, -1)
$MainPos = WinGetPos($MainGUI)

Le wingetpos me donnant la position de la fenêtre principale , il me suffit donc d'ajouter à ces coordonnées l'offset nécessaire au décalage que je souhaite:

Code : Tout sélectionner

;Gui Options
$OptionsGUI = GUICreate("", 82, 125, $MainPos[0]+230, $MainPos[1]+61, BitOR($WS_SYSMENU,$WS_DLGFRAME,$WS_POPUP,$WS_CLIPSIBLINGS),-1,$MainGUI)

Il me manque encore la solution permettant de refermer la fenêtre option avec le même bouton !

#6

toi tu n'as pas lu le bout de code que je t'avais mis un peu plus haut !
avec le styme $WS_EX_MDICHILD tu n'as pas besoin de te prendre la tete avec l'offset , il se fait tout seul, et en plus la fenetre fille est déplacée avec la mere.

Sinon pour tes probleme de on/off de ta sous-gui, voilà :

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=ds.ico
#AutoIt3Wrapper_outfile=SkinToolDS.exe
#AutoIt3Wrapper_Res_Fileversion=0.1.0.0
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <ButtonConstants.au3>

Dim $version = "0.1", $Profile
Dim $MainGUI, $DebugGUI

$MainGUI = GUICreate("IcarDS Skinner Tool "&$version&"     By: pierrotm777", 500, 603, -1, -1)
$Commands = GUICtrlCreateButton("Commands", 5, 5, 100, 25)
GUICtrlSetState($Commands,$GUI_DISABLE)
$LiveDebugLog = GUICtrlCreateButton("Live Debug Log", 105, 5, 100, 25)
$DSFiles = GUICtrlCreateButton("DS Files", 230, 5, 80, 25)
$Options = GUICtrlCreateButton("Options", 325, 5, 80, 25)
$onTop = GUICtrlCreateCheckbox("On Top?", 420, 10, 120, 20)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUISetState()

;GUI de debug
$DebugGUI = GUICreate("IcarDS Skinner Tool "&$version&"     By: pierrotm777", 500, 603, -1, -1, -1, -1, $MainGUI)
$ReturnToMainGUI = GUICtrlCreateButton("Commands", 5, 5, 100, 25)
GUICtrlSetState($ReturnToMainGUI,$GUI_ENABLE)
GUISetState(@SW_HIDE,$DebugGUI)


;Gui Options
;$OptionsGUI = GUICreate("", 82, 125, -1, -1, $MainGUI,BitOR($WS_SYSMENU,$WS_CAPTION,$WS_POPUP,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS))
$CoordsMainGui = WinGetPos($MainGui)
$OptionsGUI = GUICreate("", 81, 126, 230, 31,BitOR($WS_SYSMENU,$WS_DLGFRAME,$WS_POPUP,$WS_CLIPSIBLINGS),bitor($WS_EX_MDICHILD,$WS_EX_CLIENTEDGE),$MainGUI)
$DSDebug = GUICtrlCreateButton("DS Debug", 1, 1, 80, 25)
$DSExecTBL = GUICtrlCreateButton("DS ExecTBL", 1, 26, 80, 25)
$SkinExecTBL = GUICtrlCreateButton("SkinExecTBL", 1, 51, 80, 25)
$SkinINI = GUICtrlCreateButton("Skin Ini", 1, 76, 80, 25)
$DSDocs = GUICtrlCreateButton("< DS Doc's", 1, 101, 80, 25)
GUISetState(@SW_HIDE,$OptionsGUI)
$OptionsGUIStatus=False

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $DSFiles
            GUISwitch($OptionsGUI)
            if $OptionsGUIStatus = true Then
                GUISetState(@SW_HIDE,$OptionsGUI)
                $OptionsGUIStatus=False
            Else
                GUISetState(@SW_SHOW,$OptionsGUI)
                $OptionsGUIStatus=True
            EndIf

    EndSwitch

Wend

#7

Si si j'te JURE !!!

Et le bloquage de la fenêtre fille, j'adore , .

Merci zeshrek et à vous tous pour votre aide inestimable

AutoIt Français

[R] Fenêtre fille sans bord positionnée en xy

[R] Fenêtre fille sans bord positionnée en xy

Re: [..] Fenêtre fille sans bord positionnée en xy

Re: [..] Fenêtre fille sans bord positionnée en xy

Re: [..] Fenêtre fille sans bord positionnée en xy

Re: [..] Fenêtre fille sans bord positionnée en xy

Re: [..] Fenêtre fille sans bord positionnée en xy

Re: [..] Fenêtre fille sans bord positionnée en xy