[..] Limiter temps d'execution

[jcaspar]

B onjour à tous !
Je souhaiterais limiter le temps d'execution d'un script à 5 secondes par exemple afin d'eviter un bouclage en cas de problème

Pouvez vous svp m'expliquer si cela est possible et comme dois je procéder.

Merci d'avance pour vos conseils et idées

Jean Marc

[TaPuZ]

Allez, je me lance!
Tout dépend de ce que tu recherches comme sécurité et de la complexité de ton script.
La réponse la plus bateau serait de te dire d'utiliser la commande sleep(5000), pour faire une pause de 5000 ms, soit 5 secondes.
Tu peux aussi imaginer faire une boucle For ... Next, demandant à ton script de s'exécuter un nombre fini de fois.
Tu peux aussi imaginer faire un hotkey en assignant à une touche (ou une combinaison de touches) un appel de fonction de sortie du programme. Ainsi, tu es sur que si tu appuies sur ta touche de raccourci, ton programme s'arrete.
Enfin, tu peux aussi penser à mettre des petites pauses dans tes boucles, histoire de ne pas trop surcharger ton proc lors d'opérations ultra répétitives...
Bref tout dépend de ce que tu recherches exactement, et rien ne t'empêche de tout combiner...
That's up to you...
Voilà, je ne sais pas si j'ai vu juste, mais comme c'était mon 1/4 d'heure je me la pète, j'ai tenté...
A bientôt.
T@PµZ.

[SagePourpre]

Dans le cas où tu veux seulement avoir un moyen d'arrêter le script sans définir préalablement le
nombre d'exécution voulue à l'avance, tu peux utiliser :


Le premier code fonctionne ainsi, tant que tu n'appuies pas sur la touche "END" ou "FIN" du clavier, le script continue
(Cependant, il est fort possible que tu aies à tenir la touche 2-3 secondes pour que ça fonctionne)

Code : Tout sélectionner

#include<misc.au3>

while Not _IsPressed("23")
    MsgBox(0,"Poke system","") ; Code à exécuter 
    Sleep(1000)
    
WEnd

Sinon, ce code fonctionne sensiblement de la même façon

On vérifie la variable $stop à la fin de chaque cycle et, si jamais sa valeur tombe à 1, on sort
de la boucle (dans ce cas parce que la fonction stopscript à été déclenché lorsque la touche "END" ou "FIN"
à été pressée) Dans ce cas,

Code : Tout sélectionner

$stop = 0
HotKeySet("{END}","stopscript")


startscript()


Func startscript()
    While 1
        MsgBox(0,"Poke","",1)
    
        If $stop = 1 Then
                    $stop = 0
            ExitLoop
        EndIf
    Wend
EndFunc

Func stopscript()
$stop = 1
EndFunc

Tout dépend de ce que tu veux faire exactement.

Sinon, tu peux utiliser

For $i = 1 to 5 (où 5 représente le nombres de répétitions à effectuer)
Next

[Iste]

voici une autre facon, pour que ca se fasse tout seul

Code : Tout sélectionner

$temps = TimerInit ( )

AdlibEnable("Temps")

While 1
    Sleep(50)
WEnd

Func Temps()
    If TimerDiff ($temps) > 5000 Then Exit
EndFunc

AdlibEnable("Temps")
Lance la fonction "Temps" toute les 250ms
La fonction "Temps" vérifi le temps écoulé entre le TimerInit() et le TimerDif() (en ms), si c'est sup a 5seconde, on quite

/!\ ca protege des scripts qui tournent en boucle, mais pas des plantages ! /!\

[Tlem]

Toutes ces solutions sont pas mal (celle du AdlibEnable est de loin la plus simple) mais ....

Et oui il y à un mais. AutoIt ne sachant pas gérer le vrai multitâche, il ne peut faire deux choses réellement en parallèle.
Donc dans le cas ou le code principale vient à ce bloquer, le reste du script ne peut s'exécuter et donc point de salut.

