[Ex] Recherche Google

[DJSIR]

Bonjour, je viens de faire un petit script très petit mais utile. Il permet de lancer une recherche sur Google via une InputBox.

Google Search

► Afficher le texteScript

Code : Tout sélectionner

#Include <IE.au3>

$app_name = "Google Search"

Dim $s_iptBox
$s_iptBox = InputBox($app_name,"Recherche Google :")
If $s_iptBox = "" Then
    MsgBox ( 0, $app_name, "Vous n'avez rien entré.")
Else
    _GoogleSearch($s_iptBox)
EndIf

Exit

Func _GoogleSearch($strSearch)
    Local $o_IE
    $strSearch = StringReplace($strSearch," ","+")
    $o_IE = _IECreate ("http://www.google.fr/search?hl=fr&q=" & $strSearch & "")
EndFunc

Franchement, je m'en sert tous les jours. Il est rapide et éfficace.
Tout commentaire bon ou mauvais est le bienvenu !

[jbnh]

C'est pratique, mais bon nombre de personnes ont comme 'home page' google sur leur navigateur internet. Ca serait nettement plus intéressant si il y avait des options du genre : pages francaises uniquement, publié ces dernieres 24h, etc.

[olaiv]

Salut j'ai bien aimé ton idée de recherche rapide sur Google du coup j'ai crée un petit script sur les bases du tien avec notamment une recherche selon la langue comme le suggérait jbnh.

J'ai également ajouté la possibilité de faire la recherche sur Google web , images ou actualitées.

► Afficher le texte

Code : Tout sélectionner

#include <IE.au3>
#include <GUIConstants.au3>


$sServeurWeb = ""
$sLien = ""
$sLangue=""

$hGui = GUICreate("Recherche Google", 380, 180)

$hInput = GUICtrlCreateInput("", 15, 15,220,20)

GUICtrlCreateGroup("Filtrer les résultats selon la langue", 10, 50, 200, 110)
GUIStartGroup()
$hRadioToute=GUICtrlCreateRadio("Par défaut",30,70)
GUICtrlSetState($hRadioToute, $GUI_CHECKED)

$hRadioFr = GUICtrlCreateRadio("Francais", 30, 100)
$hRadioEn = GUICtrlCreateRadio("Anglais", 30, 130)
$hRadioDe = GUICtrlCreateRadio("Allemand", 130, 100)
$hRadioEs = GUICtrlCreateRadio("Espagnol", 130, 130)

GUICtrlCreateGroup("Type de recherche", 230, 50, 130, 110)
GUIStartGroup()
$hRadioTypeRechercheWeb = GUICtrlCreateRadio("Web", 250, 70)
GUICtrlSetState($hRadioTypeRechercheWeb, $GUI_CHECKED)
$hRadioTypeRechercheActualitees = GUICtrlCreateRadio("Actualitées", 250, 100)
$hRadioTypeRechercheImages = GUICtrlCreateRadio("Images", 250, 130)


$hLancerRecherche = GUICtrlCreateButton("Lancer la recherche", 250, 12)
GUICtrlSetState($hLancerRecherche, $GUI_FOCUS + $GUI_DEFBUTTON)


GUISetState()
Do
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $hLancerRecherche
            _lancerRecherche()
            
    EndSelect
Until $nMsg = $GUI_EVENT_CLOSE


Func _IsChecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

