[R] Combolist + .INI

[jesusip200]

Bonjour,
J'aimerais savoir si c'est possible de faire une combolist dans le script, mes qui lit la liste dans un fichier .ini. Si oui comment faire ?

Le script est très simple, il permettrais juste de sélectionner la page web voulu et l'ouvrir. Mais tout mettre dans un fichier .ini ( Les adresse web + la combolist ) mes dans 2 .ini différent.

Désoler de ma question de débutant. Je suis nouveau dans Autoit et je l'adore. Mes comme on dit, il faut toujours un début a tout.

Je vous remercie énormément de vos réponse d'avance.

[Tlem]

Vous devriez utiliser l'outil de recherche du forum : http://www.autoitscript.fr/forum/search.php
En tapant :

+combo +ini

Cela donne quelques réponses.

[jesusip200]

Ok merci je l'avais fais, mes j'avais manquer ce sujet :

[R] Problème de combo sur un script

Encore merci beaucoup.

Edit :

Bon voila sa marche toujours pas :S

Voici le script j'ai juste mit le principal et changer les mot pour mon privée

Code : Tout sélectionner

Const $INI = @scriptdir & "\db.ini"

$Form1 = GUICreate("Explorer", 171, 68, 322, 311)
$weblist = GUICtrlCreateCombo("Votre liens", 171, 68, 322, 311)
GUICtrlSetData(-1, IniRead($INI, "list", "list1"), "")

Et le fichier db.ini

Code : Tout sélectionner

[list]
list1="Google|Hotmail|Autoit"

[orax]

A première vue, la parenthèse est mal placée.

Code : Tout sélectionner

GUICtrlSetData(-1, IniRead($INI, "list", "list1", ""))

[jesusip200]

Merci beaucoup maintenant sa marche. Je peux continuer le script.

Encore merci.

Edit :

Le script

Code : Tout sélectionner

Const $INI = @scriptdir & "\ini\db.ini"

Func _Start($s_StartPath)
    If @OSTYPE = 'WIN32_NT' Then
        $s_StartStr = @ComSpec & ' /c start "" '
    Else
        $s_StartStr = @ComSpec & ' /c start '
    EndIf
    Run($s_StartStr & $s_StartPath, '', @SW_HIDE)
    If Not @error Then SetError(1)
EndFunc

$Form1 = GUICreate("Explorer", 171, 68, 322, 311)
$weblist = GUICtrlCreateCombo("Votre liens", 8, 8, 153, 25)
GUICtrlSetData(-1, IniRead($INI, "list", "list1", ""))
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $weblist
            Combobox(GuiCtrlRead($weblist))
    EndSwitch
WEnd

Func Combobox($value)
  Switch $value
    Case "Google"
        _Start(IniRead($INI, "web", "web1", ""))
    Case "Youtube"
        _Start(IniRead($INI, "web", "web2", ""))
    Case "Yahoo"
        _Start(IniRead($INI, "web", "web3", ""))
EndSwitch       
EndFunc

Fichier ini

Code : Tout sélectionner

[list]
list1="Google|Youtube|Yahoo"

[web]
web1="http://www.google.ca"
web2="http://www.youtube.com"
web3="http://www.yahoo.com"
 

Voila mon nouveau problème. C'est que j'aimerais pouvoir rajouter des liens par le fichier db.ini. Mes je ne sais pas du tout comment faire. C'est plus compliquer que ce que je penssais. Même a faire des recherche je ne trouve rien.

Dans le genre juste rajouter meebo dans list1 et faire un web4="http://www.meebo.com" et qui ce mettre tout seul dans lle script.

[jesusip200]

Personne sait ? Cars je suis bloquer la Et qui me manque juste sa pour finir le script.

J'ai même essayer de changer la function de la combo comme ceci

Code : Tout sélectionner

Func Combobox($value)
  Switch $value
    Case $weblist
        _Start(IniRead($INI, "web", $weblist, ""))
EndSwitch       
EndFunc
 

Dite moi juste une place, qui pourrais m'expliquer comment faire.

P.S. Vraiment désoler de tout le dérangement.

Edit :

Avais oublier de préciser le changement du .ini

Code : Tout sélectionner

list1="Google|Youtube|Yahoo"

[web]
Google="http://www.google.ca"
Youtube="http://www.youtube.com"
Yahoo="http://www.yahoo.com"
 

[Tlem]

Vous voulez faire un truc dans le genre :

► Afficher le texteFichier .ini

Code : Tout sélectionner

[Google]
Lien = http://www.google.ca

[YouTube]
Lien = http://www.youtube.com

[Yahoo]
Lien = http://www.yahoo.com

[AutoIt Fr]
Lien = http://www.autoitscript.fr

► Afficher le texteScript au3

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Const $INI = @scriptdir & "\ini\db.ini"
If Not FileExists($INI) Then _Erreur()

$Name = IniReadSectionNames($INI) ; Lit le nom de toutes les sections
If Not IsArray($Name) Then _Erreur()

$Form1 = GUICreate("Explorer", 171, 68, 322, 311)
$weblist = GUICtrlCreateCombo("Votre liens", 8, 8, 153, 25)

; Place le nom de toutes les sections dans le combo.
For $i = 1 To UBound($Name) - 1
    GUICtrlSetData($weblist, $Name[$i])
Next

GUISetState(@SW_SHOW) ; Affiche la GUI

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $weblist
            ; Lance le navigateur par défaut avec le lien récupéré.
            ShellExecute(IniRead($INI, GUICtrlRead($weblist), "Lien", ""))

    EndSwitch
WEnd

Func _Erreur()
    MsgBox(32, "Erreur", "Le fichier de configuration n'existe pas ou non valide !!!")
    Exit
EndFunc
 

[jesusip200]

Oui c'est exactement sa merci beaucoup.