[R] Tri ascendant/descendant d'une ListView avec icônes

[orax]

Bonjour, j'ai une ListeView dans laquelle il y a des icônes. Le problème c'est que quand un élément change de place (quand je trie la liste) l'icône de l'élément reste à la même place.

J'ai ajouté _GUICtrlListView_RegisterSortCallBack pour qu'on puisse trier la liste quand on clique sur une colonne. Ca trie bien ma liste mais quand un élément est ajouté, celui-ci n'est pas trier, je dois le faire manuellement (ce que je fais avec la fonction trieListe()). Le problème c'est qu'en faisant comme ça, comme je l'ai dit plus haut, l'icône ne change pas de place.

► Afficher le textepour voir un exemple

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <GuiStatusBar.au3>
#include <Process.au3>
#include <Constants.au3>
#include <Date.au3>
#include <WinAPI.au3>
#include <GuiHeader.au3>

;~ Opt('MustDeclareVars', 1)
Opt("GUIOnEventMode", 1)
Opt("GUICloseOnESC", 1)

; // // // // // // // // // // // // // // // // // // // // //
; //
; //
; // déclaration des variables
; //
; //
; // // // // // // // // // // // // // // // // // // // // //
Global $a_listeProcessus[1][10]
Global $a_listeProcessusMAJ[1][10]
Global $a_listViewItems[1]

Global $indexColonne = -1

; // // // // // // // // // // // // // // // // // // // // //
; //
; //
; // création de l'interface graphique
; //
; //
; // // // // // // // // // // // // // // // // // // // // //
Global $fenetrePrincipale = GUICreate( _
        "ListView Click Item", _
        600, 450, -1, -1, _
        BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))

;~ Global $idListView = GUICtrlCreateListView("Nom|PID|Priorité|Emplacement", _
;~      0, 0, 600, 320, _
;~      BitOR($GUI_DOCKBOTTOM, $LVS_SORTASCENDING))

Global $idListView = GUICtrlCreateListView("Nom|PID|Priorité|Emplacement", _
        0, 0, 600, 320, _
        $GUI_DOCKBOTTOM)

Global $hListView = GUICtrlGetHandle($idListView)

GUISetOnEvent($GUI_EVENT_CLOSE, "Quitte")

; //
; //
; // chargement de la liste des programmes
; //
; //
initialise_listeProcessus()

; //
; //
; // chargement des notifications
; //
; //
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

; //
; //
; // divers
; //
; //
_GUICtrlListView_RegisterSortCallBack($hListView)

GUISetState() ; affiche l'interface graphique

; //
; //
; // >>> exemple pour montrer le problème
; //
; //
MsgBox(0,"","La liste des processus est chargée")
$indexColonne=0
_GUICtrlListView_SortItems($hListView, $indexColonne) ; trie une la liste
MsgBox(0,"","La liste des processus viens d'être triée avec _GUICtrlListView_SortItems()")
Run("notepad")
WinWait("Sans titre - Bloc-notes")
rafraichitListeProgrammes()
MsgBox(0,"","Notepad est lancé, la liste viens d'être rafraichie mais le processus s'affiche en bas de celle-ci, il faut donc la trier...")
trieListe()
MsgBox(0,"Et c'est le drame !","Problème : l'icône de Notepad s'affiche en bas... De plus, l'icône de Notepad qui vient d'être trié n'est pas celle de Notepad.")

; //
; //
; // boucle principale
; //
; //
While 1
    rafraichitListeProgrammes()

    Sleep(1000)
WEnd

