[R] Capturer une fenêtre non visible.

[ayuckers]

Bonsoir, voila pour ma première question sur ce forum

Depuis que j'ai découvert Autoit un petit projet me trotte dans la tête.
Comment expliqué sa.... Je cherche a avoir une capture miniature d'une Application qui n'est pas visible a l'écran.
je sais c'est un peut tordu.

PS : c'est de la faute a " periaz " et de sont topic : [..] Découper une fenêtre

J'ai fait un petit bout de Script pour que ce soit plus compréhensible.

Pré requis :
- il vous faut Autoit v3.3.0.0 car j'utilise la function " AdlibEnable() "
(dans la version Beta cette fonction été modifier, il faudra adapter le script en consequence... )
- il faut que le BlocNote soit lancer
(le choix du bloc note et un pure hasard au debut j'ai fait mes test sur VLC)

Ensuite :
- " Compiler " le script puis lancer le.
Le Bouton Capture fait une capture d'écran du Control Edit du Notepad

Cliquer sur le bonton Rafale et Saisissez du texte dans le notePad

Voici mon Bout de script:

► Afficher le texte

Code : Tout sélectionner

#include <ScreenCapture.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Global $Image = ""

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("WindowsCap", 625, 478, 192, 124)
$Button1 = GUICtrlCreateButton("Capture", 200, 440, 113, 33, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Rafale", 350, 440, 113, 33, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Stop", 500, 440, 113, 33, $WS_GROUP)
;$Pic1 = GUICtrlCreatePic($Image, 8, 8, 609, 425, BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS))
$Pic1 = GUICtrlCreatePic($Image, 8, 8, 609, 425)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            _Rafale()
        Case $Button2
            AdlibEnable("_Rafale",150)
        Case $Button3
            AdlibDisable()
    EndSwitch
WEnd

Func _Rafale()
    _MyScreenCap("[CLASS:Notepad]", "", "Edit1", @MyDocumentsDir & "\GDIPlus_Image.jpg")
    ;_MyScreenCap("[CLASS:QWidget]", "", "", @MyDocumentsDir & "\GDIPlus_Image.jpg")
    _Diplay_Screen()
EndFunc


Func _Diplay_Screen()
    $Image = @MyDocumentsDir & "\GDIPlus_Image.jpg"
    GUICtrlSetImage($Pic1,$Image)
EndFunc

Func _MyScreenCap($_Class, $_Name, $_Control, $_Path)
    Local $Image, $handle
    $handle = ControlGetHandle($_Class, $_Name, $_Control)
    _ScreenCapture_CaptureWnd ($_Path, $handle)
EndFunc

La Fonction " _MyScreenCap " permet de s'affranchir du Handle et de capturer un Control

Voici une capture d'écran :

► Afficher le texte

En fait le problème vient de la fonction " _ScreenCapture_CaptureWnd "
qui ne capture que ce qui est visible a l'écran.
Si je reduit le Bloc note sa me capture un écran noir.
La solution Qui consiste a mettre le focus sur le Blocnote pour l'afficher aux premier plan ne me convient pas

Auriez vous une Idée ?

[timmalos]

Je serais tenté de dire Impossible

[ayuckers]

En fait rien n'est impossible avec autoit

Je ne met pas Résolu car j'ai trouvé une solution, après avoir perdu la moité de mes neurones....
il me faut un peut plus de temps pour codé car la sa commence a devenir un peut
complexe pour moi. Mais je devrais réussir.
je vous présenterait tout sa bientôt.

j'ai réussi a modifier un exemple trouvé sur le forum anglais.
Apres avoir modifié cet exemple j'ai réussi a afficher une capture d'une application caché par une autre
et en plus c'est dynamique.

[Tlem]

Caché par une autre c'est possible, mais j'ai bien peur que si la fenêtre est cachée ou réduite, cela ne fonction pas.
Cela dit comme vous le dites, il est parfois possible de faire beaucoup de chose avec AutoIt.

[arrkhan]

beaucoup de choses et même l'impossible, le nombre de fois où je me suis dit : arf impossible, et que j'y arrive au bout du compte, me fait ne plus me dire que c'est impossible ^^

[ayuckers]

Bon je met resolu car j'ai trouver quelque chose qui me convient.
je vais ouvrir un nouveau sujet pour presenter mon application experimental

Pour info je me suis inspirer de ce scripte :

► Afficher le texte

#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <ScreenCapture.au3>

_GDIPlus_Startup()

;$hGUI = GUICreate("Screen Capture", 400, 300, @DesktopWidth, @DesktopHeight)
;GUISetState()

$hGUI = WinGetHandle("AutoIt Help")
WinMove($hGUI, "", @DesktopWidth, @DesktopHeight)

$iWidth = _WinAPI_GetWindowWidth($hGUI)
$iHeight = _WinAPI_GetWindowHeight($hGUI)

$hParent = GUICreate("WindowViewer", 500, 400)
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hParent)
GUISetState()

While 1

$hBMP = _WinCapture($hGUI, $iWidth, $iHeight)

$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)

_GDIPlus_GraphicsDrawImageRectRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight, 50, 50, 400, 300)

_GDIPlus_ImageDispose($hImage)
_WinAPI_DeleteObject($hBMP)

Sleep(1000)

WEnd

Func _WinCapture($hWnd, $iWidth = -1, $iHeight = -1)
Local $iH, $iW, $hDDC, $hCDC, $hBMP

If $iWidth = -1 Then $iWidth = _WinAPI_GetWindowWidth($hWnd)
If $iHeight = -1 Then $iHeight = _WinAPI_GetWindowHeight($hWnd)

$hDDC = _WinAPI_GetDC($hWnd)
$hCDC = _WinAPI_CreateCompatibleDC($hDDC)
$hBMP = _WinAPI_CreateCompatibleBitmap($hDDC, $iWidth, $iHeight)
_WinAPI_SelectObject($hCDC, $hBMP)

DllCall("User32.dll", "int", "PrintWindow", "hwnd", $hWnd, "hwnd", $hCDC, "int", 0)
;_WinAPI_BitBlt($hCDC, 0, 0, $iW, $iH, $hDDC, 0, 0, 0x00330008)

_WinAPI_ReleaseDC($hWnd, $hDDC)
_WinAPI_DeleteDC($hCDC)

;_ScreenCapture_SaveImage(@DesktopDir&"\window.jpg", $hBMP)
;_WinAPI_DeleteObject($hBMP)

Return $hBMP

EndFunc ;==>_WinCapture

Voici le lien vers le forum anglais :
http://www.autoitscript.com/forum/index ... ntry706312