AutoIt Français

Bonjour à tous, j'espere que ça va, premier post pour moi dans ce forum j'ai pourtant chercher mon pb, mais en vain.
Alors voilà je fais un code qui a pour but final de pouvoir installer les logiciels cochés après être passé par le choix de l'OS Windows, avec deux trois paramètres en plus pas très importants...

J'ai une liste déroulante créée avec ComboBox, ainsi qu'un bouton suivant, en cliquant sur ce bouton, j'aimerais qu'une action s'effectue par appel d'une fonction par rapport au choix de la liste déroulante, et je n'y arrive pas

j'ai essayé avec les Switch Case les conditions avec If, j'ai vraiment tout fait (pour moi, car je tiens à dire que je ne suis pas du tout expérimenté, je code depuis très peu). Alors voilà ou j'en suis actuellement, la portion qui me pose pb :

Code : Tout sélectionner

Global $suite = GUICtrlCreateButton ("Suivant", 160, 150, 85, 25) ; mon bouton suivant

Global $List = GUICtrlCreateCombo ("test", 10, 50, 200, 200, $CBS_DROPDOWNLIST, $CBS_SORT) ; la liste déroulante

GUICtrlSetData (-1, $windowsxp)
GUICtrlSetData (-1, $windows7)
GUICtrlSetData (-1, $windows8)
GUICtrlSetData (-1, $windows_10) ; les différents choix

GUICtrlSetOnEvent ($suite, "Interlude") ; l'appel de la fonction en appuyant sur le bouton. Dans la fonction :

Func Interlude ()

If $windows7 Then Windows7 ()
If $windows8 Then Windows8 ()
If $windows_10 Then Windows_10 ()
If $windowsxp Then Windowsxp () ; et là, ça n'appel pas la fonction par rapport à la combobox, mais tjrs la première citée (ici Windows7 () )

Si cela ne suffit pas je pourrais donner l'intégralité du code mais faut que je le réorganise un peu

.

Je tiens à vous remercier d'avance pour vos réponses

L'intégralité du code, ptêt pas. Mais un petit script représentatif et fonctionnel (ou presque) moui ça serait pas mal