Func rafraichitListeProgrammes()
    Local $i, $index
    Local $horsTableau = False
    Local $elementAjoute = False

    ; met à jour la liste des processus
    $a_listeProcessusMAJ = ProcessList()

    ReDim $a_listeProcessusMAJ[UBound($a_listeProcessusMAJ)][10]
    $a_listeProcessusMAJ[0][0] = "idle"
   
    $total_a_listeProcessus = UBound($a_listeProcessus) - 1
    $total_a_listeProcessusMAJ = UBound($a_listeProcessusMAJ) - 1

    ; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
    ; *
    ; *
    ; * ajoute dans la liste les processus nouvellement créés
    ; *
    ; *
    ; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
    ;
    ;
    ReDim $a_listViewItems[$total_a_listeProcessusMAJ + 1]
   
    For $i = 0 To $total_a_listeProcessusMAJ
        If $total_a_listeProcessus >= $i Then ; vérifie qu'on ne dépasse pas les limites de la taille du tableau
            ; si le PID ne correspond pas ou...
            ; si le nom du processus ne correspond pas
            ; alors il faut rechercher le processus dans tout le tableau
            ; s'il n'a pas été trouvé il faut l'ajouter dans la liste
            If $a_listeProcessus[$i][1] <> $a_listeProcessusMAJ[$i][1] Or _
                    $a_listeProcessus[$i][0] <> $a_listeProcessusMAJ[$i][0] Then
                ; recherche le processus
                $index = _ArraySearch($a_listeProcessus, _
                        $a_listeProcessusMAJ[$i][1], _
                        0, 0, 0, 0, 1, 1)
            EndIf
        Else
            $horsTableau = True
        EndIf
       
        ; si le processus n'a pas été trouvé alors
        ; il faut l'ajouter dans la liste
        If $index = -1 Or $horsTableau Then
            $a_listeProcessusMAJ[$i][7] = recupereEmplacementProcessus($a_listeProcessusMAJ[$i][1])
           
            ; ajoute les éléments concernant le processus dans les colonnes
            $a_listViewItems[$i] = GUICtrlCreateListViewItem( _ ; $i + 1 car le 0 compte
                    $a_listeProcessusMAJ[$i][0] & "|" & _ ; nom du processus
                    $a_listeProcessusMAJ[$i][1] & "|" & _ ; PID
                    $a_listeProcessusMAJ[$i][6] & "|" & _ ; priorité
                    $a_listeProcessusMAJ[$i][7], _ ; emplacement
                    $idListView)
           
;~          trieListe()

            If $a_listeProcessusMAJ[$i][7] Then GUICtrlSetImage($a_listViewItems[$i], $a_listeProcessusMAJ[$i][7], 0) ; ajoute des images
           
            $index = UBound($a_listViewItems) - 1
        Else
            $index = $i ; index de l'élément (celui en cours)
        EndIf
    Next

    ; met à jour l'ancien tableau qui contient la liste des programmes
    $a_listeProcessus = $a_listeProcessusMAJ

;~  If $elementAjoute Then trieListe() ; si un élément a été ajouté alors il faut trier la liste

EndFunc   ;==>rafraichitListeProgrammes

Func initialise_listeProcessus()
    Local $i, $index

    ; met à jour la liste des processus
    $a_listeProcessus = ProcessList()
    ReDim $a_listeProcessus[UBound($a_listeProcessus)][10]
   
    $a_listeProcessus[0][0] = "idle"
    ReDim $a_listViewItems[UBound($a_listeProcessus)]
   
    ; *
    ; * ajoute dans la liste les processus nouvellement créés
    ; *
    For $i = 0 To UBound($a_listeProcessus) - 1
        $a_listeProcessus[$i][7] = recupereEmplacementProcessus($a_listeProcessus[$i][1])

        $prioriteProcessus = $a_listeProcessus[$i][6] ; priorité
        If @error Then $prioriteProcessus = 6

        ; ajoute les éléments concernant le processus dans les colonnes
        $a_listViewItems[$i] = GUICtrlCreateListViewItem( _
                $a_listeProcessus[$i][0] & "|" & _ ; nom du processus
                $a_listeProcessus[$i][1] & "|" & _ ; PID
                $prioriteProcessus & "|" & _ ; priorité
                $a_listeProcessus[$i][7], _ ; emplacement
                $idListView)
       
        If $a_listeProcessus[$i][7] Then GUICtrlSetImage(-1, $a_listeProcessus[$i][7], 0) ; ajoute des images

        If $a_listeProcessus[$i][4] = 0 Then ; si le processus n'est pas en suspend
            GUICtrlSetBkColor($a_listViewItems[$i], _
                    $GUI_BKCOLOR_TRANSPARENT)
        Else ; si le processus est en suspend
            GUICtrlSetBkColor($a_listViewItems[$i], _
                    0xff0000)
        EndIf
    Next
   
    ; taille automatique des colonnes
    For $i = 0 To _GUICtrlListView_GetColumnCount($hListView) - 1
        _GUICtrlListView_SetColumnWidth($hListView, $i, $LVSCW_AUTOSIZE)
    Next

