Combo Pop Up

Aide sur les Interfaces Graphique Utilisateurs (GUI).
Règles du forum
.
Répondre
Misa10
Niveau 4
Niveau 4
Messages : 52
Enregistré le : sam. 14 avr. 2018 12:50
Status : Hors ligne

Combo Pop Up

#1

Message par Misa10 »

Bonjour , je cherche simplement un moyen de faire pop une combo . Exactement comme la fonction Inputbox mais avec une combo à la place . J'ai pas réussi a trouvé d'équivalent . Du coup j'avais essayé de créer un bouton qui crée une deuxième form mais ça n'a pas marché . Si quelqu'un a des infos a me donné :) Merci.
Avatar du membre
walkson
Modérateur
Modérateur
Messages : 1020
Enregistré le : ven. 12 août 2011 19:49
Localisation : Hurepoix
Status : Hors ligne

Re: Combo Pop Up  

#2

Message par walkson »

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1) ;OnEvent functions are only called when Opt("GUIOnEventMode", 1) - when in this mode GUIGetMsg() is NOT used at all.
Global $Form2, $Combo

Global $Form1 = GUICreate("Form1", 606, 139, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
Global $Button1 = GUICtrlCreateButton("Combo", 24, 24, 121, 49)
GUICtrlSetOnEvent(-1, "Button1Click")
Global $Input1 = GUICtrlCreateInput("", 176, 24, 273, 21)
GUISetState(@SW_SHOW)


While 1
 Sleep(100)
WEnd

Func SpecialEvents()
	Exit
EndFunc

Func Button1Click()
	Form_2()
EndFunc

Func Form_2()
$Form2 = GUICreate("Combo", 300, 100, -1, -1, -1, -1,$Form1)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEventsForm2")
$Combo = GUICtrlCreateCombo("", 24, 24, 250, 35)
GUICtrlSetOnEvent(-1, "ComboClick")
GUICtrlSetData(-1,"Valeur 1|Valeur 11|Valeur 111|Valeur 1111|Valeur 11111|Valeur 111111|Valeur 1111111|Valeur 11111111")
GUICtrlSetFont(-1,12)
GUISetState(@SW_SHOW)
GUISetState(@SW_HIDE, $Form1)
EndFunc
Func SpecialEventsForm2()
	GUIDelete($Form2)
	GUISetState(@SW_SHOW, $Form1)
EndFunc

Func ComboClick()
	$val = GUICtrlRead($Combo)
	GUIDelete($Form2)
	GUISetState(@SW_SHOW, $Form1)
	GUICtrlSetData($Input1, $val)
EndFunc


Cordialement,
Walkson
"Horas non numero nisi serenas " Le canon de midi
(Je ne compte que les heures heureuses)
Répondre