[R] Quitter une GUi sans quitter le première

[astaroth]

Bonjour,

Comment faire pour quitter la GUI n°2 sans quitter la premiere?

► Afficher le texte

Code : Tout sélectionner

#include <IE.au3>
#NoTrayIcon
#include <GUIConstants.au3>

$Image2 = "\Patientez.jpg"
 
$url = "http://www.Blabla.com/"
$url3 = "http://www.1234.fr"
$url4 = "http://www.1234.fr"


GUICreate("Patientez", 480, 350)     <====GUI 1
GUICtrlCreatePic(@TempDir & $Image2, 0, 0, 480, 350, $SS_CENTERIMAGE)
GUISetBkColor(0x000000)

GUISetFont(10, 50, 1, "Comic Sans MS")

GUICtrlCreateLabel("Label rouge", 250, 270, 200, 25, $BS_CENTER)
GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT )
GUICtrlSetColor(-1, 0xFFFFFF)

GUISetFont(14, 800, 1, "Comic Sans MS")

$Button_1 = GUICtrlCreateLabel("Accès", 260, 320, 120,25, $BS_CENTER)
GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT )
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetCursor(-1, 0)

GUISetState()


While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_1
            GUICreate("Patientez", 480, 350)     <======= GUI 2
GUICtrlCreatePic(@TempDir & $Image2, 0, 0, 480, 350, $SS_CENTERIMAGE)
GUISetBkColor(0x000000)

GUISetFont(10, 50, 1, "Comic Sans MS")

GUICtrlCreateLabel("Label rouge", 250, 270, 200, 25, $BS_CENTER)
GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT )
GUICtrlSetColor(-1, 0xFFFFFF)

GUISetFont(14, 800, 1, "Comic Sans MS")

$Button_1 = GUICtrlCreateLabel("Accès", 260, 320, 120,25, $BS_CENTER)
GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT )
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetCursor(-1, 0)

GUISetState()


While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_1
            Run(@ComSpec & " /c start file:" & $url, "", @SW_HIDE)
            ExitLoop
    EndSelect
WEnd
    EndSelect
WEnd

[Tlem]

Voici un modèle de deux GUI (Avec utilisation du mode Parent).
A vous de l'adapter à votre script.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>

$hGui1 = GUICreate("GUI1", 400, 200)
$Button1 = GUICtrlCreateButton("Lancer GUI2", 300, 150, 75, 25, 0)
GUISetState()



While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            _Gui2()
    EndSwitch
WEnd



Func _Gui2()
    $hGui2 = GUICreate("GUI2", 200, 100, -1, -1, -1, -1, $hGui1)
    $Button2 = GUICtrlCreateButton("Fermer GUI2", 100, 50, 75, 25, 0)
    GUISetState(@SW_SHOW)
    GUISwitch($hGui2)


    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $Button2
                GUIDelete($hGui2)
                ExitLoop
        EndSwitch
    WEnd
EndFunc   ;==>_Gui2

[moutelous]

Ouaip, trop rapide tlem

Le même en OnEvent mode :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
Opt("GUIOnEventMode", 1)  ; Change to OnEvent mode 



$gui1=GUICreate("Patientez", 480, 350)    ; <====GUI 1

GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked")

$Button_1 = GUICtrlCreateButton("Accès", 260, 320, 120,25, $BS_CENTER)
GUICtrlSetOnEvent($Button_1,"Creation_gui2")


GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd

func Creation_gui2()
    Global $gui2 =GUICreate("Patientez ..Encore", 490, 350,-1,-1,-1,-1,$gui1)    ; <==== GUI 2  
    $Button_2 = GUICtrlCreateButton("Accès", 260, 320, 120,25, $BS_CENTER)
    GUISetState(@SW_SHOW)
    GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEgui2")
EndFunc

Func CLOSEClicked()
      Exit
EndFunc
  
  Func CLOSEgui2()
      GUIDelete($gui2)
  EndFunc
 

A+

[Tlem]

Ouaip, trop rapide tlem

[astaroth]

Merci a vous deux

[papus2]

Voici un modèle de deux GUI (Avec utilisation du mode Parent).
A vous de l'adapter à votre script.

j'ai essayé ce code mais il y a un problème si on ferme la fenêtre GUI2 avec la croix rouge, au 2ème clic ça plante, j'ai donc remplacer la ligne

Code : Tout sélectionner

$hGui2 = GUICreate("GUI2", 200, 100, -1 , -1, -1, -1, $hGui1)

par

Code : Tout sélectionner

$hGui2 = GUICreate("GUI2", 200, 100, -1 , -1, $WS_BORDER, -1, $hGui1)

et là il n'y a plus la croix

[Tlem]

Oui c'est clair que ça fonctionne, mais il y avais plus simple.

En fait dans la fonction _Gui2() les deux Case devrait faire la même chose.
Ce qui dans l'exemple que j'ai donné n'est pas le cas.

Modifiez donc le premier case de _Gui2() comme ceci :

Code : Tout sélectionner

       Case $GUI_EVENT_CLOSE
            GUIDelete($hGui2)
            ExitLoop
 

Et tout rentrera dans l'ordre.