[R] Sauvegarde de plusieurs dossiers pour chaque jour

[richie6700]

Bonjour à vous, (sachez que je suis nouveau ici et je suis vraiment pas bon en script...)

Donc voici mon soucy...

Je souhaiterais créer un script me permettant de supprimer des repertoire selon le jour de la semaine. Je vous explique :
Chaque jour je sauvegarde sur un serveur les dossiers de plusieurs serveurs en créant a chaque fois un dossier parent du style D:\SERVEUR1\lundi si on est lundi, SERVEUR2\Lundi, SERVEUR1\mardi si on est mardi.... Je souhaiterais pouvoir supprimer lundi (par exemple)avant de lancer la sauvegarde.
Par exemple nous somme lundi 1/01. Je lance la sauvegarde dans D:\Save\Lundi, OK cool sa marche .
Une semaine après (le lundi 8/01). il existe déja le repertoir Lundi ce qui m'arrange pas, donc je souhaiterais lancer le script qui reconnait le jour et ainsi me supprime le contenu de Lundi avant de lancer la sauvegarde. Et ceci pour chaque jour de la semaine. (Lundi, Mardi, Mercredi, Jeudi)
Voici mon code

► Afficher le texte

Code : Tout sélectionner

;
#Include <File.au3>
#Include <Array.au3>

;**********************************************************************************************
;
;                              Déclaration des variables
;
;**********************************************************************************************


$i = 0               ; compteur
$j = 0               ; compteur
$file =""            ; identifiant du fichier
$repertoire = ""     ; Tableau contenant le nom des répertoires a supprimer
                     ; repertoire[0][0] = contient le nombre de répertoires dont le contenu est à supprimer (appelé répertoire courant)
                     ; repertoire[$i][0] = Nom de la clé lu dans le fichier param.ini
                     ; repertoire[$i][1] = contient le nom du répertoire dont le contenu est à supprimer (lu dans le fichier param.ini)
$FileList = ""       ; Tableau contenant le noms des fichiers/répertoires à supprimer
                     ; FileList [0] = Nombre de répertoires à supprimer
                     ; FileList [$i] = Nom du répertoire à supprimer
$ficlog = "nettoye.log"  ; fichier de logs journalier rempli par l'exe sera au même endroit que l'exe
$jour = "" ; jour de la semaine
;**********************************************************************************************
;
;                              Programme
;
;**********************************************************************************************

_FileWriteLog($ficlog," ")                                                              ; écriture fichier log
_FileWriteLog($ficlog,"Nettoyage répertoire")                                          ; écriture fichier log
_FileWriteLog($ficlog,"--------------------")                                           ; écriture fichier log


$file = FileOpen("param.ini", 0)                                                        ; Ouverture du fichier param.ini
$repertoire = IniReadSection("param.ini", "repertoire")                                 ; lecture de la section repertoire

If @error Then
    MsgBox(4096, "", "Fichier Param.ini non trouvé")                                   ; si fichier param.ini non trouvé "Message d'erreur"
    _FileWriteLog($ficlog,"Fichier Param.ini non trouvé")                              ; écriture fichier log
