[R] Déterminer le temps d'un Fichier video merci a Orax

[katanes]

Bonjour tout le monde

Sauriez vous quelle fonction ou script me permettrai de récupérer le temps d une vidéo avi ou autre......sans l ouvrir juste le temps..... J avoue n avoir aucune piste.......


Merci

[orax]

Avec la ligne de commande ou la DLL de Mediainfo : http://mediainfo.sourceforge.net/fr/Download/Windows. On peut obtenir plein d'infos sur les vidéos et donc je pense que le temps doit en faire partie.

[katanes]

Merci Orax excellent conseil effectivement mediainfo est nikel je laisse le code pour ceux qui serait dans la méme problématique....

► Afficher le texte

Code : Tout sélectionner

;Loading the DLL
$DLL=DllOpen("C:\Documents and Settings\Administrateur\Bureau\script multicam vegas\Mediainfo\MediaInfo_DLL_0.7.20_Windows_i386_WithoutInstaller\MediaInfo.dll")

;Info
$Info_Parameters=DllCall($DLL, "wstr", "MediaInfo_Option", "ptr", 0, "wstr", "Info_Parameters", "wstr", "")
;MsgBox(0, "MediaInfo_Option - Info_Parameters", $Info_Parameters[0])
$Info_Capacities=DllCall($DLL, "wstr", "MediaInfo_Option", "ptr", 0, "wstr", "Info_Capacities", "wstr", "")
;MsgBox(0, "MediaInfo_Option - Info_Capacities", $Info_Capacities[0])
$Info_Codecs=DllCall($DLL, "wstr", "MediaInfo_Option", "ptr", 0, "wstr", "Info_Codecs", "wstr", "")
;MsgBox(0, "MediaInfo_Option - Info_Codecs", $Info_Codecs[0])

;New MediaInfo handle
$Handle=DllCall($DLL, "ptr", "MediaInfo_New")

;Open
$Open_Result=DllCall($DLL, "int", "MediaInfo_Open", "ptr", $Handle[0], "wstr", "C:\Documents and Settings\Administrateur\Bureau\script multicam vegas\Video x\1.avi")

;Inform with Complete=false
DllCall($DLL, "wstr", "MediaInfo_Option", "ptr", 0, "wstr", "Complete", "wstr", "")
$Inform=DllCall($DLL, "wstr", "MediaInfo_Inform", "ptr", $Handle[0], "int", 0)
MsgBox(0, "Inform with Complete=false", $Inform[0])

;Inform with Complete=true
DllCall($DLL, "wstr", "MediaInfo_Option", "ptr", 0, "wstr", "Complete", "wstr", "1")
$Inform=DllCall($DLL, "wstr", "MediaInfo_Inform", "ptr", $Handle[0], "int", 0)
MsgBox(0, "Inform with Complete=true", $Inform[0])

;Custom Inform
DllCall($DLL, "wstr", "MediaInfo_Option", "ptr", 0, "wstr", "Inform", "wstr", "General;Example : Temps=%Duration/String%")
$Inform=DllCall($DLL, "wstr", "MediaInfo_Inform", "ptr", $Handle[0], "int", 0)
MsgBox(0, "Custom Inform", $Inform[0])

;Get with Stream=General and Parameter=FileSize
$Info_Get=DllCall($DLL, "wstr", "MediaInfo_Get", "ptr", $Handle[0], "int", 0, "int", 0, "wstr", "FileSize", "int", 1, "int", 0)
MsgBox(0, "Get with Stream=General and Parameter=FileSize", $Info_Get[0])

;GetI with Stream=General and Parameter=46
$Info_GetI=DllCall($DLL, "wstr", "MediaInfo_GetI", "ptr", $Handle[0], "int", 0, "int", 0, "int", 46, "int", 1, "int", 0)
MsgBox(0, "Get with Stream=General and Parameter=46", $Info_GetI[0])