Voilà (le pb c'est que "Windows 7" s'affiche avec n'importe quel choix

► Afficher le texte

Bonjour, j'ai remarqué plusieurs erreurs dans ton code, et d'autres petites choses pas très utiles selon moi.

J'aurai pu me contenté de corriger ton code et de te le donner fonctionnel, mais pour que tu puisse progresser, je vais aussi t'expliquer pourquoi ça ne marche pas.

► Afficher le texte

Code : Tout sélectionner

;~bouton de fermeture
Global $close = GUICtrlCreateButton ("Close", 2, 150, 85, 25)
;le bouton ne sera pas créé, tu n'as pas créé de fenetre avant, il ne sais pas où est-ce qu'il doit s'afficher
GUICtrlSetOnEvent ($close, Close)

#include <ComboConstants.au3>
#include <ButtonConstants.au3>

Opt("GUIOnEventMode", 1)
Opt ("GUIDataSeparatorChar", 1);à priori inutile

Global $test
; Variables Combo
Global $windowsxp = "Windows XP"
Global $windows_10 = "Windows 10"
Global $windows8 = "Windows 8"
Global $windows7 = "Windows 7"
;Variables boutton
Global $boutton32 = "32 bits"
Global $boutton64 = "64 bits"

ChoixOS ()

Func ChoixOS ()

;~     Crée la GUI
        Global $boite = GUICreate ("Choix O$", 250, 175, 500, 250)

;~     Message selectionnez...
        GUICtrlCreateLabel ("Selectionner la version de Windows", 20, 20, -1, -1, $CBS_DROPDOWN, $CBS_OEMCONVERT)

;       Création des deux boutons 64 et 32 bits
        GUICtrlCreateCheckbox ($boutton32, 45, 85, 45, 40, $BS_PUSHLIKE, $BS_AUTORADIOBUTTON)
        GUICtrlCreateCheckbox ($boutton64, 150, 85, 45, 40, $BS_PUSHLIKE, $BS_AUTORADIOBUTTON)

;~     Crée le boutton "Suivant"
        Global $suite = GUICtrlCreateButton ("Suivant", 160, 150, 85, 25)
        GUICtrlSetOnEvent ($suite, "Interlude")

;~     Crée la liste Combo
        Global $List = GUICtrlCreateCombo ($windows_10, 10, 50, 200, 200, $CBS_DROPDOWNLIST, $CBS_SORT)

; Ajoute des éléments à la liste combo
        GUICtrlSetData (-1, $windowsxp)
        GUICtrlSetData (-1, $windows7)
        GUICtrlSetData (-1, $windows_10)
        GUICtrlSetData (-1, $windows8)

       While 1
;~           Affiche la GUI
             GUISetState(@SW_SHOW, $boite)
;            l'afficher qu'une seule fois suffit, ne met pas cette fonction ce cette boucle
       WEnd
EndFunc

;~ ; Fonction Interlude
;Interlude () ;on n'arrivera jamais ici, cettte ligne est inutile et risque plus de poser problème qu'autre chose

Func Interlude ()

       If $windows7 Then; si $windows7 est vrai, c'est pas ce qu'on veux. Nous on veut si GUICtrlRead($List) = $windows7 ;utilisée sur un comboe, cette foction retourne la valeur selectionnée
              Windows7 ()
       ElseIf $windows8 Then
              Windows8 ()
       ElseIf $windows_10 Then
              Windows_10 ()
       ElseIf $windowsxp Then
              Windowsxp ()
       EndIf

EndFunc

Func Windows7 ()
       MsgBox (0, "test", "Windows 7")
EndFunc

Func Windows8 ()
       MsgBox (0, "test", "Windows 8")
EndFunc

Func Windows_10 ()
       MsgBox (0, "test", "Windows 10")
EndFunc

Func Windowsxp ()
       MsgBox (0, "test", "Windows xp")
EndFunc

;Close ();meme commentaire que pour interlude
Func Close ()
       Exit
EndFunc

ça c'est ce qui ne va pas, compare avec ton code pour voir où est ce que j'ai mit des commentaires

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ComboConstants.au3>
#include <ButtonConstants.au3>

Opt("GUIOnEventMode", 1)

Global $test
; Variables Combo
Global $windowsxp = "Windows XP"
Global $windows_10 = "Windows 10"
Global $windows8 = "Windows 8"
Global $windows7 = "Windows 7"
;Variables boutton
Global $boutton32 = "32 bits"
Global $boutton64 = "64 bits"

ChoixOS ()

Func ChoixOS ()

	;~ Crée la GUI
	Global $boite = GUICreate ("Choix O$", 250, 175, 500, 250)
	GUISetOnEvent($GUI_EVENT_CLOSE,"close");on execute la fonction "close" quand qqun appuie sur la croix blanche sur fond rouge
	;(ou utilise alt+F4)
	
	;~ Message selectionnez...
	GUICtrlCreateLabel ("Selectionner la version de Windows", 20, 20, -1, -1, $CBS_DROPDOWN, $CBS_OEMCONVERT)

	; Création des deux boutons 64 et 32 bits
	GUICtrlCreateCheckbox ($boutton32, 45, 85, 45, 40, $BS_PUSHLIKE, $BS_AUTORADIOBUTTON)
	GUICtrlCreateCheckbox ($boutton64, 150, 85, 45, 40, $BS_PUSHLIKE, $BS_AUTORADIOBUTTON)

	;~ Crée le boutton "Suivant"
	Global $suite = GUICtrlCreateButton ("Suivant", 160, 150, 85, 25)
	GUICtrlSetOnEvent ($suite, "Interlude")

	;~ Crée la liste Combo
	Global $List = GUICtrlCreateCombo ($windows_10, 10, 50, 200, 200, $CBS_DROPDOWNLIST, $CBS_SORT)

	; Ajoute des éléments à la liste combo
	GUICtrlSetData (-1, $windowsxp)
	GUICtrlSetData (-1, $windows7)
	GUICtrlSetData (-1, $windows_10)
	GUICtrlSetData (-1, $windows8)

	GUISetState(@SW_SHOW, $boite)


	While 1
		sleep(10);oui ça sert pas à grand chose, mais j'aime pas laisser une boucle vide
	WEnd
EndFunc

;~ ; Fonction Interlude

Func Interlude ()
	Switch GUICtrlRead($List);j'utilise un switch, c'est plus joli et on fait appel à la fonction que une seule fois. Mais ça marche avec une succession de if/eslseif
		Case $windows7
			Windows7()
		Case $windows8
			Windows8()
		Case $windows_10
			Windows_10()
		Case $windowsxp
			Windowsxp()
	EndSwitch
EndFunc

Func Windows7 ()
MsgBox (0, "test", "Windows 7")
EndFunc

Func Windows8 ()
MsgBox (0, "test", "Windows 8")
EndFunc

Func Windows_10 ()
MsgBox (0, "test", "Windows 10")
EndFunc

Func Windowsxp ()
MsgBox (0, "test", "Windows xp")
EndFunc

Func Close ()
	Exit
EndFunc

Bonjour,
alors là merci bcp. Je me doutais que 2-3 trucs n'allaient pas j'y touchais depuis plusieurs jours sans trop faire gaffe pour faire plein de test comme j'étais bloqué. J'ai tout compris sauf pour la boucle j'vois pas pq ça marche pas si on l'enlève alors que y a juste une pause dedans (et que pause ou pas pause c'est pareil). Merci de ton aide ça m'a bien débloqué

AutoIt Français

Fonction par rapport au choix d'une ComboBox

Fonction par rapport au choix d'une ComboBox

Re: Fonction par rapport au choix d'une ComboBox

Re: Fonction par rapport au choix d'une ComboBox

Re: Fonction par rapport au choix d'une ComboBox

Re: Fonction par rapport au choix d'une ComboBox