Else
   
   For $i = 1 To $repertoire[0][0]                                                  ; De 1 à Nombre de répertoires dont le contenu est à supprimer

                   _FileWriteLog($ficlog,"suppression contenu du repertoire " & $repertoire[$i][1]); écriture fichier log
            FileDelete($repertoire[$i][1])                                                  ; suppression de tous les fichiers du répertoire courant
            $FileList=_FileListToArray($repertoire[$i][1])                                  ; Récupère la liste des fichiers/répertoires du répertoire courant
        
        If  @error <> 1 and @error <> 4 Then                                            ; Si le repertoire existe et qu'il y a des fichiers/respertoires à supprimer
            
            For $j = 1 to $FileList[0]                                                  ; De 1 à Nbre de répertoires à supprimer
                _FileWriteLog($ficlog,"suppression contenu du repertoire" & $repertoire[$i][1] & "\" & $FileList[$j])
                DirRemove($repertoire[$i][1] & "\" & $FileList[$j], 1)                  ; Suppression du répertoire
            Next
        EndIf
    Next
EndIf


 

Le fichier .INI contient ceci

► Afficher le texte

Code : Tout sélectionner

REM
REM
REM
REM
REM
REM
rem CONTIENT LE NOM DES REPERTOIRES DONT LE CONTENU EST A EFFACER

[repertoire]
repertoire1=D:\save\TESTSERVEUR1\lundi  
repertoire2=D:\save\TESTSERVEUR1\mardi
repertoire3=D:\save\TESTSERVEUR2\lundi
 

Est t-il possible de dire par exemple : Si on est Lundi rechercher dans param.ini tout ce qui contient lundi et de les supprimer????
Je pense qu'il faut utiliser "@wday@ mais je sais pas comment faire
J'espère que vous m'avez compris....

Et merci de votre aide!!

[FernandG]

Bonsoir,

Voici un exemple de code qui répond à votre demande :

Code : Tout sélectionner

Dim $jour, $path_backup = "D:\MyPathBackup"
Switch @WDAY
    Case 1
        $jour = "Dimanche"
    Case 2
        $jour = "Lundi"
    Case 3
        $jour = "Mardi"
    Case 4
        $jour = "Mercredi"
    Case 5
        $jour = "Jeudi"
    Case 6
        $jour = "Vendredi"
    Case 6
        $jour = "Samedi"
EndSwitch
If FileExists($path_backup & "\MonServeur1\" & $jour) Then DirRemove($path_backup & "\MonServeur1\" & $jour, 1)
ConsoleWrite('La suite de mon script de sauvegarde du serveur "MonServeur1".' & @CRLF)
If FileExists($path_backup & "\MonServeur2\" & $jour) Then DirRemove($path_backup & "\MonServeur2\" & $jour, 1)
ConsoleWrite('La suite de mon script de sauvegarde du serveur "MonServeur2".' & @CRLF)

Si vous avez plusieurs serveurs, je vous recommande de créer une function pour tout regrouper et éviter les répétitions.

Je n'ai pas abordé le fichier "ini", mais rien de bien compliqué. Sinon n'hésitez pas à nous soliciter de nouveau.

Bonne soirée.
AutoItement.

[richie6700]

bonsoir et merci pour ta réponse,

Il est vraiment pas compliqué ton script c'est cool!!! J'ai quand même un soucis c'est que le script me supprime tous le contenu du dossier "D:\Backup" et c'est pas ce que je veux... parce que dans ce dossier j'ai aussi les autres jours et sachant que c'est des sauvegardes il ne faut pas les supprimé tous en même temps.

N'y a t-il pas un moyen de "vider" le dossier Lundi???

merci et bonne soirée

[Tlem]

Le script de FernandG ne devrait pas effacer le répertoire entier, peut être, avez-vous mal retranscrit le script ...

Voici une version un peut plus universelle du script de FernandG, car il vous suffira de modifier les deux premières variables pour que le script s'occupe du répertoire de sauvegarde de vos 5 ou 10 serveurs.
Les deux lignes ConsoleWrite, ne sont là que pour afficher dans la console de Scite des infos sur le déroulement du script.

► Afficher le texte

Code : Tout sélectionner

; Variables à mettre à jour
Dim $BackupPath = "D:\MyPathBackup"
Dim $ServersName = ("MonServeur1,MonServeur2,MonServeur3")

; Déclarations internes.
Dim $ServersName, $i
Dim $Day[8] = ["7", "Dimanche", "Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi"]
$ServersName = StringSplit($ServersName, ",")

For $i = 1 to UBound($ServersName) - 1
    Local $DayBackupPath = $BackupPath & "\" & $ServersName[$i] & "\" & $Day[@WDAY]
    If FileExists($DayBackupPath) Then
        DirRemove($DayBackupPath, 1)
        ConsoleWrite('Suppression du répertoire : ' & $DayBackupPath & @CRLF)
        ConsoleWrite('La suite du script de sauvegarde du serveur "' & $ServersName[$i] & '".' & @CRLF)
    EndIf
Next

[FernandG]

Bonjour,

Il est vraiment pas compliqué ton script ...

C'était le but de cet exemple, pour ensuite passer à du code plus sophistiqué, plus "propre" comme celui de Tlem

Néanmoins attention au DirRemove. Vous parlez de serveur, j'imagine que c'est dans un contexte professionnel !?! La préservation des données est primordiale. Donc, vérifiez l'existence des données à sauvegarder avant toute suppression par une condition ou autre. Personnellement, j'opterai pour un RoboCopy avec le commutateur /MIR. Ainsi pas besoin de supprimer le dossier, le dossier du jour se met à jour et les données sont préservées si la sauvegarde échoue pour quelque raison que ce soit.

Bonne journée.
AutoItement.

[Tlem]

+1

Sinon, pour une utilisation en tout AutoIt, il faudrait dans un premier temps renommer le répertoire de destination (par exemple Lundi deviendrait Lundi_Old) puis lancer le backup, puis un petit contrôle de la taille du nouveau dossier de sauvegarde afin de contrôler que la sauvegarde c'est à peut prêt bien déroulée puis suppression de l'ancien dossier de sauvegarde.

Cela dit ce genre de manipulation est plutôt moyenne en temps et en sécurité. La solution de FenandG (Robocopy) est sans aucun doute la plus adaptée dans l'environnement décrit.

[richie6700]

Bonjour et encore merci pour vos conseil.

Pour répondre a ferndandG oui c'est pour un contexte professionnel, et la solution de robocopy est je crois la dernière solution malgré qu'elle soit facile, simple et rapide... mais étant donné que ce n'est pas moi le chef Informatique.... c'est pas moi qui prend les décision.. . Mais c'est une solution que je mettrais en avant étant donné que moi et les scripts sa fait 37.

Et pour Tlem je vous remercie pour le script que vous m'avez apporté. En effet, je pense que c'est moi qui a mal interprété le script de FernandG. Je vais voir le votre, en tout cas c'est cool de m'avoir aidé.

Je vous tiens au courant mes amis de toute façon.

@ plus et merci!!

AHHH J'ai oublié de dire... c'est sur un serveur distant que je souhaiterais mettre les sauvegarde et non en local... Je pense que si je monte un lecteur réseau sa passera nan???

[Tlem]

Peut importe.
Si vous avez accès à un répertoire de la forme \\Serveur\répertoire ou Z:\Répertoire ça fonctionnera de la même manière à partir du moment ou vous avez les droits de lecture/écriture.

Si lorsque vous parlez de distant, vous voulez dire sur un autre site, alors une solution de VPN sera préférable.

[richie6700]

OK OK OK!! c'est un serveur distant en local donc c'est bon!!! J'y accède grâce à son chemin UNC. Et maintenant peut être aurait vous une idée... Je suis toujours dans le même contexte avec les sauvegarde ect ect. Vous avez peut être vu que je ne parlai jamais du Vendredi...

Actuellement je fait aussi des sauvegarde complete le Vendredi ==> je le sauvegarde dans \\Monserveur1\save\Vendredi pour le serveur 1 ect ect comme pour les autres jours. Mon problème est le suivant :
Je souhaiterais que Vendredi soit renommer par Vendredi 1 le premier Vendredi du mois, par Vendredi 2 le 2ieme Vendredi du mois.... Comment pourrais je faire car le logiciel que j'utilise pour faire les sauvegarde (Cobian) ne permet pas de faire cela. Il permet juste de faire une sauvegarde tous les vendredi.

J'ai quelque idée du style copier le dossier Vendredi une fois la sauvegarde faite en vendredi 1 et ensuite supprimer Vendredi ect ect. Mais comment pourrais-je dire au script quel Vendredi je suis?

[bloodwolff]

moi je ferais un petit calcul en utilisant @MDAY

[FernandG]

Bonsoir,

Exact, bloodwolff vous a donné la réponse à travers @MDAY.

Voici un exemple de votre demande en me basant sur le code de Tlem

► Afficher le texte

Code : Tout sélectionner

; Variables à mettre à jour
Dim $BackupPath = "D:\MyPathBackup"
Dim $ServersName = ("MonServeur1,MonServeur2,MonServeur3")

; Déclarations internes.
Dim $ServersName, $d, $i, $jour
Dim $Day[8] = ["7", "Dimanche", "Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi"]
$ServersName = StringSplit($ServersName, ",")

For $i = 1 to UBound($ServersName) - 1
    Select
        Case @WDAY = 6 And @MDAY - 7 > 21
            $jour = $Day[@WDAY] & " 5"
        Case @WDAY = 6 And @MDAY - 7 > 14
            $jour = $Day[@WDAY] & " 4"
        Case @WDAY = 6 And @MDAY - 7 > 7
            $jour = $Day[@WDAY] & " 3"
        Case @WDAY = 6 And @MDAY - 7 > 0
            $jour = $Day[@WDAY] & " 2"
        Case @WDAY = 6 And @MDAY - 7 <= 0
            $jour = $Day[@WDAY] & " 1"
        Case Else
            $jour = $Day[@WDAY]
    EndSelect
    Local $DayBackupPath = $BackupPath & "\" & $ServersName[$i] & "\" & $jour
    If FileExists($DayBackupPath) Then
        DirRemove($DayBackupPath, 1)
        ConsoleWrite('Suppression du répertoire : ' & $DayBackupPath & @CRLF)
        ConsoleWrite('La suite du script de sauvegarde du serveur "' & $ServersName[$i] & '".' & @CRLF)
    EndIf
Next

Exit

Bonne soirée.

[bloodwolff]

Au lieu de ton sélect je voyais plus un truc du genre

Code : Tout sélectionner

 Floor((@MDAY-1)/7)+1

Mais bon

[FernandG]

Bien vu

Donc remplacer la section Select par :

Code : Tout sélectionner

    If @WDAY = 6 Then
        $jour = $Day[@WDAY] & " " & Floor((@MDAY - 1) / 7) + 1
    Else
        $jour = $Day[@WDAY]
    EndIf

Bonne soirée.

[Tlem]

Ouaip. Ou encore comme ceci :

► Afficher le texte

Code : Tout sélectionner

; Variables à mettre à jour
Dim $BackupPath = "D:\MyPathBackup"
Dim $ServersName = ("MonServeur1,MonServeur2,MonServeur3")

; Déclarations internes.
Dim $ServersName, $d, $i, $jour
Dim $Day[8] = ["7", "Dimanche", "Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi"]
Dim $PrevWDay[8] = [0, 7, 1, 2, 3, 4, 5, 6]
$ServersName = StringSplit($ServersName, ",")

For $i = 1 to UBound($ServersName) - 1
    Local $DayBackupPath = $BackupPath & "\" & $ServersName[$i] & "\" & $Day[$PrevWDay[@WDAY]]
    If FileExists($DayBackupPath) Then
        DirRemove($DayBackupPath, 1)
        ConsoleWrite('Suppression du répertoire : ' & $DayBackupPath & @CRLF)
        ConsoleWrite('La suite du script de sauvegarde du serveur "' & $ServersName[$i] & '".' & @CRLF)
    EndIf
Next

Exit

[FernandG]

Bonjour,

Je pense que le code est incomplet ...
Peux-tu nous mettre le For et les éventuelles lignes après ?!?!

[Tlem]

Arf, effectivement j'avais effacé par inadvertance la ligne du FOR.

Code modifié.

[FernandG]

Décalage horaire ?

Code : Tout sélectionner

Local $DayBackupPath = $BackupPath & "\" & $ServersName[$i] & "\" & $PrevWDay[@WDAY]

Code : Tout sélectionner

Local $DayBackupPath = D:\MyPathBackup\MonServeur1\7

[Tlem]

Hummm oui effectivement.

Pas de décalage horaire, mais une soirée un peut trop arrosée ...

Code corrigé.

[Tlem]

Bien que ce que j'ai fait fonctionne parfaitement, je me suis rendu compte que je me suis laissé entrainé dans un code complexe alors que la solution était bien plus simple.
Techniquement, richie6700 va avoir besoin de deux choses.
1 - Le nom du jour de la semaine au moment du lancement du script
2 - Le nom du jour précédent de la semaine au moment du lancement du script

C'est à dire, Vendredi (Jour du lancement du script) et Jeudi (Jour précédent).
Donc au lieu de partir dans des complications de calcul ou de tableau imbriqués, le plus simple est d'avoir deux tableaux de correspondance.

► Afficher le texte

Code : Tout sélectionner

; Variables à mettre à jour
Dim $BackupPath = "D:\MyPathBackup"
Dim $ServersName = ("MonServeur1,MonServeur2,MonServeur3")

; Déclarations internes.
Dim $ServersName, $d, $i, $jour
Dim $Day[8] = ["7", "Dimanche", "Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi"] ; Pour le Backup du jour
Dim $PrevDay[8] = ["7", "Samedi", "Dimanche", "Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi"] ; Pour le Backup du jour avant
$ServersName = StringSplit($ServersName, ",")

For $i = 1 to UBound($ServersName) - 1
    Local $DayBackupPath = $BackupPath & "\" & $ServersName[$i] & "\" & $PrevDay[@WDAY]
    If FileExists($DayBackupPath) Then
        DirRemove($DayBackupPath, 1)
        ConsoleWrite('Suppression du répertoire : ' & $DayBackupPath & @CRLF)
        ConsoleWrite('La suite du script de sauvegarde du serveur "' & $ServersName[$i] & '".' & @CRLF)
    EndIf
Next

Exit

[FernandG]

Cela commence à devenir confus

...
richie6700 va avoir besoin de deux choses. ...
2 - Le nom du jour précédent de la semaine au moment du lancement du script
...

Pourquoi faire ?

Le but n'est pas ; la sauvegarde du jour remplace la sauvegarde de la semaine dernière en J-7 ?
Puis des dossier différents pour les vendredi afin de les différencier en énième vendredi du mois ?

Ou j'y comprends plus rien ...