[R] Gui modifiable par l'utilisateur

[neric77]

Bonjour,

Est il possible que l'utilisateur modifie sa GUI à sa convenance?

Je m'explique. A partir d'une Gui initiale vierge:


l'utilisateur, suite à une action :


peut ajouter un raccourci(bouton) à cette Gui:



Merci d'avance pour vos réponses.

Neric77

[Sh4dows]

Oui, c'est tout à fait possible !
Un simple GuiCtrlcreate en global lors d'un click sur un control et le tour est joué

Après si il souhaite déplacer le control il existe déjà un code de ce type sur le forum...

[neric77]

Oui, c'est tout à fait possible !
Un simple GuiCtrlcreate en global lors d'un click sur un control et le tour est joué

Après si il souhaite déplacer le control il existe déjà un code de ce type sur le forum...

J'ai essayer le Guictrlcreatebutton mais il n'apparait pas. J'ai essayé à partir d'une fonction et directement sous le case, dans les deux cas cela ne fonctionne pas

[SagePourpre]

Voici un petit exemple (codé grossièrement) démontrant la
faisabilité de la chose.

Code : Tout sélectionner

Global $rangee = 1, $col = 1, $nb_boutons = 0


Opt('GuiOnEventMode', 1)
$gui = GUICreate('Test', 250, 400)
GUISetOnEvent(-3, 'quitter')
$menu = GUICtrlCreateMenu('Action')
Global $ajout_bouton = GUICtrlCreateMenuItem('Ajouter un Bouton', $menu)
GUICtrlSetOnEvent($ajout_bouton, 'menu_events')
GUISetState()


While 1
    Sleep(10000)
WEnd


Func quitter()
    Exit
EndFunc   ;==>quitter

Func menu_events()
    Switch @GUI_CtrlId
        Case $ajout_bouton

            ConsoleWrite(Int($nb_boutons / 3))
            If Int($nb_boutons / 4) = $rangee Then
                $rangee += 1
                $col = 1
            EndIf

            Assign('_bouton_' & $nb_boutons + 1, GUICtrlCreateButton('Bouton ' & $nb_boutons, 10 + $col * 50 - 50, 10 + $rangee * 50 - 50, 45, 45), 2)
            GUICtrlSetOnEvent(-1, 'boutons_events')
            $col += 1
            $nb_boutons += 1




    EndSwitch


EndFunc   ;==>menu_events


Func boutons_events()
    For $i = 1 To $nb_boutons
        If @GUI_CtrlId = Eval('_bouton_' & $i) Then ; Bouton trouvé
            ;Action à effectuer avec le bouoton ( par exemple exécuter un programme, etc... )
            MsgBox(0, 'Notez Bien', 'Le bouton ' & $i - 1 & ' a été pressé')

        EndIf

    Next


EndFunc   ;==>boutons_events
 

Quelques points de repères :

- Utilisation de Assign et Eval afin de créer des événements aux boutons créés dynamiquement.
- Utilisation de variable afin de positionner les nouveaux boutons.

Finalement, c'est pas mal tout...

[neric77]

Merci

[neric77]

Pour info,

Après de multiples tests, mon erreur se situe dans le fait que le programme ne veut pas du tray et de la modification de la gui sous la même fonction Func menu_events()

a+

[benjahinfo]

Bonjour, peut-on le faire aussi mais pas avec du code événementiel ?
Auriez-vous un exemple ?

Up

[Tlem]

C'est vraiment grossier, mais en reprenant l'exemple de SagePourpre et en le transformant en mode standard, voici ce que cela donne :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $rangee = 1, $col = 1, $nb_boutons = 0

$gui = GUICreate('Test', 250, 400)
$menu = GUICtrlCreateMenu('Action')
Global $ajout_bouton = GUICtrlCreateMenuItem('Ajouter un Bouton', $menu)
GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $ajout_bouton
            ajout_bouton()

        Case Else
            boutons_events($nMsg)
    EndSwitch
WEnd

Func ajout_bouton()
    ConsoleWrite(Int($nb_boutons / 3))
    If Int($nb_boutons / 4) = $rangee Then
        $rangee += 1
        $col = 1
    EndIf

    Assign('_bouton_' & $nb_boutons + 1, GUICtrlCreateButton('Bouton ' & $nb_boutons, 10 + $col * 50 - 50, 10 + $rangee * 50 - 50, 45, 45), 2)
    $col += 1
    $nb_boutons += 1

EndFunc   ;==>ajout_bouton


Func boutons_events($nMsg)
    For $i = 1 To $nb_boutons
        If $nMsg = Eval('_bouton_' & $i) Then ; Bouton trouvé
            ;Action à effectuer avec le bouoton ( par exemple exécuter un programme, etc... )
            MsgBox(0, 'Notez Bien', 'Le bouton ' & $i - 1 & ' a été pressé')
        EndIf
    Next
EndFunc   ;==>boutons_events

Par contre je ne vois pas l’intérêt de vouloir absolument éviter le mode événementiel, car en passant en mode normal, vous vous compliquez le code.

[benjahinfo]

Merci,
Et bien en fait, j'ai commencer à apprendre Autoit de cette façon.
Je ne sais pas encore si la conversion de ces types deux modes se fait simplement.