[App]Dictionnaires en ligne

Numeric · #1

Titre de l'Application: Dictionnaire en ligne avec Vérification de la Connexion Internet

L'application "Dictionnaire en ligne avec Vérification de la Connexion Internet" est une application simple et utile développée en AutoIt. Elle permet aux utilisateurs de rechercher des définitions de mots en ligne à partir de trois dictionnaires populaires (LeRobert, TV5 dico et Larousse). En outre, l'application vérifie également la connexion Internet de l'utilisateur.

Caractéristiques Principales:

1. Recherche de Définitions de Mots: Les utilisateurs peuvent saisir un mot dans la zone de texte et choisir l'un des trois dictionnaires disponibles dans la liste déroulante. L'application récupère la définition du mot à partir du dictionnaire sélectionné en utilisant des fonctions de recherche.

2. Conversion d'Entités HTML: L'application prend en charge la conversion des entités HTML courantes vers leurs caractères correspondants. Cela permet d'afficher des définitions de mots contenant des entités HTML de manière lisible.

3. Indicateur de Connexion Internet:** L'application vérifie la connexion Internet en tentant de résoudre le nom de domaine de Google. Un indicateur de couleur verte ou rouge est affiché à côté du bouton "Rechercher" pour indiquer si l'utilisateur est connecté à Internet.

4. Interface Utilisateur Conviviale: L'interface utilisateur de l'application est simple et conviviale. Les utilisateurs peuvent facilement saisir un mot, choisir un dictionnaire, effectuer une recherche et afficher les définitions des mots.

Comment Utiliser l'Application:

1. Saisissez un mot dans la zone de texte.
2. Choisissez un dictionnaire dans la liste déroulante.
3. Cliquez sur le bouton "Rechercher" pour obtenir la définition du mot.
4. Les définitions des mots contenant des entités HTML sont automatiquement converties en caractères lisibles.

Exigences:

- L'application nécessite une connexion Internet pour rechercher des définitions de mots en ligne.
- Et l'UDF DicoOnLine.au3
- Uniquement l'UDF mise à jour: DicoOnLineV2.au3

Code Source:
Le code source complet de l'application est fourni et peut être personnalisé selon les besoins de l'utilisateur.

Remarques:
Cette application est destinée à être utilisée comme un outil pratique pour rechercher des définitions de mots en ligne tout en vérifiant la connexion Internet. Elle est conçue pour être simple à utiliser et sert de point de départ pour d'autres développements AutoIt.

Avertissement:
L'application utilise la résolution DNS pour vérifier la connexion Internet en tentant de résoudre le nom de domaine de Google. En cas de problème de connexion Internet, l'indicateur de connexion sera rouge.

L'application est fournie à des fins éducatives et peut être personnalisée pour répondre à vos besoins. Nous vous encourageons à respecter les lois locales et à utiliser l'application de manière responsable.

Nouvelle mise à jour: ajout d'un autre dictionnaire, gestion des erreurs simplification du code source...

Voici le code source

Code: [Tout sélectionner] [Déplier/Replier]

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <ComboConstants.au3>
#include <WinAPIDiag.au3>
#include "DicoOnLineV2.au3"


Opt("GUICloseOnESC", 1)
Global $b__CONNECTED = False


Local $hGUI = GUICreate("Dictionnaire en ligne", 400, 230)
Local $hInput = GUICtrlCreateInput("", 10, 10, 300, 25)
Local $hDictionaryCombo = GUICtrlCreateCombo("", 320, 10, 70, 25, $CBS_DROPDOWNLIST)
GUICtrlSetData($hDictionaryCombo, "LeRobert|TV5 dico|Larousse|Linternaute")

Local $hSearchButton = GUICtrlCreateButton("Rechercher", 10, 40, 380, 25)
Local $hOutput = GUICtrlCreateEdit("", 10, 75, 380, 145, BitOR($ES_READONLY, $ES_WANTRETURN))
GUICtrlSetFont($hOutput, 10, 20, "", "Arial")
AdlibRegister("clignote", 2000)
GUISetState(@SW_SHOW)

