[..] Calcul d'un masque de sous réseau IP

[Rapace15]

Bonjour à tous,

Je suis en train d'essayer de créer un script de config auto des proxy des navigateurs que nous utilisons au sein de notre société, et je bloque au niveau de la config des exceptions au proxy (je suis obligé pour diverses raisons de passer par une config de proxy manuelle).

FF utilise une notation du type aaa.bbb.ccc.ddd/mm
et IE utilise cette notation aaa.bbb.*.*

Généralement on me donne les exceptions sous la forme suivante aaa.bbb.ccc.ddd/255.255.248.0 (le masque étant variable)

Je ne comprends absolument pas comment calculer les notations vers IE ou FF à partir des éléments que j'ai.

Merci des pistes que vous pourrez me donner.

[zeshrek]

Es tu sur que ce soit un pb d'autoit ?

Premier lien : http://lmgtfy.com/?q=masques-de-sous-reseau
en particulier le § 5.8

[Rapace15]

Es tu sur que ce soit un pb d'autoit ?

Ben s'il existe des fonction AutoIt qui le font Oui, mais j'ai rien trouvé dans l'aide.

Quant à Google, oui... j'ai cherché, j'ai même trouvé un exemple en PHP ici, mais il utilise des fonctions PHP dont je n'ai pas trouvé d'équivalence dans l'aide.

long2ip par exemple...

[Tlem]

Pourtant, comme vous l'a fait remarque zeshrek, ceci est plutôt clair :

► Afficher le texte

5.8 - Quelle est cette notation avec un /, comme /24 ?
Une autre notation est souvent utilisée pour représenter les masques. On la rencontre souvent car elle est plus rapide à écrire. Dans celle-ci, on note directement le nombre de bits significatifs en décimal, en considérant que la contiguïté est respectée. Ainsi, pour notre exemple 192.168.25.0/255.255.255.0, on peut aussi écrire 192.168.25.0/24, car 24 bits sont significatifs de la partie réseau de l'adresse.

De même, les écritures suivantes sont équivalentes:

10.0.0.0/255.0.0.0 = 10.0.0.0/8
192.168.25.32/255.255.255.248 = 192.168.25.32/29

Etant donné que le masque détermine le nombre de machines qu'il pourra y avoir sur un réseau, c'est souvent de cette information que l'on part pour choisir le masque. Etant donné que l'on travail en binaire, le nombre de machines possible au sein d'un réseau sera une puissance de 2. Pour un nombre de machines donné, il faudra donc choisir la puissance de 2 supérieure pour pouvoir adresser les machines. De plus, il faudra prévoir un certain nombre d'adresses supplémentaires pour accueillir de nouvelles machines.

Ainsi, disons que l'on possède le réseau 193.225.34.0/255.255.255.0 et que l'on veut faire un réseau de 60 machines au sein de celui-ci. On veut 60 machines, il faut ajouter deux adresses pour le réseau et le broadcast, ce qui fait 62 adresses au total. La puissance de 2 supérieure à 62 est 64, mais cela ne nous laisserait que 2 adresses pour évoluer, ce qui est un peu juste. On préfèrera donc un réseau de 128 adresses. Pour identifier 128 adresses, il nous faut 7 bits (128 = 2^7) Donc dans notre masque, 7 bits seront à 0 pour identifier la partie machine, et les 25 bits restants seront à 1. Ce qui donne:

11111111.11111111.11111111.10000000

et en décimal 255.255.255.128.

Certes, les fonctions de calcul n'exites pas, mais vous avez tout les éléments pour le faire !!!

[Tlem]

Voici déjà la conversion du format xxx.xxx.xxx.xxx ou /xx en binaire :

► Afficher le texte

Code : Tout sélectionner

MsgBox(0, 'Conversion d''un masque 255.255.255.0', MaskToBinary("255.255.255.0"))
MsgBox(0, 'Conversion d''un masque décimal de 24', MaskToBinary("24"))

Func MaskToBinary($Mask)
    ; Test si le masque est valide
    If StringRegExp($Mask, "^(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[1-9])\.(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[1-9]|0)\.(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[1-9]|0)\.(25[0-5]|2[0-4][0-9]|[0-1]{1}[0-9]{2}|[1-9]{1}[0-9]{1}|[0-9])$") Then
        Local $aMask, $netmaskbinary
        ; On décompose le masque
        $aMask = StringSplit($Mask, ".")

        ; On convertit le masque en binaire
        $netmaskdec = ($aMask[1] * 16777216) + ($aMask[2] * 65536) + ($aMask[3] * 256) + $aMask[4]
        While $netmaskdec <> 0
            $binmod = Mod($netmaskdec, 2)
            $netmaskbinary = $binmod & $netmaskbinary
            $netmaskdec = Int($netmaskdec / 2)
        WEnd

        Return $netmaskbinary

        ; Test si nombre de 0 à 31
    ElseIf StringRegExp($Mask, "^([12]?[0-9]|3[01])$") Then
        Local $n, $Numb
        Local $FmtStr = "00000000000000000000000000000000"

        $Numb = Number($Mask)
        ; Ne pas prendre en compte le nombre 0
        If $Numb = 0 Then
            SetError(-2)
            Return
        EndIf

        ; Traite le nombre pour le transformer en nombre de bit
        For $n = 1 To $Numb
            $FmtStr = '1' & $FmtStr
        Next
        $FmtStr = StringLeft($FmtStr, 32) ; On garde les 32 derniers bits

        Return $FmtStr

    Else
        SetError(-2)
        Return
    EndIf