;Count_Get with StreamKind=Stream_Audio
$Count_Get=DllCall($DLL, "int", "MediaInfo_Count_Get", "ptr", $Handle[0], "int", 2, "int", 0)
MsgBox(0, "Count_Get with StreamKind=Stream_Audio", $Count_Get[0])

;Get with Stream=General and Parameter=AudioCount
$Info_Get=DllCall($DLL, "wstr", "MediaInfo_Get", "ptr", $Handle[0], "int", 0, "int", 0, "wstr", "AudioCount", "int", 1, "int", 0)
MsgBox(0, "Get with Stream=General and Parameter=AudioCount", $Info_Get[0])

;Get with Stream=Audio and Parameter=StreamCount
$Info_Get=DllCall($DLL, "wstr", "MediaInfo_Get", "ptr", $Handle[0], "int", 2, "int", 0, "wstr", "StreamCount", "int", 1, "int", 0)
MsgBox(0, "Get with Stream=Audio and Parameter=StreamCount", $Info_Get[0])

;Delete MediaInfo handle
$Handle=DllCall($DLL, "none", "MediaInfo_Delete", "ptr", $Handle[0])

;Close the DLL
DllClose($dll)

[katanes]

Bonjour voila je suis un bloqué et je ne comprend vraiment pas le problème

Quand on le lance il fait une boucle mais ensuite erreur au niveau de la variable $sMediaInfo
J'utilise la dll mediainfo
Alors le script devrait permettre de chercher tout les .avi et en fonction de leur temps et les classer
exemple tout ceux qui font moins de 10 min

Code : Tout sélectionner

#include<Array.au3>
#include "FileListToArrayEx.au3"
#include<File.au3>
#include <ClipBoard.au3>

Dim $indice, $var_Array

$hDLL = DllOpen("C:\test\MediaInfo_DLL_0.7.20_Windows_i386_WithoutInstaller\MediaInfo.dll")
$dest = "C:\test\"
$dest2 = "C:\test\video"

; New MediaInfo handle

;Determiner nombre de .avi
Global $var_Array = _FileListToArrayEx ($dest, "*.avi", 0, "",true)
MsgBox(0,"",$var_Array[0]);Nombre de video

For $indice = 1 to $var_Array[0]
 $aMediaInfo = DllCall($hDLL, "ptr", "MediaInfo_New")
 $hMediaInfo = $aMediaInfo[0]
MsgBox(0,"hmediainfo",$hMediaInfo)

DllCall($hDLL, "dword", "MediaInfo_Open", _
        "ptr", $hMediaInfo, _ ; Handle
        "wstr", $var_Array[$indice]) ; Full path
MsgBox(0,"",$var_Array[$indice]);voir le resultat

; MediaInfo
$aMediaInfoGet = DllCall($hDLL, "wstr", "MediaInfo_Get", _
        "ptr", $hMediaInfo, _ ; Handle
        "int", 1, _ ; StreamKind <--Video
        "int", 0, _ ; StreamNumber
        "wstr", "Duration", _ ; Codec ID <-- this
        "int", 1, _ ; KindOfInfo
        "int", 0) ; KindOfSearch      ; Open


$sMediaInfo = $aMediaInfoGet[0]
MsgBox(0,"Test resulta sMediaInfo",$sMediaInfo);ici bug a la 2 e boucle résultat en ms pour résultat remplacer Duration par Duration\String
;résultat qui permet ensuite comparer
;pour les video moins de 10 min copier alors ici
;pour les video entre   10 min et 20 alors copier ici

DllCall($hDLL, "none", "MediaInfo_Close", "ptr", $hMediaInfo)
DllClose($hDLL)
sleep(1000)
Next

MsgBox(0,"","Tout est ok")







 

Merci de votre aide pour ce bug incompréhensible......si quelqu'un un a des suggestions ....

[orax]

En fait, il y avait également un problème plus haut ; vous auriez pu vous en rendre compte en mettant la macro @error dans la MsgBox :

