[R] Modifier le texte selectionné

[Thomas33]

Salut à tous!!!

J'ai un petit soucis, j'aimerais faire un petit script avec une GUI ou je pourrais écrire dans une partie (1) du texte. Pour pouvoir le modifier (Gras, couleur, italique, souligné) et ensuite en cliquant sur un boutons écrire le texte modifier dans un fichier mais avec des balises html c'est à dire pour un texte en gras je voudrais que le texte apparraisse <b>mon texte</b> dans le fichier texte.

Mon soucis c'est que je ne connais pas la fonction qui permet de modifier la selection effectuer avec la souris. Quelqu'un a une idée??

Merci d'avance pour votre aide j'espere que j'ai été assez clair sinon je recomenceré

Thomas

[jl56]

bonjour

Désolé mais j'aime pas ta pancarte

salut

[Tlem]

L'idée serait sans doute de faire un contrôle Input, puis en dessous des checkbox ou des boutons représentants la mise en forme du texte.
Lors du choix, vous effectuez la modification au texte de l'InputBox, mais il vous faut conserver l'information sous forme de variable.

Lors d'un clic sur le bouton écrire par exemple, avec les variables de mise en forme de votre texte, vous appliquez l'ajout des variables comme il se doit.

[jbnh]

Salut

@Tlem, je pense qu'il a bien compris. Mais ce qu'il veut savoir, et ce que je ne sais pas non plus, c'est comment mettre en forme le texte sélectionné avec la souris, ou dit autrement : comment détecter le texte sélectionné de la souris.

[Tlem]

Humm.
Effectivement, il parle de sélection de texte, mais peut-être n'avait-il pas envisagé de créer un simple champ input pour y placer son texte et créer les modifications à envoyer au fichier, car si je comprend bien, il voudrait faire de la mise en forme de texte pour le placer dans une page HTML.

C'est un peut comme le principe de ForumColor (par voodoo) mais en gérant le style du texte.

[Voodoo]

Oui ? Qui m'appelle ?

Pour la sélection il y a _GUICtrlEdit_GetSel() si tu as un edit. Après pour le modifier tu as _GUICtrlEdit_SetSel(). Je suppose que dans ton logiciel il y a un edit à gauche avec le texte en clair et à droite un objet IE pour le rendu en html.

[Thomas33]

D'abord je voudrais vous remercie de m'avoir répondus.

Par contre je n'ai pas trouver la commande _GUICtrlEdit_GetSel() dans la doc de autoit normal ?

parce que je ne vois pas trop comment l'utiliser

Merci a vous si vous pouvez m'aider


Thomas

EDIT de moi

c'est bon j'ai trouver la commande dans la doc mais je ne comprends pas du tous comment elle fonctionne si quelqu'un peut me venir en aide merci d'avance

[orax]

Ca semblerait marcher en utilisant StringMid().

Edité : correction de l'erreur dans mon code.

► Afficher le texte

Code : Tout sélectionner

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_Ed = False ; Check ClassName being passed to Edit functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $StatusBar, $hEdit, $hGUI
;~  Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"
    Local $aPartRightSide[3] = [190, 378, -1], $aSel
    
    ; Create GUI
    $hGUI = GUICreate("Edit Get Sel", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $StatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($StatusBar, 2, 97, "shell32.dll")
    GUISetState()

    ; Set Margins
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Set Text
    _GUICtrlEdit_SetText($hEdit, "test.123456789")

    ; Set Sel
    _GUICtrlEdit_SetSel($hEdit, 1, 5)
    Sleep(2000)
    
    ; Get Sel
    $aSel = _GUICtrlEdit_GetSel($hEdit)
    _GUICtrlStatusBar_SetText($StatusBar, "Start: " & $aSel[0])
    _GUICtrlStatusBar_SetText($StatusBar, "End: " & $aSel[1], 1)
    
    Local $txt=_GUICtrlEdit_GetText($hEdit)
    Local $txtSel=StringMid($txt,$aSel[0]+1,$aSel[1]-$aSel[0])
    MsgBox(0,$aSel[0]+1 & " " & $aSel[1],$txtSel)
    
    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

[Voodoo]

Code : Tout sélectionner

#include <GuiEdit.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>


GUICreate("Edit Set Sel",400 , 300)
$Edit = GUICtrlCreateEdit("Lorem ipsum dolor sit amet, consectetur adipisicing elit, sed do eiusmod ", 2, 2, 394, 268)

$but=GUICtrlCreateButton("Lire selection",320,270)
GUISetState()

while 1
    $msg=GUIGetMsg()
    Switch  $msg
        case $GUI_EVENT_CLOSE
            ExitLoop
        case $but
            $ret=_GUICtrlEdit_GetSel($Edit)
            msgbox(0,"Selection", StringMid(guictrlread($Edit),$ret[0],$ret[1]-$ret[0]))
    EndSwitch
WEnd
 

_GUICtrlEdit_GetSel() renvoie un tableau. Le premier élément est la position de départ dans la chaine de la sélection et le second sa position final. Donc si je soustrais les deux j'ai la longueur de ma sélection.

[Thomas33]

Merci beaucoup de votre aide je vais voir ce que je peux faire avec tous vos conseils encore Merci