EndFunc   ;==>MaskToBinary

[sksbir]

Bonjour

Dans le but de rechercher si deux adresses IP sont dans le même réseau , j'avais trouvé deux fonctions qui semblent convenir à ton besoin. J'utilise ces fonctions afin de déterminer dans quel réseau se trouve le PC qui démarre.

Je précise que ça n'est pas moi qui les ai écrites, mais impossible de remettre la main sur la source. Désolé pour l'auteur, d'autant plus qu'il a bien fait les choses.

► Afficher le texte

Code : Tout sélectionner

Func _Subnet($sIp, $sNetmask)

    Dim $netmaskbinary
    Dim $subnetaddarray[5]
    Dim $invmaskarray[5]
    Dim $broadcastaddarray[5]
    Dim $sSubnetinfo[7]
    Dim $subnetadd
    Dim $invmask
    Dim $broadcastadd

    ; Reads IP and Netmask to an array
    $iparray = StringSplit($sIp, ".")
    $netmaskarray = StringSplit($sNetmask, ".")

    ; Validates IP address
    For $i = 1 To 4
        If Number($iparray[$i]) < 0 Or Number($iparray[$i]) > 255 Then
            SetError(1)
            Return (-1)
        EndIf
    Next

    ; Converts netmask into a decimal
    $netmaskdec = ($netmaskarray[1] * 16777216) + ($netmaskarray[2] * 65536) + ($netmaskarray[3] * 256) + $netmaskarray[4]

    ; Converts decimal netmask into binary (ex. 11111111111111111100000000000000)
    While $netmaskdec <> 0
        $binmod = Mod($netmaskdec, 2)
        $netmaskbinary = $binmod & $netmaskbinary
        $netmaskdec = Int($netmaskdec / 2)
    WEnd

    ; Determines the "slash" value of the netmask
    $maskslash = StringInStr($netmaskbinary, "0", 1) - 1

    ; Validates the "slash" value and netmask value
    If StringInStr(StringRight($netmaskbinary, 32 - $maskslash), "1") Then
        If $netmaskarray[4] = "255" Then
            $maskslash = 32
        Else
            SetError(1)
            Return (-1)
        EndIf
    EndIf

    ; Creates arrays conatining subnet address, wilcard, and broadcast addresses
    For $i = 1 To $iparray[0]
        $subnetaddarray[$i] = BitAND($iparray[$i], $netmaskarray[$i])
        $invmaskarray[$i] = BitNOT($netmaskarray[$i] - 256)
        $broadcastaddarray[$i] = BitOR($subnetaddarray[$i], $invmaskarray[$i])
    Next

    ; Creates strings conatining subnet address, wilcard, and broadcast addresses
    $subnetadd = $subnetaddarray[1] & "." & $subnetaddarray[2] & "." & $subnetaddarray[3] & "." & $subnetaddarray[4]
    $invmask = $invmaskarray[1] & "." & $invmaskarray[2] & "." & $invmaskarray[3] & "." & $invmaskarray[4]
    $broadcastadd = $broadcastaddarray[1] & "." & $broadcastaddarray[2] & "." & $broadcastaddarray[3] & "." & $broadcastaddarray[4]

    If $maskslash = 32 Then
        $iprange = $iparray[1] & "." & $iparray[2] & "." & $iparray[3] & "." & $iparray[4]
        $hosts = 1
    Else
        ; Determines the IP range for this subnet
        $iprange = $subnetaddarray[1] & "." & $subnetaddarray[2] & "." & $subnetaddarray[3] & "." & $subnetaddarray[4] + 1 & _
                "-" & $broadcastaddarray[1] & "." & $broadcastaddarray[2] & "." & $broadcastaddarray[3] & "." & $broadcastaddarray[4] - 1
        ; Calculates number of available hosts on this subnet
        $hosts = ($invmaskarray[4] + 1) * ($invmaskarray[3] + 1) * ($invmaskarray[2] + 1) * ($invmaskarray[1] + 1) - 2
    EndIf

    $sSubnetinfo[1] = $subnetadd
    $sSubnetinfo[2] = $broadcastadd
    $sSubnetinfo[3] = $invmask
    $sSubnetinfo[4] = $iprange
    $sSubnetinfo[5] = $hosts
    $sSubnetinfo[6] = $maskslash

    Return ($sSubnetinfo)
EndFunc   ;==>_Subnet

