[..] Affichage d'un texte en fonction d'une valeur de var.

[RL77LUC]

Bonjour à tous.

Je débute en AutoIt et je suis confronté à un "problème".
En fait, mon problème est relativement simple. Je veux juste afficher un texte "Activé" en vert si une variable Tapp est égale à 1, un texte "Désactivé" en rouge si une variable Tapp est égale à 0.
Je pense qu'avec une boucle ça doit se faire MAIS je veux également que le script continue de tourner, dpnc que l'état se recharge automatiquement pendant que le script continue son execution. Voilà mon code actuel :

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
If Not IsAdmin() Then
    MsgBox(16, "Erreur", "Vous devez exécuter le programme en tant qu'administrateur.")
    Exit
EndIf
HotKeySet("{F5}", "Tapper")
HotKeySet("{F6}", "OffTapp")
Global $Tapp

#Region ### START Koda GUI section ### Form=C:\Users\Romain\Desktop\CAMultiTool.kxf
Global $Form1 = GUICreate("CA MultiTools", 625, 443, 192, 124)
Global $Group1 = GUICtrlCreateGroup("Tapper", 8, 8, 161, 89)
Global $Button1 = GUICtrlCreateButton("ON", 16, 24, 65, 25, $WS_GROUP)
Global $Button2 = GUICtrlCreateButton("OFF", 96, 24, 65, 25, $WS_GROUP)
Global $Label1 = GUICtrlCreateLabel("F5", 40, 56, 16, 17)
Global $Label2 = GUICtrlCreateLabel("F6", 120, 56, 16, 17)
Global $Label3 = GUICtrlCreateLabel("Tapper :", 16, 72, 44, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg

Case $GUI_EVENT_CLOSE
   Exit

Case $Button1
    RunWait (@ComSpec & " /c " & "net start DHCP","", @SW_HIDE)

Case $Button2
    RunWait (@ComSpec & " /c " & "net stop DHCP","", @SW_SHOW)

 EndSwitch
WEnd

Func Tapper()
RunWait (@ComSpec & " /c " & "net start DHCP","", @SW_HIDE)
EndFunc

Func OffTapp()
RunWait (@ComSpec & " /c " & "net stop DHCP","", @SW_HIDE)
EndFunc
 

Voilà, merci d'avance pour l'aide que vous pourrez m'apporter. Je pense que ça doit être assez simple, mais impossible pour moi d'arriver à un résultat fonctionnel .

[jbnh]

Vous pouvez toujours essayer avec AdlibRegister

[moutelous]

Bonjour,

Ou alors utilisez Opt("GUIOnEventMode", 1).

... Il faut dans ce cas réadapter votre script bien sûr ...

[zeshrek]

un p'tit code valant mieux qu'on long discour...

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
If Not IsAdmin() Then
    MsgBox(16, "Erreur", "Vous devez exécuter le programme en tant qu'administrateur.")
    Exit
EndIf
HotKeySet("{F5}", "Tapper")
HotKeySet("{F6}", "OffTapp")
Global $Tapp = "Inconnu"

#Region ### START Koda GUI section ### Form=C:\Users\Romain\Desktop\CAMultiTool.kxf
Global $Form1 = GUICreate("CA MultiTools", 625, 443, 192, 124)
Global $Group1 = GUICtrlCreateGroup("Tapper", 8, 8, 161, 89)
Global $Button1 = GUICtrlCreateButton("ON", 16, 24, 65, 25, $WS_GROUP)
Global $Button2 = GUICtrlCreateButton("OFF", 96, 24, 65, 25, $WS_GROUP)
Global $Label1 = GUICtrlCreateLabel("F5", 40, 56, 16, 17)
Global $Label2 = GUICtrlCreateLabel("F6", 120, 56, 16, 17)
Global $Label3 = GUICtrlCreateLabel("Tapper :", 16, 72, 44, 17)
Global $Label4 = GUICtrlCreateLabel($Tapp, 60, 72, 70, 17,$SS_CENTER) ; Ici le statut qui va changer de couleur
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

AdlibRegister("ColorTapp",100) ; on appelle la fonction qui colorie toutes les 100ms

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1 
            Tapper() ; pas la peine de remettre l'action ici, vu qu'il y avait une fonction pour ca, donc il suffit de l'appeler
        Case $Button2
            OffTapp() ; idem
    EndSwitch
WEnd

Func Tapper()
    $Tapp = "Activé" ; on paramettre le nouveau statut pour forcerle changement de couleur
    GUICtrlSetData($Label4,"Activation") ; vu que l'action d'activation / désactivation prend du temps, on affiche un statut intermédiaire
    RunWait(@ComSpec & " /c " & "net start DHCP", "", @SW_HIDE)
    GUICtrlSetData($Label4,$Tapp) ; et quand c'est fini on met le nouveau statut
EndFunc

Func OffTapp() 
    $Tapp = "Désactivé" ; on paramettre le nouveau statut pour forcerle changement de couleur
    GUICtrlSetData($Label4,"Désactivation")  ; vu que l'action d'activation / désactivation prend du temps, on affiche un statut intermédiaire
    RunWait(@ComSpec & " /c " & "net stop DHCP", "", @SW_HIDE)
    GUICtrlSetData($Label4,$Tapp) ; et quand c'est fini on met le nouveau statut
EndFunc

Func ColorTapp() ; La fonction qui change la couleur d'affichafe en fonction de $tapp
    Switch $Tapp
        case "Inconnu" ; j'ai mis celui ci parceque au début on sait pas encore quel est son statut
            GUICtrlSetBkColor($Label4, 0xffff00) ; fond jaune
            GUICtrlSetColor($Label4, 0x000000) ; ecriture noire
        case "Activé"
            GUICtrlSetBkColor($Label4, 0x00ff00) ; fond vert
            GUICtrlSetColor($Label4, 0x0ffff00) ; ecriture jaune
        case "Désactivé"
            GUICtrlSetBkColor($Label4, 0xff0000) ; fond rouge
            GUICtrlSetColor($Label4, 0xffff00) ; ecriture jaune
    EndSwitch
EndFunc
 

[moutelous]

OK ... je suis plutôt partisan de donner des indications pour inciter à la recherche ....

Mais bon, à chacun sa méthode et toute méthode à ses qualités ...

[RL77LUC]

Merci, ça fonctionne bien. J'aurais juste voulu savoir si y'avait pas moyen de supprimer l'effet de scintillement qui est fatiguant ^^ sinon c'est super, merci beaucoup.

Et sinon vous auriez pas une solution pour stopper/lancer un service et ses dépendances sans confirmation ? Le soucis c'est que Net Stop demande une confirmation qui du coup bloque le script.

[zeshrek]

@moutelous : c'est vrai quele sage a dit "si tu croises qqun qui a faim, ne lui donne pas un poisson, apprend lui a pecher". M'en vais donc mettre cela en pratique dès a présent.

@RL77LUC : Pour le scintillement, il faut juste que tu passespar une variable supplémentaire dans la fonction qui change les couleurs, et qui stocke la valeur de $Tapp.
Si cette variable est différente de $tapp, on fais un changement de couleur, et on lui affecte la nouvelle valeur de $tapp, sinon, on ne fait rien.
Comme ca ca scintillera plus

Pour le lancement/arret de services, y a eu un topic qui en parlait pas plus tard qu'hier ou avant hier. Une petite recherche peut etre ?

[RL77LUC]

OK Merci, ça scintille plus . Sinon pour les services j'ai essayé, mais les scripts fournis provoquent des erreurs chez moi :S.
Le soucis, c'est que j'ai des processus qui dépendent de mon service (DHCP), mais vu qu'il peut y en avoir pleins de différents, il me faudrait une commande qui shunte toutes ses dépendences .