[...]Probléme de script aprés démarrage PC

[luffy43]

Bonjour , j'ai un probléme assez bizare , en fait voila , aprés le démarrage (ou le redémarrage) de mon PC , j'éxécute certain scripts ( par exemple script d'automatisation de l'installation d'un logiciel tel que office , adobe , ... ou alors scripts concernant l'automatisation d'un paramétrage systéme tel que changer les paramétres d'alimentation , désactiver la mise en veille , ....) mais à sa premiére execution le script bloque ( et je ne comprends pas pourquoi ) alors que si je l'execute une deuxiéme fois il marche tout à fait normalement.
Voila alors si quelqu'un à une idée qu'il m'aide.
Merci d'avance.

[Iste]

Sans la source, ça va être dure

[luffy43]

Désolés , j'ai effectivement oublié de la mettre voici quelques exemples :

Code : Tout sélectionner

;;;;;AFFICHER RACCOURCI;;;;;;;;;;;;;;
; Début du script - Ajouter votre code ci-dessous.
Send ("#r")
WinWaitActive("Exécuter")
Send("control desktop")
Send("{ENTER}")
WinWaitActive("Propriétés de Affichage","Bureau")
Send("!e")
WinWaitActive("Éléments du Bureau","Général")
Send("!m")
Send("!o")
Send("{ENTER}")
Send("!a")
Send("{ENTER}")

;;;;;;;;;;;Dévérouillage barre des taches et Affichage QuickLaunch ;;;;;;;;;;;;;;;;
Send("#r")
WinWaitActive("Exécuter")
Send("control")
Send("{ENTER}")
WinWaitActive("Panneau de configuration", "Panneau de configuration")
Send("b")
Send("{ENTER}")
WinWaitActive("Propriétés de la Barre des tâches et du menu Démarrer", "Barre des tâches")
Send("v")
Send("l")
Send("{ENTER}")
WinClose("Panneau de configuration")

;;;;;;;;;;;;;;Héritage droits all users;;;;;;;;;;;;;;;
Send ("#r")
WinWaitActive("Exécuter")
Send("C:\Documents and Settings")
Send("{ENTER}")
WinWaitActive("Documents and Settings")
Send("a")
Send("+{F10}")
Send("r")
WinWaitActive("Propriétés de All Users","Général")
Send("{TAB 5}")
Send("{RIGHT}")
WinWaitActive("Propriétés de All Users","Partage")
Send("{RIGHT}")
WinWaitActive("Propriétés de All Users","Sécurité")
Send("!p")
WinWaitActive("Paramètres de sécurité avancé pour All Users")
Send("!p")
Send("!a")
WinWaitActive("Sécurité")
Send("!o")
Sleep(1000)
WinClose("Paramètres de sécurité avancé pour All Users")
WinClose("Propriétés de All Users")
WinClose("Documents and Settings")

[Iste]

heuuu alors la c'est étrange Oo
Je ne vois vraiment pas le probleme.

Les script freez complètement ou plantent ?
Toujours au même endroit ?
Si tu attend un peu après le démarrage, ça passe pas ?
Des exemple de scripts d'autre membres du forum subissent les même effet ?

[orax]

Je ne comprends pas non plus ce que vous entendez par "le script bloque" ; il faudrait plus de précisions. Mais étant donné qu'il y a des WinWaitActive() je suppose qu'il tourne en boucle indéfiniment. Si c'est le cas, pour savoir dans un premier temps à quel endroit du script provient le problème, je vous propose d'ajouter par exemple des MsgBox(0,"",@ScriptLineNumber) à différents endroits du script.

[Tlem]

Rahhh la laaaa ....
Encore une utilisation de paramétrage par GUI .

Sans doute, que votre script est lancé trop tôt et que l'interface graphique de Windows n'est pas totalement démarrée.

Voici la première partie de votre script sans utilisation de l'interface graphique :

► Afficher le texte

Code : Tout sélectionner

#include <WinAPI.au3>
#include <GuiReBar.au3>