Func _SameSub($sIp, $sSubadd, $sBroadadd)

    Dim $iparray[5]
    Dim $subaddarray[5]
    Dim $broadaddarray[5]

    $iparray = StringSplit($sIp, ".")
    $subaddarray = StringSplit($sSubadd, ".")
    $broadaddarray = StringSplit($sBroadadd, ".")

    For $i = 1 To 4
        If Number($iparray[$i]) < 0 Or Number($iparray[$i]) > 255 Then
            SetError(1)
            Return (-1)
        EndIf
        If Number($subaddarray[$i]) < 0 Or Number($subaddarray[$i]) > 255 Then
            SetError(1)
            Return (-2)
        EndIf
        If Number($broadaddarray[$i]) < 0 Or Number($broadaddarray[$i]) > 255 Then
            SetError(1)
            Return (-3)
        EndIf
    Next

    $ipint = ($iparray[1] * 16777216) + ($iparray[2] * 65536) + ($iparray[3] * 256) + $iparray[4]
    $subaddint = ($subaddarray[1] * 16777216) + ($subaddarray[2] * 65536) + ($subaddarray[3] * 256) + $subaddarray[4]
    $broadaddint = ($broadaddarray[1] * 16777216) + ($broadaddarray[2] * 65536) + ($broadaddarray[3] * 256) + $broadaddarray[4]

    If $ipint > $subaddint And $ipint < $broadaddint Then
        Return (1)
    Else
        Return (0)
    EndIf
EndFunc   ;==>_SameSub
 

et voici un exemple simple d'utilisation de ces fonctions:

► Afficher le texte

Code : Tout sélectionner

Dim Const $RESEAU_ACTIF[2][7] = [ _
        ["reseau1", "10.1.0.0", "255.255.0.0", "X", 0, 0, 0], _
        ["reseau2", "192.168.0.0", "255.255.255.0", "X", 0, 0, 0], _

dim Const $ADRES[4]=[@IPAddress1,@IPAddress2,@IPAddress3,@IPAddress4]


$NB_IP_CONNUE=0
$LISTE_IP_CONNUE=""
For $SCAN_NET=0 To UBound($RESEAU_ACTIF)-1
    $IDSUBNET=_Subnet($RESEAU_ACTIF[$SCAN_NET][1],$RESEAU_ACTIF[$SCAN_NET][2])
    MsgBox(0,"test subnet", _
    $RESEAU_ACTIF[$SCAN_NET][0] & ":" & $RESEAU_ACTIF[$SCAN_NET][1] & "," & $RESEAU_ACTIF[$SCAN_NET][2] & @CRLF & _
    "subnetadd=" & $IDSUBNET[1] & @CRLF & _
    "broadcastadd=" & $IDSUBNET[2] & @CRLF & _
    "invmask=" & $IDSUBNET[3] & @CRLF & _
    "Iprange=" & $IDSUBNET[4] & @CRLF & _
    "hosts=" & $IDSUBNET[5] & @CRLF & _
    "maskslash=" & $IDSUBNET[6] )

    For $IP_INTERNE=0 To 3
        $TESTSUB=_SameSub($ADRES[$IP_INTERNE],$RESEAU_ACTIF[$SCAN_NET][1],$IDSUBNET[2])
        If @error=0 Then
            If $TESTSUB=1 Then
;;              MsgBox(0,"test","IPINT=" & $IP_INTERNE & ",samesub(" & $ADRES[$IP_INTERNE] & "," & $RESEAU_ACTIF[$SCAN_NET][1] & "," & $RESEAU_ACTIF[$SCAN_NET][2])
                $NB_IP_CONNUE+=1
                $LISTE_IP_CONNUE&=$RESEAU_ACTIF[$SCAN_NET][0] & ","
            EndIf
        EndIf
    Next
Next

 

Évidemment, le tableau est enrichi avec tous les réseaux existants, et les colonnes supplémentaires du tableau servent à mémoriser des caractéristiques supplémentaires ( pour toi, typiquement : l'adresse du proxy à configurer dans le navigateur, puisque elle semble etre différente en fonction du réseau sur lequel on est connecté)

[Tlem]

@sksbir
Votre message ne répond pas vraiment à la question de Rapace15, car celui-ci souhaite convertir un masque binaire /24 en masque classique 255.255.255.0 et vice versa.
Quand à votre source, c'est peut être celle-ci : http://www.autoitscript.com/forum/topic ... __p__51444

Merci quand même pour l'intention.

[sksbir]

Disons que ça répond partiellement
Sinon, ça peut toujours servir

Et pour la source, oui, c'est tout à fait ça. Je n'ai pas compris pourquoi je n'ai pas réussi à remettre la main dessus ? j'ai pourtant utilisé des mots clés comme _subnet ou _samesub sur google pour retrouver mes sources...

Dans la source en question, il y a quelque chose qui pourrait intéresser plus directement rapace15 : http://www.wildpackets.com/resources/fr ... subnetcalc