;~  trieListe()
EndFunc   ;==>initialise_listeProcessus

Func recupereEmplacementProcessus($pid)
    Local $processus, $modulesProcessus, $r

    $processus = DllCall("kernel32.dll", "hwnd", "OpenProcess", _
            "int", BitOR($PROCESS_QUERY_INFORMATION, $PROCESS_VM_READ), _
            "int", 0, _
            "int", $pid)
    If $processus[0] = 0 Then Return SetError(1)

    $modulesProcessus = DllStructCreate("int[1024]")
   
    DllCall("psapi.dll", "int", "EnumProcessModules", _
            "hwnd", $processus[0], _
            "ptr", DllStructGetPtr($modulesProcessus), _
            "int", DllStructGetSize($modulesProcessus), _
            "int_ptr", 0)

    $r = DllCall("psapi.dll", "int", "GetModuleFileNameEx", _
            "hwnd", $processus[0], _
            "int", DllStructGetData($modulesProcessus, 1), _
            "str", "", _
            "int", 2048)
   
    $modulesProcessus = 0
   
    If StringLen($r[3]) = 0 Then Return SetError(1)

    Return $r[3]
EndFunc   ;==>recupereEmplacementProcessus

Func supprimeProcessusDeLaListe($index)
    GUICtrlDelete($a_listViewItems[$index]) ; supprime l'élément de la liste
    _ArrayDelete($a_listViewItems, $index) ; supprime l'élément du tableau
EndFunc   ;==>supprimeProcessusDeLaListe

; supprime tous les éléments de la liste
Func supprimeTousLesElementsDansListe()
    For $i = 0 To UBound($a_listViewItems) - 1
        GUICtrlDelete($a_listViewItems[$i]) ; supprime l'élément de la liste
    Next
   
    ReDim $a_listViewItems[1]
    $a_listViewItems[0] = ""
   
    ; la liste a été vidée alors
    ; on vide également l'ancien tableau des processus
    ReDim $a_listeProcessus[1][1]
    $a_listeProcessus[0][0] = 0
    ReDim $a_listeProcessus[1][10]
EndFunc   ;==>supprimeTousLesElementsDansListe

; // // // // // // // // // // // // // // // // // // // // //
; //
; //
; // >>> fonction qui semble poser problème
; //
; //
; // // // // // // // // // // // // // // // // // // // // //
Func trieListe()
    Local $ordreTrie

    If $indexColonne <> -1 Then
        $ordreTrie = _GUICtrlHeader_GetItemFormat(_GUICtrlListView_GetHeader($hListView), $indexColonne)
        If BitAND($ordreTrie, $HDF_SORTUP) Then
            $ordreTrie = False
        Else
            $ordreTrie = True
        EndIf

        _GUICtrlListView_SimpleSort($hListView, $ordreTrie, $indexColonne)
    EndIf
EndFunc   ;==>trieListe

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
   
    Local $hWndFrom, $iCode, $iIDFrom, $tNMHDR, $hWndListView, $tInfo, $index, $indexListe
   
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
   
    Switch $hWndFrom
        ; ListView
        Case $hWndListView
            Switch $iCode
                Case $LVN_COLUMNCLICK
                    ;
                    ; clic sur une colonne de la liste
                    ;
                    ; http://msdn.microsoft.com/en-us/library ... #40;VS.85&#41;.aspx
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
                    $indexColonne = DllStructGetData($tInfo, "SubItem")
                   
                    _GUICtrlListView_SortItems($hListView, $indexColonne) ; trie la liste
            EndSwitch
    EndSwitch
   
    $actionEnCours = False
   
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func quitte()
    _GUICtrlListView_UnRegisterSortCallBack($hListView)
   
    GUIDelete()
   
    Exit
EndFunc   ;==>quitte

[Iste]

heu... chez moi ca marche ^^' apres l'ouverture de notepad et avant le message qui dit qu'il y a un probleme, la liste est bien retriée par nom et notepad remonte :/
ou alors j'ai pas compris le probleme ?

[orax]