Func _lancerRecherche()
    
    If StringIsSpace(GUICtrlRead($hInput)) Or GUICtrlRead($hInput)="" Then 
        MsgBox(8208,"Erreur","Le champ de recherche ne doit pas être vide.")
        Return False
    EndIf
        
    Select
        Case _IsChecked($hRadioFr)
            $sLangue="fr"
            $sFinLien="&btnG=Rechercher&meta=lr%3Dlang_"& $sLangue
            
        Case _IsChecked($hRadioEn)
            $sLangue="en"
            $sFinLien="&btnG=Rechercher&meta=lr%3Dlang_"& $sLangue
            
        Case _IsChecked($hRadioEs)
            $sLangue="es"
            $sFinLien="&btnG=Rechercher&meta=lr%3Dlang_"& $sLangue
            
        Case _IsChecked($hRadioDe)
            $sLangue="de"
            $sFinLien="&btnG=Rechercher&meta=lr%3Dlang_"& $sLangue
            
        Case _IsChecked($hRadioToute)
            $sLangue=""
            $sFinLien="&btnG=Rechercher&meta=lr%3D"
            
    EndSelect
    
    Select
        Case _IsChecked($hRadioTypeRechercheWeb)
            $sServeurWeb = "http://www.google.fr/search?hl=fr"
            
        Case _IsChecked($hRadioTypeRechercheImages)
            $sServeurWeb = "http://images.google.fr/images?hl="&$sLangue
            
        Case _IsChecked($hRadioTypeRechercheActualitees)
            $sServeurWeb = "http://news.google.fr/news?hl="&$sLangue
    EndSelect
    
    $sContenuRecherche ="&q=" & GUICtrlRead($hInput)
    $sLien = $sServeurWeb &  $sContenuRecherche & $sFinLien
    $oIE = _IECreate($sLien)
EndFunc   ;==>_lancerRecherche

Par contre je ne vois pas pourquoi mais parfois le script se bloque et le clic sur le bouton ne répond plus ...
Si quelqu'un à une idée pour ca merci

[timmalos]

J'ai éfféctué une petite modification:

--->>> Plus besoin de l'UDF IE.au3
--->>> Lance la recherche sur le navigateur par défaut, qui est utile pour ceux qui associent Internet Explorer avec J'aime pas.

rechercheGoogle.au3

(2.56 Kio) Téléchargé 333 fois

Je vous poste également un script que j'avasi fait et qui traduit un mot en plusieurs langues en utilisant la traduction voilà, qui est la meilleur à mon avis.

► Afficher le texteTraduction Voila

Code : Tout sélectionner

#include <String.au3>
$txt = InputBox("","Texte a traduire",""," 300")
$langue = InputBox("","Traduction","fe")
Inetget("http://tr.voila.fr/traduction_voila.php?isText=1&translationDirection="&$langue&"&stext="&$txt,@ScriptDir & "\tr.txt",1)
$l = Fileopen(@ScriptDir & "\tr.txt",0)
$texte = Fileread($l)
$new = _StringBetween($texte,'<div class="txtTrad">','</div>')
Msgbox(0,"Texte Traduit",$new[0])
Fileclose($l)
FileDelete(@ScriptDir & "\tr.txt")

Pour l'inputbox demandant la traduction,
fe signifie french to english
si vous voulez Anglais vers francais, il faut mettre ef
Si vous voulez francais vers allemand, il faut mettre fg
Si vous voulez francais vers espagnol, il faut mettre fs

[DJSIR]

Désole de ne pas avoir répondu plutôt. J'ai des problèmes de connection en ce moment. Peut pas tester script je suis pas sur mon pc. En tous cas ça a l'air vraimant bien

[fabricel]

@timalos : Le script marche super. Si j'ai le temps je rajouterai une option qui permettra de dire si un site donné est présent dans les resultats de recherche.
Il faudra naviguer sur les différentes pages et chercher une url dans les liens...
Rien de bien méchant je pense (mais en même temps je suis juste à ma première utilisation de autoit )

[LELIEVRE]

Une traduction avec Google serait aussi bienvenue...

[jbnh]

http://www.autoitscript.fr/forum/viewto ... f=6&t=1208

mais aucune idée de si il marche encore

[Dan]

Bonjour,
Superbe idée !
Juste une remarque : j'utilise souvent les " " sous Google, et avec le script, ça coince.
Si vous avez une idée ?