[R] Filtrer un fichier texte trés long

[pierrotm777]

Bonjour à tous,
J'essaie de traiter un long fichier texte du genre:
essai.txt

► Afficher le texte

Code : Tout sélectionner

abaca/LMS
abacule/LMS
abaissable/LMS
abaissai/jnmtlw
abaissais/jnmtlv
abaissante/LMF
abaissée/F
abaisse/jnmtlu
abaisse-langue/LM
abaissement/LMS
abaisserai/jnmtlx
abaisser/snmtlM
abaisseur/LMS
abajoue/LMS
abandon/LMS
abandonnai/jnmtlw
abandonnais/jnmtlv
abandonnataire/LMS
abandonnée/F
abandonne/jnmtlu
abandonnerai/jnmtlx
abandonner/snmtlM
abandonnique/LMS
abaque/LMS
abasourdie/F
abasourdirai/jnmtlx
abasourdir/snmtlM
abasourdis/jnmtluw
abasourdissais/jnmtlv
abasourdissante/LMF
abasourdissante/LMF
abasourdissement/LMS
abatage/LMS
abatant/LMS
abâtardie/F
abâtardirai/jnmtlx
abâtardir/snmtlM

J'ai essayé cela sans succés

Code : Tout sélectionner

$_TxtFilePath = @ScriptDir & "\essai.txt"
For $I = 1 To UBound ( $_TxtFilePath ) -1
    StringSplit($_TxtFilePath[$I],"/")
    StringReplace($_TxtFilePath[$I],$_TxtFilePath[$I],$_TxtFilePath[$I][1])
Next

Je voudrais que tout ce qui se trouve après les / soient effacés y compris les / .

Merci de votre aide

[mimione]

Bonjour
Essayer avec "StringInStr " et "StringTrimRight ".
Le plus dur, c'est de déterminer si le premier caractère est numéroté "0" ou "1"..!

[pop45]

J'espere que ceci, n'est qu'une partie du script, car la vous ne risque pas de modifier le contenue du fichier...

Code : Tout sélectionner

#include <File.au3>

$Path = @ScriptDir & "\essai.txt"
$File = FileOpen ("essai.txt")
For $i = 1 To _FileCountLines ($Path)
    $line = FileReadLine ($File,$i)
    $rep = StringSplit ($line,"/")
    _FileWriteToLine ($Path,$i,$rep[1],1)
Next

 

Tentez avec ce code

[Tlem]

Utilisez StringRegExpReplace avec le pattern (/.*)

[pierrotm777]

Merci , cela fonctionne à merveille

[pierrotm777]

Cela fonctionne trés bien,pop45, mais est terriblement long sur mon fichier de plus d'un mega .
(traitement non fini au bout de 5 heures) .

[pierrotm777]

Tlem,

J'ai donc testé votre solution, ainsi :

Code : Tout sélectionner

#include <File.au3>

$Path = @ScriptDir & "\dicofr2.txt"
$File = FileOpen ("dicofr2.txt")
For $i = 1 To _FileCountLines ($Path)
    $line = FileReadLine ($File,$i)
    $rep = StringRegExpReplace($line,"/.*","")
    _FileWriteToLine ($Path,$i,$rep,1)
Next

Mais cela prend aussi beaucoup de temps !

[sylvanie]

Bonsoir,

c'est en partie parce que vous travaillez ligne par ligne et que vous lancez une écriture de fichier à chaque ligne. Un peu comme si vous utilisiez un camion pour déménager, mais vous ne prenez qu'un carton par voyage.

essayez comme ceci par blocks de 500 lignes :

► Afficher le texte

Code : Tout sélectionner

$Path = @ScriptDir&"\dicofr2.txt"
$File = FileOpen ($Path,0)
$out_file=FileOpen(@TempDir&"\tmpwork",2)

$taille_block=500 ; on va lire / écrire par paquets de 500 lignes

While 1
       $block=""
       For $ind=1 to $taille_block
        $block&=FileReadLine($File)&@CRLF
        $err=@error
        if $err=-1 Then ExitLoop
       Next
       $rep = StringRegExpReplace($block,"/.*","")
       FileWrite($out_file,$rep)
       If $err=-1 Then ExitLoop
WEnd

FileClose($File)
FileClose($out_file)
FileMove(@TempDir&"\tmpwork",$Path,1)

 

mettez des timers sur les deux méthodes pour mesurer la différence.

[edit] : au fait q'appelez vous "gros" ? Si le fichier ne dépasse pas 50Mo par exple, ne bouclez plus et faites un seule fileread ...

[pierrotm777]

sylvanie,
je n'ai même pas vu se passer le traitement tellement il a été rapide.

Merci beaucoup de votre aide