While 1
   Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE
         Exit
      Case $hSearchButton
         Local $sSearchWord = GUICtrlRead($hInput)
         Local $sSelectedDictionary = GUICtrlRead($hDictionaryCombo)
         If $sSearchWord <> "" Then
            Local $sDefinition = ""
            Select
               Case $sSelectedDictionary = "LeRobert"
                  $sDefinition = ChercherDefinitionLeRobert($sSearchWord)
               Case $sSelectedDictionary = "TV5 dico"
                  $sDefinition = ChercherDefinitionTV5($sSearchWord)
               Case $sSelectedDictionary = "Larousse"
                  $sDefinition = ChercherDefinitionLarousse($sSearchWord)
               Case $sSelectedDictionary = "Linternaute"
                  $sDefinition = GetDefinitionFromLinternaute($sSearchWord)
            EndSelect
            If $sSelectedDictionary <> "" Then
               If $sDefinition <> "" Then
                  GUICtrlSetData($hOutput, $sDefinition)
               Else
                  GUICtrlSetData($hOutput, "Mot introuvable.")
               EndIf
            Else
               MsgBox(64, "Information!", "Veuillez sélectionner un dictionnaire")
            EndIf
         EndIf

   EndSwitch
WEnd

AdlibUnRegister("clignote")

Func greenColor()
   GUICtrlSetColor($hSearchButton, 0x00FF00) ; Couleur verte
   Sleep(1000)
   GUICtrlSetColor($hSearchButton, -1) ; Réinitialiser la couleur
EndFunc   ;==>greenColor

Func redColor()
   GUICtrlSetColor($hSearchButton, 0xFF0000) ; Couleur rouge
   Sleep(1000)
   GUICtrlSetColor($hSearchButton, -1) ; Réinitialiser la couleur
EndFunc   ;==>redColor

Func clignote()
   check_connexion()
   If $b__CONNECTED Then
      greenColor()
   Else
      redColor()
   EndIf
EndFunc   ;==>clignote

Func check_connexion()
   If _WinAPI_IsInternetConnected() Then
      $b__CONNECTED = True
   Else
      $b__CONNECTED = False
   EndIf
EndFunc   ;==>check_connexion

GeSHi © Extension Codebox Plus

Leonard83 · #2

Salut,

Je trouve que ton application "Dictionnaire en ligne avec Vérification de la Connexion Internet" est une idée originale et pratique. C'est cool de pouvoir rechercher des définitions de mots en ligne à partir de différents dictionnaires, et de savoir si on est connecté à Internet ou pas. J'aime bien aussi le fait que ton application convertisse les entités HTML en caractères lisibles, ça rend les définitions plus claires.

Par contre, je trouve que ton code source est un peu long et compliqué. Je ne connais pas bien le langage AutoIt, mais je me demande s'il n'y a pas moyen de simplifier ou d'optimiser ton code. Peut-être que tu pourrais utiliser des fonctions plus courtes, des variables plus explicites, des commentaires plus clairs, etc. Je pense que ça rendrait ton application plus facile à comprendre et à modifier.

Numeric · #3

Salut, je vous propose une version améliorée du dictionnaire. Ce programme vous permettra de chercher la définition des mot sur 4 dictionnaires en lignes et vous pouvez aussi traduire dans n'importe quelle langue. La traduction en temps réel est possible... Pour utiliser le programme, vous devez tout simplement télécharger la version2 de DicoOnLineV2 et aussi l'UDF GoogleTranslate.

Code: [Tout sélectionner] [Déplier/Replier]

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPISysWin.au3>
#include <WinAPIConv.au3>
#include <WinAPISys.au3>
#include <DicoOnLineV2.au3>
#include <GoogleTranslate.au3>
;###################################################################################
Global Const $DICTIONNARIES = ["TV5 DICO", "LE ROBERT", "LAROUSSE", "INTERNAUTE"]   ; "LAROUSSE",
Global Const $GET_DEF_REQUETE_ERROR = "Impossible de répondre à la démande"
###################################################################################
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Dictionnaires by Numeric", 575, 283, 221, 122, -1, BitOR($WS_EX_TRANSPARENT, $WS_EX_WINDOWEDGE))
GUISetBkColor(0x99B4D1)