La solution pour être sur à 99,99% que le script s'arrête au bout d'un temps déterminé, c'est d'externaliser la partie qui doit contrôler le script principal.

Le principe en lui même est tordu, mais simple. Il suffit au script principal de générer le fichier de contrôle du processus principal et de le lancer. Ensuite le script continue normalement et lorsque le moment est venu, le script de contrôle ferme le script principale.

Mais comme je le dit souvent, un dessin vaut mieux qu'un long discours :

► Afficher le texteKillMyProcess

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

; Lancement de la fonction KillMyProcess
KillMyProcess()

; Création de la GUI du script principal.
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Horloge", 371, 136, 192, 124)
$Label1 = GUICtrlCreateLabel("12:30:00", 8, 8, 356, 113)
GUICtrlSetFont(-1, 72, 800, 0, "Times New Roman")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

; Boucle d'attente du script principal.
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case Else
            ; Affiche l'heure dans la GUI.
            GUICtrlSetData($Label1, @HOUR & ":" & @MIN & ":" & @SEC)
            Sleep(100)

    EndSwitch
WEnd

Func KillMyProcess()
    $CurProcID = _WinAPI_GetCurrentProcessID() ; Récupère le ProcessID du script en cours.
    ; Création du script de fermeture du process.
    $ProcControl = 'Sleep(5000)' & @CRLF
    $ProcControl &= 'ProcessClose(' & $CurProcID & ')' & @CRLF & @CRLF
    ; Cette partie permet l'autodestruction du script de fermeture du process.
    $ProcControl &= '_SelfDelete()' & @CRLF
    $ProcControl &= 'Func _SelfDelete($iDelay = 0)' & @CRLF
    $ProcControl &= '    Local $sCmdFile' & @CRLF
    $ProcControl &= '    FileDelete(@TempDir & "\scratch.bat")' & @CRLF
    $ProcControl &= '    $sCmdFile = "ping -n " & $iDelay & "127.0.0.1 > nul" & @CRLF'
    $ProcControl &= ' & ":loop" & @CRLF '
    $ProcControl &= '& "del " & Chr(34) & @ScriptFullPath & Chr(34) & @CRLF'
    $ProcControl &= '& "if exist " & Chr(34) & @ScriptFullPath & Chr(34) & " goto loop" & @CRLF'
    $ProcControl &= '& "del " & @TempDir & "\scratch.bat"' & @CRLF
    $ProcControl &= '    FileWrite(@TempDir & "\scratch.bat", $sCmdFile)' & @CRLF
    $ProcControl &= '    Run(@TempDir & "\scratch.bat", @TempDir, @SW_HIDE)' & @CRLF
    $ProcControl &= 'EndFunc' & @CRLF

    ; Ecriture du fichier KillMyProcess.au3
    If FileExists(@TempDir & "\KillMyProcess.au3") Then FileDelete(@TempDir & "\KillMyProcess.au3")
    FileWrite(@TempDir & "\KillMyProcess.au3", $ProcControl)

    ; Cette partie permet de lancer le script KillMyProcess.au3
    If Not @Compiled Then
        ShellExecute(@AutoItExe, @TempDir & "\KillMyProcess.au3" ) ; Cas ou le script n'est pas compilé.
    Else
        ShellExecute(@ScriptFullPath, "/AutoIt3ExecuteScript " & @TempDir & "\KillMyProcess.au3") ; Cas ou le script est compilé.
    EndIf
EndFunc

; Cette fonction récupérée du Winapi.au3 permet de récupérer le ProcessID du script en cours.
Func _WinAPI_GetCurrentProcessID()
    Local $aResult

    $aResult = DllCall("Kernel32.dll", "int", "GetCurrentProcessId")
    If @error Then Return SetError(@error, 0, 0)
    Return $aResult[0]
EndFunc   ;==>_WinAPI_GetCurrentProcessID