Code : Tout sélectionner

    DllCall($hDLL, "dword", "MediaInfo_Open", _
            "ptr", $hMediaInfo, _ ; Handle
            "wstr", $dest & $var_Array[$indice]) ; Full path
    MsgBox(0, [color=#FF0000]@error[/color], $dest & $var_Array[$indice]);voir le resultat

A la deuxième boucle @error valait "1".

Donc pour corriger le problème, mettez les lignes :

Code : Tout sélectionner

DllCall($hDLL, "none", "MediaInfo_Close", "ptr", $hMediaInfo)
DllClose($hDLL)

après la boucle For/Next (après le Next).

[katanes]

Oui merci j ai en retour cette erreur
==> Subscript used with non-Array variable.:
$hMediaInfo = $aMediaInfo[0]
$hMediaInfo = $aMediaInfo^ ERROR

Meme en deplacer derriere Next

Mais ca avance...........merci de votre aide orax Et cool je comprend mieux @error mais la effectivement ca reste a 0 .........Mais tjrs cette meme erreur....

[orax]

Ben alors je vous donne mon script qui est fonctionnel chez moi.

► Afficher le texte

Code : Tout sélectionner

#include<Array.au3>
;~ #include "FileListToArrayEx.au3"
#include<File.au3>
#include <ClipBoard.au3>

Dim $indice, $var_Array

$hDLL = DllOpen("MediaInfo.dll")
$dest = "o:\"
$dest2 = "C:\test\video"

; New MediaInfo handle

;Determiner nombre de .avi
Global $var_Array = _FileListToArray($dest, "*.avi", 1)
MsgBox(0, "", $var_Array[0]);Nombre de video



For $indice = 1 To $var_Array[0]
$aMediaInfo = DllCall($hDLL, "ptr", "MediaInfo_New")
$hMediaInfo = $aMediaInfo[0]
MsgBox(0, "hmediainfo", $hMediaInfo)

    ; c'est ici qu'il y avait un problème puisque vous aviez mis "DllClose" dans la boucle
    DllCall($hDLL, "dword", "MediaInfo_Open", _
            "ptr", $hMediaInfo, _ ; Handle
            "wstr", $dest & $var_Array[$indice]) ; Full path
    MsgBox(0, @error, $dest & $var_Array[$indice]);voir le resultat

    ; MediaInfo
    $aMediaInfoGet = DllCall($hDLL, "wstr", "MediaInfo_Get", _
            "ptr", $hMediaInfo, _ ; Handle
            "int", 1, _ ; StreamKind <--Video
            "int", 0, _ ; StreamNumber
            "wstr", "Duration", _ ; Codec ID <-- this
            "int", 1, _ ; KindOfInfo
            "int", 0) ; KindOfSearch      ; Open


    $sMediaInfo = $aMediaInfoGet[0]
    MsgBox(0, "Test resulta sMediaInfo", $sMediaInfo);ici bug a la 2 e boucle résultat en ms pour résultat remplacer Duration par Duration\String
    ;résultat qui permet ensuite comparer
    ;pour les video moins de 10 min copier alors ici
    ;pour les video entre   10 min et 20 alors copier ici

    Sleep(1000)
Next

DllCall($hDLL, "none", "MediaInfo_Close", "ptr", $hMediaInfo)
DllClose($hDLL)

MsgBox(0, "", "Tout est ok")

Je n'ai pas mis FileListToArrayEx puisque je ne l'ai pas trouvé. Et attention, j'ai changé le chemin des vidéos et de la DLL.

[katanes]

Mais quel crétin je fais......... effectivement c 'est du a l adresse de la dll...Non mais c 'est fou merci encore tout est fonctionnel......excellent

Merci beaucoup.....c 'est cool je peut continuer.......
Décidément j 'apprécie de plus en plus la communauté d'autoit

[orax]

Et pour avoir un résultat différent il ne faut pas remplacer Duration par Duration\String comme c'est écrit dans le script, mais plutôt par Duration par Duration/String.

[katanes]

Pour moi c 'est ok merci encore Orax