[R] Mettre son propore ContextMenu sur un Edit

[TommyDDR]

Bonjour,

J'aimerais savoir comment mettre mon PROPRE ContextMenu sur un Edit.
En appliquant un GUICtrlCreateContextMenu() sur un Edit, cela n'a pas d'effet car il me laisse le ContextMenu d'origine (Que je n'ai pas demandé).

Voici un code pour tester :

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)

Dim $Gui

$Gui = GUICreate("test", 300, 300)
$Edit = GUICtrlCreateEdit("", 5, 5, 290, 290)
$Ctxt = GUICtrlCreateContextMenu($Edit)
$Item = GUICtrlCreateMenuItem("Test", $Ctxt)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
GUISetState()

While(True)
    Sleep(10)
WEnd

Func quit()
    Exit
EndFunc
 

En remplaçant "GUICtrlCreateEdit" par "GUICtrlCreateButton" ca marche donc ce n'est pas une erreur de codage.

Si quelqu'un a une solution... Je prend ^^

Merci.

[TommyDDR]

Au temps pour moi...

Note: You can't create context menus for controls that already have system context menus, i.e. edit or input controls.

Désolé (Résolu).

[ani]

lien = http://www.autoitscript.com/forum/index ... 77271&st=0

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GuiMenu.au3>
#include <Constants.au3>
#include <WinAPI.au3>

Global Enum $idOpen = 1000, $idSave, $idInfo, $idSelectAll

$hGUI = GUICreate("Test", 300, 200)

$Edit1 = GUICtrlCreateEdit("", 10, 10, 280, 150, BitOR($WS_HSCROLL, $WS_VSCROLL, $ES_MULTILINE))

$hMenu = _GUICtrlMenu_CreatePopup()

_GUICtrlMenu_AddMenuItem($hMenu, "Open", $idOpen)
_GUICtrlMenu_AddMenuItem($hMenu, "Save", $idSave)
_GUICtrlMenu_AddMenuItem($hMenu, "Info", $idInfo)
_GUICtrlMenu_AddMenuItem($hMenu,"")
_GUICtrlMenu_AddMenuItem($hMenu, "Undo", $WM_UNDO)
_GUICtrlMenu_AddMenuItem($hMenu,"")
_GUICtrlMenu_AddMenuItem($hMenu, "Cut", $WM_CUT)
_GUICtrlMenu_AddMenuItem($hMenu, "Copy", $WM_COPY)
_GUICtrlMenu_AddMenuItem($hMenu, "Paste", $WM_PASTE)
_GUICtrlMenu_AddMenuItem($hMenu,"")
_GUICtrlMenu_AddMenuItem($hMenu, "Select All", $idSelectAll)

GUISetState()

$wProcHandle = DllCallbackRegister("_WindowProc", "ptr", "hwnd;uint;wparam;lparam")

$wProcOld = _WinAPI_SetWindowLong(GUICtrlGetHandle($Edit1), $GWL_WNDPROC, DllCallbackGetPtr($wProcHandle))

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

GUIDelete($hGui)
DllCallbackFree($wProcHandle)

Func _WindowProc($hWnd, $Msg, $wParam, $lParam)
    Switch $hWnd
        Case GUICtrlGetHandle($Edit1)
            Switch $Msg
                Case $WM_CONTEXTMENU
                    _GUICtrlMenu_TrackPopupMenu($hMenu, $wParam)
                    Return 1
                Case $WM_COMMAND
                    Switch $wParam
                        Case $WM_UNDO, $WM_CUT, $WM_COPY, $WM_CLEAR, $WM_PASTE
                            _SendMessage($hWnd, $wParam)
                        Case $idOpen
                            ConsoleWrite("-> Open" & @LF)
                        Case $idSave
                            ConsoleWrite("-> Save" & @LF)
                        Case $idInfo
                            ConsoleWrite("-> Info" & @LF)
                        Case $idSelectAll
                            _SendMessage($hWnd, $EM_SETSEL, 0, -1)
                    EndSwitch
            EndSwitch
    EndSwitch
   
    Local $aRet = DllCall("user32.dll", "int", "CallWindowProc", "ptr", $wProcOld, _
                          "hwnd", $hWnd, "uint", $Msg, "wparam", $wParam, "lparam", $lParam)
    Return $aRet[0]
EndFunc
 

[TommyDDR]

Ah, joli.

J'ai finalement opté pour l'ajout d'une image transparente par dessus (car je n'accède jamais directement à mon "Edit") ce qui à résolu mon problème, mais merci pour ta réponse, je garde l exemple de côté