[R] Menu qui clignote sur selection dans Treeview

[Julien]

Bonjour,

Quand je clic sur un item de mon Treeview cela fait clignoter mon menu, ce n'est pas dérangant plus que ça mais pouvez-vous me dire ce que je dois faire pour ne pas que cela se produise ?

Je n'ai pas testé sur un autre système qu Windows XP.

D'avance merci et voila le code :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TreeViewConstants.au3>
#include <StaticConstants.au3>

Opt("GUIOnEventMode", 1)

Global $TitleApps = "Test"
Global $FormWidth = 753, $FormHeight = 606, $FormPositionWidth = -1, $FormPositionHeight = -1
Global $FileICODll = @ScriptDir & "\dll.dll"
Global $ControlPanelCurrent = ""
Global $GUIChild1, $GUIChild2

Global $FormPrincipal = GUICreate($TitleApps, $FormWidth, $FormHeight, $FormPositionWidth, $FormPositionHeight)
Global $MenuFile = GUICtrlCreateMenu("&Fichier")
Global $MenuExit = GUICtrlCreateMenuItem("&Quitter", $MenuFile)
GUICtrlSetOnEvent(-1, "_ExitApplication")
GUISetIcon($FileICODll, -1)
GUISetFont(9, 400, 0, "Verdana")
GUISetOnEvent($GUI_EVENT_CLOSE, "_ExitApplication")
Global $ControlPanel = GUICtrlCreateTreeView(5, 8, 193, 513, BitOR($GUI_SS_DEFAULT_TREEVIEW,$WS_BORDER), $WS_EX_CLIENTEDGE)
Global $ControlPanelHandle = ControlGetHandle($FormPrincipal, "", $ControlPanel)
Global $ControlPanel_0 = GUICtrlCreateTreeViewItem("1", $ControlPanel)
GUICtrlSetOnEvent(-1, "_ControlPanelClick")
Global $ControlPanel_1 = GUICtrlCreateTreeViewItem("2", $ControlPanel_0)
GUICtrlSetOnEvent(-1, "_ControlPanelClick")
GUICtrlSetState($ControlPanel_0, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))
_GUI1()
_GUI2()

GUISwitch($FormPrincipal)

GUISetState(@SW_SHOW, $FormPrincipal)

While 1
    Sleep(100)
WEnd

Func _ControlPanelClick()
    Local $Item = GUICtrlRead($ControlPanel)
    If $Item = 0 Then
        $ControlPanelCurrent = ""
    Else
        Local $Text = GUICtrlRead($Item, 1)
        If $Text == "" Then
            $ControlPanelCurrent = ""
        Else
            $ControlPanelCurrent = $Text
            _GUIChangeSelect()
        EndIf
    EndIf
EndFunc
Func _ExitApplication()
    Exit
EndFunc
Func _GUIChangeSelect()
    Local $ArrayGUI[3][2] = [["Name", "Global"], _
        ["1", "GUIChild1"], _
        ["2", "GUIChild2"] _
        ]
    For $i = 1 To UBound($ArrayGUI) -1
        If $ArrayGUI[$i][0] = $ControlPanelCurrent Then
            GUISetState(@SW_SHOW, Eval($ArrayGUI[$i][1]))
        Else
            GUISetState(@SW_HIDE, Eval($ArrayGUI[$i][1]))
            GUISwitch(Eval($ArrayGUI[$i][1]))
        EndIf
    Next
EndFunc
Func _GUI1()
    $GUIChild1 = GUICreate("", 545, 511, 201, 9, BitOr($WS_CHILD,$WS_TABSTOP), -1, $FormPrincipal)
    GUISetBkColor(0x00FF00)
    GUISetState(@SW_HIDE, $GUIChild1)
EndFunc
Func _GUI2()
    $GUIChild2 = GUICreate("", 545, 511, 201, 9, BitOr($WS_CHILD,$WS_TABSTOP), -1, $FormPrincipal)
    GUISetBkColor(0xFF00FF)
    GUISetState(@SW_HIDE, $GUIChild2)
EndFunc
 

[TommyDDR]

Ligne 68 :

Remplacez

Code : Tout sélectionner

 GUISetState(@SW_SHOW, Eval($ArrayGUI[$i][1]))

Par :

Code : Tout sélectionner

 GUISetState(@SW_SHOWNA, Eval($ArrayGUI[$i][1]))

Je vous laisse regarder l'aide pour cerner la différence entre ces deux macros.

[Julien]

Merci je ne connaissais pas du tout cette macro !

J'ai une autre question toujours concernant le code de base, il n'est pas possible d'utiliser la touche TAB dans par exemple le GUI1 malgré la présence de $WS_TABSTOP

Code : Tout sélectionner

_GUI1()
    $GUIChild1 = GUICreate("", 545, 511, 201, 9, BitOr($WS_CHILD,$WS_TABSTOP), -1, $FormPrincipal)

Je ne connais pas bien le fonctionnement des "GUI" enfant.

D'avance merci.