heu... chez moi ca marche ^^' apres l'ouverture de notepad et avant le message qui dit qu'il y a un probleme, la liste est bien retriée par nom et notepad remonte :/
ou alors j'ai pas compris le probleme ?

Quand notepad est remonté, son icône n'est pas la bonne (je viens de le préciser dans le code) : notepad prend l'icône d'un autre processus, et le dernier processus dans la liste prend l'icône de notepad. En gros, le nom du processus (notepad.exe) est bien remonté (trié) mais pas son icône.

Je viens de remarquer autre chose : tous les icônes qui suivent notepad.exe (après avoir été trié) sont décalés, ils ne correspondent pas à leur processus.

[Iste]

Ha oui, effectivement, j'ai bien le meme bug.
Beh, je jette un coup d'oeil alors, mais si ta fonction d'ini marche, il doit juste avoir un petit bug dans la MAJ de la liste...

Sinon, un peu barbar mais qui marche, tu peux tout supprimer et tout recreer (ca m'a l'air plutot rapide)

[GaRydelaMer]

Bonjour

moi de ce que j'ai compris de ton script, tu fais le tri mais avec 2 fonction différentes.

Au début
_GUICtrlListView_SortItems($hListView, $indexColonne) ; trie une la liste

Puis dans ta fonction Trie

_GUICtrlListView_SimpleSort($hListView, $ordreTrie, $indexColonne)

Peut être que l'erreur viens de la !!!

[orax]

Oui, en effet l'erreur viens du fait que j'utilise deux fonctions différentes. Le problème est que quand j'utilise _GUICtrlListView_SortItems() une première fois, il me trie la liste par ordre alphabétique et si je le réutilise une deuxième fois la liste sera trié dans le sens contraire. Visiblement avec cette fonction il n'est pas possible de spécifier l'ordre de tri et c'est pour cette raison que j'avais utilisé une deuxième fonction.
Je crois toutefois que le problème est résolu, cette fois je n'utilise qu'une seule et même fonction.

Merci de votre aide. Je ne sais pas s'il y a un autre moyen de faire mais ça semble fonctionner comme ça.

Voilà les fonctions que j'ai dû ajouter (en gros, j'ai modifié la fonction de tri dans l'UDF qui inversait l'ordre de tri à chaque fois) :

► Afficher le texte

Code : Tout sélectionner

Func trieListe()
    Local $ordreTrie

    If $indexColonne <> -1 Then
        $ordreTrie = _GUICtrlHeader_GetItemFormat(_GUICtrlListView_GetHeader($hListView), $indexColonne)
        If BitAND($ordreTrie, $HDF_SORTUP) Then
            $ordreTrie = False
        Else
            $ordreTrie = True
        EndIf
        
        ; ****
        ; *
        ; * utilise la nouvelle fonction
        ; *
        ; ****
        __GUICtrlListView_SortItems($hListView, $indexColonne)
;~      _GUICtrlListView_SimpleSort($hListView, $ordreTrie, $indexColonne)
    EndIf
EndFunc   ;==>trieListe

Func __GUICtrlListView_SortItems($hWnd, $iCol)
    Local $iResult, $iIndex, $pFunction, $hHeader, $iFormat

    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    For $x = 1 To $aListViewSortInfo[0][0]
        If $hWnd = $aListViewSortInfo[$x][1] Then
            $iIndex = $x
            ExitLoop
        EndIf
    Next
    
;~  $aListViewSortInfo[$iIndex][2] = _
;~          DllCallbackRegister("_GUICtrlListView_Sort", "int", "int;int;hwnd") ; Handle of callback

    ; ****
    ; *
    ; * je remplace ici la fonction de callback pour trier la liste par celle modifiée : __GUICtrlListView_Sort
    ; *
    ; ****
    $pFunction = DllCallbackGetPtr(DllCallbackRegister("__GUICtrlListView_Sort", "int", "int;int;hwnd")) ; get pointer to call back