Const $PosteDeTravail = "{20D04FE0-3AEA-1069-A2D8-08002B30309D}"
Const $MesDocuments = "{450D8FBA-AD25-11D0-98A8-0800361B1103}"
Const $InternetExplorer = "{871C5380-42A0-1069-A2EA-08002B30309D}"
Const $FavorisReseau = "{208D2C60-3AEA-1069-A2D7-08002B30309D}"
Const $Corbeille = "{645FF040-5081-101B-9F08-00AA002F954E}"

$sRootKey = "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer"
$sKey1 = "\HideDesktopIcons\ClassicStartMenu"
$sKey2 = "\HideDesktopIcons\NewStartPanel"
$sKey3 = "\Advanced"
$iState = 0


RegWrite($sRootKey & $sKey1, $PosteDeTravail, "REG_DWORD", $iState)
RegWrite($sRootKey & $sKey2, $PosteDeTravail, "REG_DWORD", $iState)

RegWrite($sRootKey & $sKey1, $MesDocuments, "REG_DWORD", $iState)
RegWrite($sRootKey & $sKey2, $MesDocuments, "REG_DWORD", $iState)

; TaskBar (Déverrouillé = 1):
RegWrite($sRootKey & $sKey3, "TaskbarSizeMove", "REG_DWORD", 1)
ProcessClose ("Explorer.exe")
ProcessWaitClose("Explorer.exe")
ProcessWait("Explorer.exe")
Sleep(2000)

; Activation du QuickLaunch.
_QuickLaunch_SetState(True)
;_ResizeQuickLaunchBar()  ; A ajouter si necessaire.

ShellExecute(@SystemDir & "\RUNDLL32.EXE", " user32.dll,UpdatePerUserSystemParameters")


;===============================================================================
;
; Function Name:    _QuickLaunch_SetState
; Description:    Enable/disable the quick launch toolbar
; Parameter(s):  $fState - Specifies whether to enable or disable the quick launch toolbar.
;                  True (1) = toolbar is enabled
;                  False (0) = toolbar is disabled
; Requirement(s):   Windows 2000 or XP
; Return Value(s):  Success   - Return value from _SendMessage
;               Failure    - @error is set
;               @error     - 1 = Invalid $fState, 2 = Unable to get handle for Shell_TrayWnd
; Author(s):        Bob Anthony (big_daddy)
;
;===============================================================================
Func _QuickLaunch_SetState($fState)
    Const $WM_USER = 0X400
    Const $WMTRAY_TOGGLEQL = ($WM_USER + 237)

    If $fState <> 0 And $fState <> 1 Then Return SetError(1, 0, 0)

    $hTrayWnd = WinGetHandle("[CLASS:Shell_TrayWnd]")
    If @error Then Return SetError(2, 0, 0)

    Return _SendMessage($hTrayWnd, $WMTRAY_TOGGLEQL, 0, $fState)
EndFunc   ;==>_QuickLaunch_SetState

Func _ResizeQuickLaunchBar()
    Local $iIndex = 0
    Local $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    Local $hRebar = ControlGetHandle($hTaskBar, "", "ReBarWindow321")
    _GUICtrlRebar_MinimizeBand($hRebar, $iIndex)
    _GUICtrlRebar_MaximizeBand($hRebar, $iIndex, True)
EndFunc   ;==>_ResizeQuickLaunchBar
 

Pour la partie partage, vous pouvez faire de même en utilisant les commandes de XP.

[luffy43]

Merci pour votre méthode c'est trés gentil à vous mais j'ai bien peur que je ne puisse reproduir une telle méthode etant donné mon niveau ( 3 semaine que je commence).et si j'intégre mais script à une interface ( à un bouton dans l'interface plus exactement ) vous ne pensez pas que cela résoudra le probléme ?

[SagePourpre]

Si tu nous disais où exactement le script bloque la première fois ... ?

Il ne bloque jamais à la même place, ou c'est toujours au même endroit ?


Sinon, ajoute ceci au début de tes scripts lorsque tu as des problèmes.

Code : Tout sélectionner

Opt("TrayIconDebug",1)

Si jamais un script fonctionne mal, tu n'as qu'à aller sur l'icône du script dans la barre des tâches et une bulle
apparaîtra montrant la ligne sur laquelle le script est rendu (et bloque)