$Tab1 = GUICtrlCreateTab(16, 56, 313, 201)
$TabSheet1 = GUICtrlCreateTabItem("Dictionnaires en ligne")
$Group1 = GUICtrlCreateGroup("Mot a definir", 24, 88, 161, 89)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$Input1 = GUICtrlCreateInput("Ecrire le mot ici...", 40, 120, 121, 24)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button1 = GUICtrlCreateButton("Definition", 56, 192, 83, 17, BitOR($BS_CENTER, $BS_VCENTER, $BS_PUSHLIKE, $BS_NOTIFY))
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$Group2 = GUICtrlCreateGroup("Dictionnaires", 200, 96, 113, 81)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
$Combo1 = GUICtrlCreateCombo("Dicos", 208, 128, 89, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
setComboData($Combo1, $DICTIONNARIES)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$TabSheet2 = GUICtrlCreateTabItem("Google Translate")
$Edit1 = GUICtrlCreateEdit("", 24, 88, 201, 129)
$Button2 = GUICtrlCreateButton("Traduire", 80, 224, 75, 17)
$Group3 = GUICtrlCreateGroup("Source", 240, 88, 73, 65)


$Combo2 = GUICtrlCreateCombo("", 248, 112, 57, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group4 = GUICtrlCreateGroup("Cible", 240, 160, 73, 57)
$Combo3 = GUICtrlCreateCombo("", 248, 184, 57, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Radio1 = GUICtrlCreateRadio("Auto Traduire", 168, 224, 113, 17)
GUICtrlCreateTabItem("")
$Edit2 = GUICtrlCreateEdit("", 344, 80, 209, 169)
$Dummy1 = GUICtrlCreateDummy()

Global $IS_CHECKED = False

Global $languageCodes[26][2] = _
      [["Anglais", "en"], _
      ["Espagnol", "es"], _
      ["Français", "fr"], _
      ["Allemand", "de"], _
      ["Chinois (simplifié)", "zh-CN"], _
      ["Chinois (traditionnel)", "zh-TW"], _
      ["Japonais", "ja"], _
      ["Coréen", "ko"], _
      ["Arabe", "ar"], _
      ["Russe", "ru"], _
      ["Portugais", "pt"], _
      ["Italien", "it"], _
      ["Néerlandais", "nl"], _
      ["Suédois", "sv"], _
      ["Norvégien", "no"], _
      ["Danois", "da"], _
      ["Finnois", "fi"], _
      ["Grec", "el"], _
      ["Turc", "tr"], _
      ["Hindi", "hi"], _
      ["Bengali", "bn"], _
      ["Hébreu", "he"], _
      ["Thaï", "th"], _
      ["Vietnamien", "vi"], _
      ["Ukrainien", "uk"], _
      ["Polonais", "pl"]]

For $i = 0 To UBound($languageCodes) - 1
   GUICtrlSetData($Combo2, $languageCodes[$i][0])
   GUICtrlSetData($Combo3, $languageCodes[$i][0])
Next


GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


Global Const $SYSTEM_INFOS = "Ecrire le mot ici..."

Global $hProcNew = DllCallbackRegister("_MyWindowProc", "ptr", "hwnd;uint;long;ptr")
Global $g_hProcOld = _WinAPI_SetWindowLong(GUICtrlGetHandle($Input1), $GWL_WNDPROC, DllCallbackGetPtr($hProcNew))
GUIRegisterMsg($WM_COMMAND, WM_COMMAND)
While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         Exit

      Case $Tab1
   EndSwitch
WEnd

Func setComboData($Combo, $aData)
   If Not IsArray($aData) Then Return SetError(1)
   For $element In $aData
      GUICtrlSetData($Combo, $element)
   Next
EndFunc   ;==>setComboData


Func _MyWindowProc($hWnd, $iMsg, $wParam, $lParam)
   _ManageInputInfos($iMsg)

   ;pass the unhandled messages to default WindowProc
   Return _WinAPI_CallWindowProc($g_hProcOld, $hWnd, $iMsg, $wParam, $lParam)
EndFunc   ;==>_MyWindowProc

Func _ManageInputInfos($iMsg)
   Local $sData = ""
   Switch $iMsg
      Case $WM_SETCURSOR
         If GUICtrlRead($Input1) == $SYSTEM_INFOS Then
            GUICtrlSetData($Input1, "")
            _WinAPI_SetFocus(GUICtrlGetHandle($Input1))
         EndIf
      Case $WM_MOUSELEAVE
         $sData = GUICtrlRead($Input1)
         If $sData == "" Or StringIsSpace($sData) Then
            GUICtrlSetData($Input1, $SYSTEM_INFOS)
            _WinAPI_SetFocus(GUICtrlGetHandle($TabSheet1))
         EndIf
   EndSwitch
EndFunc   ;==>_ManageInputInfos

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

   If $iMsg == $WM_CLOSE Then Exit

   Local $nNotificationCode = _WinAPI_HiWord($wParam)
   Local $iCtrlID = _WinAPI_GetDlgCtrlID($lParam)

   Switch $iCtrlID
      Case $Button1 ;$TabSheet1
         ; Handle events specific to TabSheet1
         Local $sMot = GUICtrlRead($Input1)
         Local $sDico = GUICtrlRead($Combo1)

         If $nNotificationCode = $EN_CHANGE Then
            ;
         EndIf

         If $nNotificationCode = $BN_CLICKED Then

            If $iCtrlID = $Button1 Then

               If $sMot <> "" And $sMot <> $SYSTEM_INFOS Then

                  If $sDico <> "" And isNotComboDicoManuallyEdited($sDico) Then
                     Local $sDefinition = "", $from = ""
                     Switch $sDico
                        Case $DICTIONNARIES[0] ;TV5 Dico
                           $from = "TV5 Dico"
                           $sDefinition = ChercherDefinitionTV5($sMot)
                        Case $DICTIONNARIES[1]  ;"LE ROBERT"
                           $from = "LeRobert"
                           $sDefinition = ChercherDefinitionLeRobert($sMot, True)
                        Case $DICTIONNARIES[2] ;"LAROUSSE"
                           $from = "LaRousse"
                           $sDefinition = ChercherDefinitionLaRousse($sMot)
                        Case $DICTIONNARIES[3] ;"INTERNAUTE"
                           $from = "Linternaute-dico"
                           $sDefinition = GetDefinitionFromLinternaute($sMot)
                     EndSwitch
                     If $sDefinition == "" Then
                        $sDefinition = $SYSTEM_INFOS
                     EndIf
                     TrayTip("Définition de : '" & $sMot & "' d'après : " & $from, $sDefinition, 2)
                     GUICtrlSetData($Edit2, $sDefinition)
                     ConsoleWrite($sDefinition & @CRLF)
                  Else
                     MsgBox(16, "Information!", "Veuillez sélectionner un dictionnaire!", 1)
                  EndIf
               Else
                  MsgBox(16, 'Information!', 'Veuillez écrire un mot.!', 1)
               EndIf
            EndIf
         EndIf

      Case $Combo1

         If $nNotificationCode = $CBN_SELCHANGE Then
            ;Version future
         EndIf

      Case $Button2
         Local $sData = GUICtrlRead($Edit1)
         If $sData == "" Then Return $GUI_RUNDEFMSG

         If GUICtrlRead($Combo2) == "" Or GUICtrlRead($Combo3) == "" Then
            MsgBox(16, "Avertissement!", "Veuillez selectionner les langues...", 1)
            Return $GUI_RUNDEFMSG
         EndIf

         Local $iSource = __getIndex(GUICtrlRead($Combo2))
         Local $iDest = __getIndex(GUICtrlRead($Combo3))
         Local $sSrc, $sDst

         If $iSource <> -1 Then
            $sSrc = $languageCodes[$iSource][1]
         EndIf

         If $iDest <> -1 Then
            $sDst = $languageCodes[$iDest][1]
         EndIf

         If $sSrc == "" Then
            $sSrc = "fr"
         EndIf
         If $sDst == "" Then
            $sDst = "en"
         EndIf

         Local $sTraduction = GoogleTranslate($sData, $sSrc, $sDst)
         If $sTraduction <> "" Then
            GUICtrlSetData($Edit2, $sTraduction)
            TrayTip("Traduction", $sTraduction, 3)
         EndIf

      Case $Radio1

         If $IS_CHECKED Then
            GUICtrlSetState($Radio1, $GUI_UNCHECKED)
            $IS_CHECKED = False
         Else
            GUICtrlSetState($Radio1, $GUI_CHECKED)
            $IS_CHECKED = True
         EndIf

      Case $Edit1
         Local $iSource = __getIndex(GUICtrlRead($Combo2))
         Local $iDest = __getIndex(GUICtrlRead($Combo3))
         Local $sSrc, $sDst

         If $iSource <> -1 Then
            $sSrc = $languageCodes[$iSource][1]
         EndIf

         If $iDest <> -1 Then
            $sDst = $languageCodes[$iDest][1]
         EndIf

         If $sSrc == "" Then
            $sSrc = "fr"
         EndIf
         If $sDst == "" Then
            $sDst = "en"
         EndIf

         Local $sTraduction = ''
         If Not $IS_CHECKED Or GUICtrlRead($Edit1) ==""  Then Return $GUI_RUNDEFMSG
         If $nNotificationCode == $EN_CHANGE Then
            GUICtrlSetData($Edit2, GoogleTranslate(GUICtrlRead($Edit1), $sSrc,$sDst))
            Return
         EndIf

   EndSwitch

   Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func isNotComboDicoManuallyEdited($sDico)
   For $sValue In $DICTIONNARIES
      If $sValue == $sDico Then Return True
   Next
   Return False
EndFunc   ;==>isNotComboDicoManuallyEdited

Func __getIndex($searchLanguage)
   ; Chercher l'index du nom de la langue
   Local $index = -1
   For $i = 0 To UBound($languageCodes) - 1
      If StringCompare($languageCodes[$i][0], $searchLanguage) == 0 Then
         $index = $i
         ExitLoop
      EndIf
   Next
   Return $index
EndFunc   ;==>__getIndex

GeSHi © Extension Codebox Plus

un autre exemple qui est basé sur la Version3 [ DicoOnLineV3.au3 ]

Code: [Tout sélectionner] [Déplier/Replier]

#include-once
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <DicoOnLineV3.au3>
#include <WinAPIDiag.au3>

;###################################################################################
Global Const $DICTIONNARIES = ["TV5 DICO", "LE ROBERT", "LAROUSSE", "INTERNAUTE", " ETYMOLOGY"]   ; "LAROUSSE",
Global Const $GET_DEF_REQUETE_ERROR = "Impossible de répondre à la démande"
Global $b__CONNECTED = False

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Dictionnaires en Ligne by Numeric", 797, 460, 192, 124)
$Edit1 = GUICtrlCreateEdit("", 200, 8, 585, 417, BitOR($ES_READONLY, $ES_AUTOVSCROLL, $ES_WANTRETURN, $WS_VSCROLL), 0)
GUICtrlSetBkColor($Edit1, 0xFFFFFF)
GUICtrlSetFont(-1, 11, 400, 0, "Nirmala UI")
$Group1 = GUICtrlCreateGroup("Dictionnaires", 8, 32, 185, 105, -1, BitOR($WS_EX_TRANSPARENT, $WS_EX_CLIENTEDGE))
$Combo1 = GUICtrlCreateCombo("", 32, 72, 145, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
setComboData($Combo1, $DICTIONNARIES)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Mot a definir", 8, 160, 185, 105, -1, BitOR($WS_EX_TRANSPARENT, $WS_EX_CLIENTEDGE))
$Input1 = GUICtrlCreateInput("", 16, 200, 169, 21)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button1 = GUICtrlCreateButton("Obtenir la Definition", 40, 312, 107, 25)
GUICtrlSetCursor(-1, 0)
$Label2 = GUICtrlCreateLabel("", 200, 440, 260, 17)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlSetCursor(-1, 4)
$Label1 = GUICtrlCreateLabel("", 570, 440, 101, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlSetCursor(-1, 4)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
AdlibRegister("clignote", 2000)
While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         Exit
      Case $Button1
         GUICtrlSetData($Edit1, "")

         Local $sMot = GUICtrlRead($Input1)
         Local $sDico = GUICtrlRead($Combo1)
         Local $sDefinition = "", $from = ""
         If $sMot <> "" Then

            If $sDico <> "" And isNotComboDicoManuallyEdited($sDico) Then

               Switch $sDico
                  Case $DICTIONNARIES[0] ;TV5 Dico
                     $from = "TV5 Dico"
                     $sDefinition = ChercherDefinitionTV5($sMot)
                  Case $DICTIONNARIES[1]  ;"LE ROBERT"
                     $from = "LeRobert"
                     $sDefinition = ChercherDefinitionLeRobert($sMot, True)
                  Case $DICTIONNARIES[2] ;"LAROUSSE"
                     $from = "LaRousse"
                     $sDefinition = ChercherDefinitionLaRousse($sMot)
                  Case $DICTIONNARIES[3] ;"INTERNAUTE"
                     $from = "Linternaute-dico"
                     $sDefinition = GetDefinitionFromLinternaute($sMot)

                  Case $DICTIONNARIES[4]
                     $from = "Etymology-dico"
                     $sDefinition = EtymologyDefinitions($sMot, "fr")
               EndSwitch

               If $sDefinition <> "" Then
                  ;TrayTip("Définition de : '" & $sMot & "' d'après : " & $from, $sDefinition, 2)
                  GUICtrlSetData($Edit1, $sDefinition)
               Else

                  TrayTip("Définition de : '" & $sMot & "' d'après : " & $from, "Non trouvée...", 2)
                  GUICtrlSetData($Edit1, "Définition non trouvée!")
               EndIf

            Else
               MsgBox(16, "Information", "Veuillez selectionner un dictionnaire.")
            EndIf

         Else
            MsgBox(16, "Information!", "Veuillez selectionner un mot")
         EndIf

   EndSwitch
WEnd



Func setComboData($Combo, $aData)
   If Not IsArray($aData) Then Return SetError(1)
   For $element In $aData
      GUICtrlSetData($Combo, $element)
   Next
EndFunc   ;==>setComboData


Func clignote()
   check_connexion()
   If $b__CONNECTED Then
      greenColor()
   Else
      redColor()
   EndIf
EndFunc   ;==>clignote

Func check_connexion()
   If _WinAPI_IsInternetConnected() Then
      $b__CONNECTED = True
   Else
      $b__CONNECTED = False
   EndIf
EndFunc   ;==>check_connexion

Func greenColor()
   GUICtrlSetData($Label2, "Connected...")
   GUICtrlSetColor($Label2, 0x00FF00) ; Couleur verte
   Sleep(1000)
   GUICtrlSetColor($Label2, -1) ; Réinitialiser la couleur
EndFunc   ;==>greenColor

Func redColor()
   GUICtrlSetData($Label2, "Not Connected...")
   GUICtrlSetColor($Label2, 0xFF0000) ; Couleur rouge
   Sleep(1000)
   GUICtrlSetColor($Label2, -1) ; Réinitialiser la couleur
EndFunc   ;==>redColor

Func isNotComboDicoManuallyEdited($sDico)
   For $sValue In $DICTIONNARIES
      If $sValue == $sDico Then Return True
   Next
   Return False
EndFunc   ;==>isNotComboDicoManuallyEdited

GeSHi © Extension Codebox Plus

MaellieCo2 · #4

ce dictionnaire aussi ma beaucoup aide.Voici le lien:https://dictionnaire.merci-app.com/repertoire/m

Numeric · #5

MaellieCo2 a écrit : ↑ven. 10 nov. 2023 06:59 ce dictionnaire aussi ma beaucoup aide.Voici le lien:https://dictionnaire.merci-app.com/repertoire/m

Effectivement un bon dictionnaire. Mais je n'ai pas eu le temps de lire les Conditions d'utilisations de ce site. Si tu peux me fournir plus d'informations à ce sujet... Je signale que certains sites n'autorisent pas qu'une application tierce utilise leurs données d'une "certaine façon". Et nous respectons cela à la lettre.

MaellieCo2 · #6

Numeric a écrit : ↑ven. 10 nov. 2023 13:03
MaellieCo2 a écrit : ↑ven. 10 nov. 2023 06:59 ce dictionnaire aussi ma beaucoup aide.Voici le lien:https://dictionnaire.merci-app.com/repertoire/m
Effectivement un bon dictionnaire. Mais je n'ai pas eu le temps de lire les Conditions d'utilisations de ce site. Si tu peux me fournir plus d'informations à ce sujet... Je signale que certains sites n'autorisent pas qu'une application tierce utilise leurs données d'une "certaine façon". Et nous respectons cela à la lettre.

Merci..je vais le lire....

AutoIt Français

[App]Dictionnaires en ligne

[App]Dictionnaires en ligne

Re: [App]Dictionnaires en ligne

Re: [App]Dictionnaires en ligne

Re: [App]Dictionnaires en ligne

Re: [App]Dictionnaires en ligne

Re: [App]Dictionnaires en ligne