;~  $pFunction = DllCallbackGetPtr($aListViewSortInfo[$iIndex][2]) ; get pointer to call back
    $aListViewSortInfo[$iIndex][3] = $iCol ; $nColumn = column clicked
    $aListViewSortInfo[$iIndex][7] = 0 ; $bSet
    $aListViewSortInfo[$iIndex][4] = $aListViewSortInfo[$iIndex][6] ; nCurCol = $nCol
    $iResult = _SendMessage($hWnd, $LVM_SORTITEMS, $hWnd, $pFunction, 0, "hwnd", "ptr")
    If $iResult <> 0 Then
        If $aListViewSortInfo[$iIndex][9] Then ; Use arrow in header
            $hHeader = $aListViewSortInfo[$iIndex][10]
            For $x = 0 To _GUICtrlHeader_GetItemCount($hHeader) - 1
                $iFormat = _GUICtrlHeader_GetItemFormat($hHeader, $x)
                If BitAND($iFormat, $HDF_SORTDOWN) Then
                    _GUICtrlHeader_SetItemFormat($hHeader, $x, BitXOR($iFormat, $HDF_SORTDOWN))
                ElseIf BitAND($iFormat, $HDF_SORTUP) Then
                    _GUICtrlHeader_SetItemFormat($hHeader, $x, BitXOR($iFormat, $HDF_SORTUP))
                EndIf
            Next
            $iFormat = _GUICtrlHeader_GetItemFormat($hHeader, $iCol)
            If $aListViewSortInfo[$iIndex][5] = 1 Then ; ascending
                _GUICtrlHeader_SetItemFormat($hHeader, $iCol, BitOR($iFormat, $HDF_SORTUP))
            Else ; descending
                _GUICtrlHeader_SetItemFormat($hHeader, $iCol, BitOR($iFormat, $HDF_SORTDOWN))
            EndIf
        EndIf
    EndIf

    Return $iResult <> 0
EndFunc   ;==>__GUICtrlListView_SortItems

Func __GUICtrlListView_Sort($nItem1, $nItem2, $hWnd)
    Local $iIndex, $tInfo, $val1, $val2, $nResult
    $tInfo = DllStructCreate($tagLVFINDINFO)
    DllStructSetData($tInfo, "Flags", $LVFI_PARAM)

    For $x = 1 To $aListViewSortInfo[0][0]
        If $hWnd = $aListViewSortInfo[$x][1] Then
            $iIndex = $x
            ExitLoop
        EndIf
    Next

; ****
; *
; * je pense que c'est ici que le l'ordre de trie sera inversé, ce que je ne veux pas
; *
; ****
;~  ; Switch the sorting direction
;~  If $aListViewSortInfo[$iIndex][3] = $aListViewSortInfo[$iIndex][4] Then ; $nColumn = nCurCol ?
;~      If Not $aListViewSortInfo[$iIndex][7] Then ; $bSet
;~          $aListViewSortInfo[$iIndex][5] *= -1 ; $nSortDir
;~          $aListViewSortInfo[$iIndex][7] = 1 ; $bSet
;~      EndIf
;~  Else
;~      $aListViewSortInfo[$iIndex][7] = 1 ; $bSet
;~  EndIf
    $aListViewSortInfo[$iIndex][6] = $aListViewSortInfo[$iIndex][3] ; $nCol = $nColumn
    DllStructSetData($tInfo, "Param", $nItem1)
    $val1 = _GUICtrlListView_FindItem($hWnd, -1, $tInfo)
    DllStructSetData($tInfo, "Param", $nItem2)
    $val2 = _GUICtrlListView_FindItem($hWnd, -1, $tInfo)
    $val1 = _GUICtrlListView_GetItemText($hWnd, $val1, $aListViewSortInfo[$iIndex][3])
    $val2 = _GUICtrlListView_GetItemText($hWnd, $val2, $aListViewSortInfo[$iIndex][3])
    If $aListViewSortInfo[$iIndex][8] Then ; Treat As Number
        If (StringIsFloat($val1) Or StringIsInt($val1)) Then $val1 = Number($val1)
        If (StringIsFloat($val2) Or StringIsInt($val2)) Then $val2 = Number($val2)
    EndIf

    $nResult = 0 ; No change of item1 and item2 positions

    If $val1 < $val2 Then
        $nResult = -1 ; Put item2 before item1
    ElseIf $val1 > $val2 Then
        $nResult = 1 ; Put item2 behind item1
    EndIf

    $nResult = $nResult * $aListViewSortInfo[$iIndex][5] ; $nSortDir

    Return $nResult
EndFunc   ;==>__GUICtrlListView_Sort