[R] @DesktopWidth/@DesktopHeight

[Amesamana]

Bonjour,

Pour commencer de bonnes fêtes à tous

Je vous expose mon soucis !
Je veux dimensionner ma GUI pour n'importe quel écran.
Voici un bout de code :

Code : Tout sélectionner

Global $Button2 = GUICtrlCreateButton("Informations système", 14/1680*@DesktopWidth, 200/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)

L'interface se redimensionne très bien ainsi que les boutons, les inputs, et labels...
Par contre mon soucis et sur la police, je ne trouve pas comment faire pour la redimensionner
Merci.

[mikell]

Ta question est plus compliquée qu'elle n'en a l'air
Taille de gui, de controles et de police, avec taille d'écran variable mais aussi peut-être résolution d'écran variable ^^
Tu devrais lire ce sujet ça te donnera quelques réponses
Sinon faut être plus précis dans ta question, et si possible poster un code complet qu'on puisse tester

[Amesamana]

Bonjour mikell,

Merci pour cette réponse

Taille de gui, de controles et de police, avec taille d'écran variable mais aussi peut-être résolution d'écran variable ^^

Oui exactement.
Voici ma GUI

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <Constants.au3>
#include <EditConstants.au3>
#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <Inet.au3>
#include <WindowsConstants.au3>
#RequireAdmin
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=..\..\Downloads\Logitech-G7-Corrdless-2.ico
#AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#cs ----------------------------------------------------------------------------

 AutoIt Version : 3.3.8.1
 Auteur:         Amesam-ToolsDiags


#ce ----------

#include-once

Global $font = "Comic Sans MS"
Global $font1 = "segoe print"
Global $font2 = "Segoe Script"
Global $hosts = @SystemDir & "\drivers\etc\hosts"
Global $Now = @MDAY & "/" & @MON & "/" & @YEAR & " " & @HOUR & ":" & @MIN & ":" & @SEC
Global $obj_SR, $obj_WMI
Global $SystemDrive = EnvGet('SystemDrive') & '\'

Local $sUserName = "Administrateur"
Local $sPassword = "P@ssw0rd"
If not IsAdmin() Then
RunAs($sUserName, @ComputerName, $sPassword, 0, @ScriptFullPath, @ScriptDir)
Exit
EndIf


#Region ### START Koda GUI section ### Form=C:\Users\63\Desktop\form4.kxf
Global $Form1 = GUICreate("ToolsDiags - Amesam", 915/1680*@DesktopWidth, 730/1050*@DesktopHeight, 190/1680*@DesktopWidth, 125/1050*@DesktopHeight)
GUICtrlSetBkColor($Form1, 0xFFFFFF)
$Input1 = GUICtrlCreateInput("cmd.exe /C echo.&", 13/1680*@DesktopWidth, 648/1050*@DesktopHeight, 161/1680*@DesktopWidth, 5/1050*@DesktopHeight)
GUICtrlSetBkColor($Input1, 0xFF0000)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Edit1 = GUICtrlCreateEdit("", 200/1680*@DesktopWidth, 672/1050*@DesktopHeight, 417/1680*@DesktopWidth, 49/1050*@DesktopHeight, BitOR($GUI_SS_DEFAULT_EDIT,$WS_BORDER), BitOR($WS_EX_CLIENTEDGE,$WS_EX_STATICEDGE))
GUICtrlSetBkColor($Edit1, 0xFFFFCC)
GUICtrlSetColor($Edit1,0x0000FF)
Global $Edit2 = GUICtrlCreateEdit("", 200/1680*@DesktopWidth, 192/1050*@DesktopHeight, 417/1680*@DesktopWidth, 473/1050*@DesktopHeight, BitOR($GUI_SS_DEFAULT_EDIT,$WS_BORDER), BitOR($WS_EX_CLIENTEDGE,$WS_EX_STATICEDGE))
GUICtrlSetData(-1, "")
GUICtrlSetBkColor($Edit2, 0xFFFFCC)
GUICtrlSetCursor (-1, 0)

Global $Pic1 = GUICtrlCreatePic("C:\Users\63\Desktop\Images\bfee7d1895f445777160322afc7e3c99.jpg", 8/1680*@DesktopWidth, 8/1050*@DesktopHeight, 169/1680*@DesktopWidth, 169/1050*@DesktopHeight)

Global $Pic2 = GUICtrlCreatePic("C:\Users\63\Desktop\Images\malwares-troyanos.jpg", 664/1680*@DesktopWidth, 264/1050*@DesktopHeight, 201/1680*@DesktopWidth, 153/1050*@DesktopHeight)

Global $Graphic1 = GUICtrlCreateGraphic(184/1680*@DesktopWidth, 0/1050*@DesktopHeight, 18/1680*@DesktopWidth, 169/1050*@DesktopHeight)
GUICtrlSetGraphic(-1, $GUI_GR_PENSIZE, 3)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xFF0000, 0xFFFF00)
GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 7, 6)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 7, 154)

Global $Graphic2 = GUICtrlCreateGraphic(200/1680*@DesktopWidth, 176/1050*@DesktopHeight, 401/1680*@DesktopWidth, 12/1050*@DesktopHeight)
GUICtrlSetGraphic(-1, $GUI_GR_PENSIZE, 3)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xFF0000)
GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 0, 1)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 396, 1)

Global $Graphic3 = GUICtrlCreateGraphic(184/1680*@DesktopWidth, 192/1050*@DesktopHeight, 17/1680*@DesktopWidth, 479/1050*@DesktopHeight)
GUICtrlSetGraphic(-1, $GUI_GR_PENSIZE, 3)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xFF0000)
GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 8, 8)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 8, 482)

Global $Graphic4 = GUICtrlCreateGraphic(624/1680*@DesktopWidth, 200/1050*@DesktopHeight, 284/1680*@DesktopWidth, 8/1050*@DesktopHeight)
GUICtrlSetGraphic(-1, $GUI_GR_PENSIZE, 2)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xFF0000)
GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 6, 2)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 279, 2)

Global $Graphic5 = GUICtrlCreateGraphic(624/1680*@DesktopWidth, 128/1050*@DesktopHeight, 286/1680*@DesktopWidth, 8/1050*@DesktopHeight)
GUICtrlSetGraphic(-1, $GUI_GR_PENSIZE, 2)
GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xFF0000)
GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 8, 2)
GUICtrlSetGraphic(-1, $GUI_GR_LINE, 281, 2)

Global $Input2 = GUICtrlCreateInput("" & MemGetStats (), 752/1680*@DesktopWidth, 48/1050*@DesktopHeight, 155/1680*@DesktopWidth, 20/1050*@DesktopHeight) ; Memo total  ****Affichage ????****
GUICtrlSetBkColor($Input2, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input3_IpAddress = GUICtrlCreateInput("" & @IPAddress1, 408/1680*@DesktopWidth, 8/1050*@DesktopHeight, 201/1680*@DesktopWidth, 19/1050*@DesktopHeight)
GUICtrlSetBkColor($Input3_IpAddress, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input4_IpAddress = GUICtrlCreateInput("" & _GetIP(), 408/1680*@DesktopWidth, 32/1050*@DesktopHeight, 201, 19)
GUICtrlSetBkColor($Input4_IpAddress, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input5 = GUICtrlCreateInput("" & "CPU " & @CPUARCH & "        OS " & @OSARCH &"  "& @OSVersion, 408/1680*@DesktopWidth, 56/1050*@DesktopHeight, 201/1680*@DesktopWidth, 19/1050*@DesktopHeight)
GUICtrlSetBkColor($Input5, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)

Global $Input6 = GUICtrlCreateInput("Input6", 752/1680*@DesktopWidth, 72/1050*@DesktopHeight, 155/1680*@DesktopWidth, 20/1050*@DesktopHeight) ; % utilisation
GUICtrlSetBkColor($Input6, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input7 = GUICtrlCreateInput("Input7", 752/1680*@DesktopWidth, 96/1050*@DesktopHeight, 155/1680*@DesktopWidth, 20/1050*@DesktopHeight) ; Memo disponible
GUICtrlSetBkColor($Input7, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input8 = GUICtrlCreateInput("Input8", 752/1680*@DesktopWidth, 144/1050*@DesktopHeight, 155/1680*@DesktopWidth, 20/1050*@DesktopHeight); Pagefile total   ****Affichage ????****
GUICtrlSetBkColor($Input8, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input9 = GUICtrlCreateInput("Input9", 752/1680*@DesktopWidth, 168/1050*@DesktopHeight, 155/1680*@DesktopWidth, 20/1050*@DesktopHeight) ; Pagefile disponible
GUICtrlSetBkColor($Input9, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input10 = GUICtrlCreateInput("Input10", 752/1680*@DesktopWidth, 216/1050*@DesktopHeight, 155/1680*@DesktopWidth, 20/1050*@DesktopHeight) ; Virtuelle total   ****Affichage ????****
GUICtrlSetBkColor($Input10, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input11 = GUICtrlCreateInput("Input11", 752/1680*@DesktopWidth, 240/1050*@DesktopHeight, 155/1680*@DesktopWidth, 20/1050*@DesktopHeight) ; Virtuelle disponible
GUICtrlSetBkColor($Input11, 0xFFFFCC)
GUICtrlSetState(-1, $GUI_DISABLE)

Global $Progress1 = GUICtrlCreateProgress(632/1680*@DesktopWidth, 80/1050*@DesktopHeight, 102/1680*@DesktopWidth, 9/1050*@DesktopHeight)
Global $Progress2 = GUICtrlCreateProgress(632/1680*@DesktopWidth, 104/1050*@DesktopHeight, 102/1680*@DesktopWidth, 9/1050*@DesktopHeight)
Global $Progress3 = GUICtrlCreateProgress(632/1680*@DesktopWidth, 176/1050*@DesktopHeight, 102/1680*@DesktopWidth, 9/1050*@DesktopHeight)
Global $Progress4 = GUICtrlCreateProgress(632/1680*@DesktopWidth, 244/1050*@DesktopHeight, 102/1680*@DesktopWidth, 9/1050*@DesktopHeight)

Global $Label1 = GUICtrlCreateLabel("Pagefile total", 630/1680*@DesktopWidth, 144/1050*@DesktopHeight, 100/1680*@DesktopWidth, 17/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
GUICtrlSetColor($Label1,0x0000FF)
Global $Label2 = GUICtrlCreateLabel("Votre IP Local", 208/1680*@DesktopWidth, 8/1050*@DesktopHeight, 156/1680*@DesktopWidth, 17/1050*@DesktopHeight)
GUICtrlSetFont(-1, 10, 400, 2, $font)
GUICtrlSetColor($Label2,0x0000FF)
Global $Label3 = GUICtrlCreateLabel("Votre IP Publique", 208/1680*@DesktopWidth, 32/1050*@DesktopHeight, 156/1680*@DesktopWidth, 17/1050*@DesktopHeight)
GUICtrlSetFont(-1, 10, 400, 2, $font)
GUICtrlSetColor($Label3,0x0000FF)
Global $Label4 = GUICtrlCreateLabel("Votre CPU et OS", 208/1680*@DesktopWidth, 56/1050*@DesktopHeight, 156/1680*@DesktopWidth, 17/1050*@DesktopHeight)
GUICtrlSetFont(-1, 10, 400, 2, $font)
GUICtrlSetColor($Label4,0x0000FF)
Global $Label5 = GUICtrlCreateLabel("Physique -RAM-", 630/1680*@DesktopWidth, 48/1050*@DesktopHeight, 100/1680*@DesktopWidth, 17/1050*@DesktopHeight)
GUICtrlSetFont(-1, 10, 400, 2, $font)
GUICtrlSetColor($Label5,0x0000FF)
Global $Label6 = GUICtrlCreateLabel("virtuelle total", 630/1680*@DesktopWidth, 216/1050*@DesktopHeight, 100/1680*@DesktopWidth, 17/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
GUICtrlSetColor($Label6,0x0000FF)
Global $Label7 = GUICtrlCreateLabel("Activités de la mémoire", 680/1680*@DesktopWidth, 8/1050*@DesktopHeight, 228/1680*@DesktopWidth, 19/1050*@DesktopHeight)
GUICtrlSetFont(-1, 12, 400, 2, $font)
GUICtrlSetColor($Label7,0x0000FF)

Global $Button1 = GUICtrlCreateButton("Rapport général", 14/1680*@DesktopWidth, 600/1050*@DesktopHeight, 161/1680*@DesktopWidth, 42/1050*@DesktopHeight, BitOR($BS_COMMANDLINK, $BS_DEFCOMMANDLINK))
Global $Button2 = GUICtrlCreateButton("Informations système", 14/1680*@DesktopWidth, 200/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button3 = GUICtrlCreateButton("Configuration de l'IP", 14/1680*@DesktopWidth, 240/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button4 = GUICtrlCreateButton("Afficher les TEMP\Cookies", 14/1680*@DesktopWidth, 280/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button5 = GUICtrlCreateButton("Programmes et Run", 14/1680*@DesktopWidth, 320/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button6 = GUICtrlCreateButton("Afficher System32", 14/1680*@DesktopWidth, 360/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button7 = GUICtrlCreateButton("Afficher les drivers", 14/1680*@DesktopWidth, 400/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button8 = GUICtrlCreateButton("Tâches/Services exécutés", 14/1680*@DesktopWidth, 440/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button9 = GUICtrlCreateButton("Ports ouverts", 14/1680*@DesktopWidth, 480/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button10 = GUICtrlCreateButton("Statistiques connexions/IP", 14/1680*@DesktopWidth, 520/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button11 = GUICtrlCreateButton("Options Menu Clic Droit", 14/1680*@DesktopWidth, 660/1050*@DesktopHeight, 161/1680*@DesktopWidth, 49/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button12 = GUICtrlCreateButton("SFC /Scannow", 14/1680*@DesktopWidth, 560/1050*@DesktopHeight, 161/1680*@DesktopWidth, 33/1050*@DesktopHeight)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button13 = GUICtrlCreateButton(" Clean hosts avec ToolsDiags ", 408/1680*@DesktopWidth, 80/1050*@DesktopHeight, 201/1680*@DesktopWidth, 25/1050*@DesktopHeight, $BS_LEFT)
_GUICtrlButton_SetShield($button13)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button14 = GUICtrlCreateButton(" Modifier le fichier hosts", 208/1680*@DesktopWidth, 112/1050*@DesktopHeight, 193/1680*@DesktopWidth, 25/1050*@DesktopHeight, $BS_LEFT)
 _GUICtrlButton_SetShield($button14)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button15 = GUICtrlCreateButton(" Quitter", 640/1680*@DesktopWidth, 664/1050*@DesktopHeight, 257/1680*@DesktopWidth, 57/1050*@DesktopHeight, -1, BitOR($BS_COMMANDLINK, $BS_DEFCOMMANDLINK))
GUICtrlSetFont(-1, 12, 400, 2, $font)
GUICtrlSetBkColor($Button15, 0xCCFFFF)
Global $Button16 = GUICtrlCreateButton(" Visionner le fichier hosts", 208/1680*@DesktopWidth, 80/1050*@DesktopHeight, 193/1680*@DesktopWidth, 25/1050*@DesktopHeight, $BS_LEFT)
 _GUICtrlButton_SetShield($button16)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button19 = GUICtrlCreateButton("   Nettoyage général de l'ordinateur ", 632/1680*@DesktopWidth, 424/1050*@DesktopHeight, 273/1680*@DesktopWidth, 33/1050*@DesktopHeight, $BS_LEFT)
_GUICtrlButton_SetShield     ($button19)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button20 = GUICtrlCreateButton("   Supprimer le points de restauration ", 632/1680*@DesktopWidth, 464/1050*@DesktopHeight, 273/1680*@DesktopWidth, 33/1050*@DesktopHeight, $BS_LEFT)
 _GUICtrlButton_SetShield($button20)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button21 = GUICtrlCreateButton("   Création d'un point de restauration ", 632/1680*@DesktopWidth, 504/1050*@DesktopHeight, 273/1680*@DesktopWidth, 33/1050*@DesktopHeight,  $BS_LEFT)
 _GUICtrlButton_SetShield($button21)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button22 = GUICtrlCreateButton("   Gestion du volume des sauvgardes", 632/1680*@DesktopWidth, 544/1050*@DesktopHeight, 273/1680*@DesktopWidth, 33/1050*@DesktopHeight, $BS_LEFT)
 _GUICtrlButton_SetShield($button22)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button23 = GUICtrlCreateButton("Désactiver l'autorun par défaut dans Windows", 632/1680*@DesktopWidth, 584/1050*@DesktopHeight, 273/1680*@DesktopWidth, 33/1050*@DesktopHeight)
; _GUICtrlButton_SetShield($button23)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button24 = GUICtrlCreateButton("Redémarrer pour valider les modifications", 632/1680*@DesktopWidth, 624/1050*@DesktopHeight, 273/1680*@DesktopWidth, 33/1050*@DesktopHeight)
 ;_GUICtrlButton_SetShield($button24)
GUICtrlSetFont(-1, 9, 400, 2, $font)
Global $Button25 = GUICtrlCreateButton("Copier le résultat de la commande ", 208/1680*@DesktopWidth, 144/1050*@DesktopHeight, 401/1680*@DesktopWidth, 25/1050*@DesktopHeight)
GUICtrlSetBkColor($Button25, 0xFFCC00)
GUICtrlSetFont(-1, 9, 400, 2, $font2)
Global $Button26 = GUICtrlCreateButton(" Restaurer le hosts à l'origine ", 408/1680*@DesktopWidth, 112/1050*@DesktopHeight, 201/1680*@DesktopWidth, 25/1050*@DesktopHeight, $BS_LEFT)
_GUICtrlButton_SetShield($button26)
GUICtrlSetFont(-1, 9, 400, 2, $font)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

while 1

#cs##############################################
Valeur de retour
Retourne un tableau de sept éléments contenant les informations sur la mémoire:

$ Array [0] = Charge Memory (pourcentage de mémoire utilisée)
$ Array [1] = RAM physique totale
$ Array [2] = RAM physique disponible
$ Array [3] = Pagefile totale
$ Array [4] = Pagefile Disponible
$ Array [5] = Total virtuelle
$ Array [6] = Disponible virtuelle

Toutes les tailles de mémoire sont en kilo-octets.
#ce##############################################
                $memo = MemGetStats()
                $Label1 = $memo[1]
                $memo2 = $memo[0]
                $memo3 = $memo[2]
                $Label5 = $memo[3]
                $memo5 = $memo[4]
                $Label6 = $memo[5]
                $memo7 = $memo[6]
                Switch $memo2
                    Case 0 To 100

                        $st = StringRight($memo2, 2)
                        $st1 = StringRight($memo3, 2)
                        $st2 = StringRight($memo5, 2)
                        $st3 = StringRight($memo7, 2)
                        $Mem = MemGetStats ( )
                        $MemTot = Round ( ( $Mem[1] ) / 1024 , 0 ) + 1
                        GUICtrlSetData($Input2, $MemTot & "   Mo de mémoire")
                        GUICtrlSetData($Input6, $memo2 & "   %  de mémoire utilisée")
                        GUICtrlSetData($Input7, $memo3 & "   Ko  Disponible")
                        GUICtrlSetData($Input8, $Label5 & "   Ko  de mémoire")
                        GUICtrlSetData($Input9, $memo5 & "   Ko  Disponible")
                        GUICtrlSetData($Input10, $Label6 & "   Ko  de mémoire")
                        GUICtrlSetData($Input11, $memo7 & "  Ko  Disponible")
                        GUICtrlSetData($Progress1, $st)
                        GUICtrlSetData($Progress2, $st1)
                        GUICtrlSetData($Progress3, $st2)
                        GUICtrlSetData($Progress4, $st3)

EndSwitch
                $nMsg = GUIGetMsg()
                Switch $nMsg
                     Case $GUI_EVENT_CLOSE
                     Exit
 EndSwitch
WEnd
 

J'ai fait un petit test suite au lien que tu as donné.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>


$LogPixels = _GetLogPixels()
Global $s = $LogPixels / 96
_Gui()
    While 1
    Sleep(10) ; pourquoi un sleep ici ?
    Wend

Func _Gui()

Global $Form1 = GUICreate("Form1", 623*$s, 171*$s, 192, 124)
Global $Button1 = GUICtrlCreateButton("Button1JGFQKEGHGGGGGGGTTTTTT ", 16*$s, 16*$s, 201*$s, 25*$s)
Global $Button2 = GUICtrlCreateButton("Button2", 16*$s, 64*$s, 201*$s, 25*$s)
Global $Button3 = GUICtrlCreateButton("Button3", 16*$s, 112*$s, 201*$s, 25*$s)
Global $Label1 = GUICtrlCreateLabel("Label1 pour faire le test", 248*$s, 16*$s, 188*$s, 17*$s)
Global $Input1 = GUICtrlCreateInput("Input1 pour faire le test", 464*$s, 16*$s, 145*$s, 21*$s)
GUISetState(@SW_SHOW)
EndFunc

Func _GetLogPixels()
    $objWMIService = ObjGet("winmgmts:\\.\root\CIMV2")
     $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_DisplayConfiguration")
    For $objItem In $colItems
          $ppp = $objItem.LogPixels
      Next
      Return $ppp
  EndFunc
 

Cette solution semble fonctionner sur mes PC, mais je n'ai pas tout compris
A tester sur ma GUI.
Ici la taille 96 est la taille normale, mais sur d'avoir pigé.

[Amesamana]

Bonjour,

Bon mes test ne sont pas concluant
J'ai refais une GUI vite faite (grossière) sur mon écran 1680*1050 et refais un test.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>



Global $font = "Comic Sans MS"
 $LogPixels = _GetLogPixels()
    Global $s = $LogPixels / 96
    _Gui()
        While 1
        Sleep(10) ; pourquoi un sleep ici ?
        Wend

    Func _Gui()

#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Form1", 1365*$s, 817*$s, 192*$s, 124*$s)
Global $Button1 = GUICtrlCreateButton("Ceci est un test de dimension de la gui et police", 200*$s, 24*$s, 1025*$s, 73*$s)
GUICtrlSetFont(-1, 12, 400, 2, $font)
Global $Button2 = Ceci est un test de dimension de la gui et police", 200*$s, 128*$s, 1025*$s, 153*$s)
GUICtrlSetFont(-1, 14, 400, 2, $font)
Global $Button3 = GUICtrlCreateButton("Ceci est un test de dimension de la gui et police", 192*$s, 328*$s, 1033*$s, 281*$s)
GUICtrlSetFont(-1, 16, 400, 2, $font)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd
    EndFunc
    Func _GetLogPixels()
        $objWMIService = ObjGet("winmgmts:\\.\root\CIMV2")
         $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_DisplayConfiguration")
        For $objItem In $colItems
              $ppp = $objItem.LogPixels
          Next
          Return $ppp
      EndFunc

 

Si je compile et que je visionne sur un écran 1024*768 ça ne fonctionne pas.
Il me semblais bien que je n'avais pas compris quelques chose.
Ou est mon erreur ?

[mikell]

Qu'est-ce qui ne fonctionne pas ?
ou plutôt, qu'est-ce qui va bien et qu'est-ce qui ne va pas ?

[Amesamana]

Le redimensionnement ne fonctionne pas, j'ai surement fait une ou plusieurs erreur ?
Le dernier test est fait depuis un PC avec un écran en 1680*1050, une fois compilé je test le .exe sur un PC avec un écran 1024*768 et la GUI n'est pas redimensionner par rapport à l'écran.

J'ai fait exprès de faire une grande GUi pour le test 1365, 817, mais elle ne s'adapte pas au différente résolution ?
La première solution fonctionne (@DesktopWidth/@DesktopHeight) sauf la police.

[mikell]

C'est peut-être simplement parce que LogPixels = 96 sur les 2 pc
Facile à vérifier avec un

Code : Tout sélectionner

msgbox(0,"", _GetLogPixels() )

Mais si tu redimensionnes les boutons, alors tu peux essayer tout à fait autre chose dans ton 1er code, la fonction StringSize de M23, exemple :

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <SendMessage.au3>
#include <WinAPI.au3>

$txt  = "Test de police"
$gui = GUICreate("Test", 300, 300)
$btn1 = GUICtrlCreateButton($txt, 10, 10, 120, 40)
$btn2 = GUICtrlCreateButton($txt, 10, 60, 170, 45)
$btn3 = GUICtrlCreateButton($txt, 10, 115, 220, 50)
$btn4 = GUICtrlCreateButton($txt, 10, 175, 270, 55)
GUISetState()
   
$sFont = "Comic Sans MS"
$iWeight = 400
$iAttrib = 0

For $b = $btn1 To $btn4
    $pos = ControlGetPos ($gui, "", $b)
    For $i = 24 To 8 step -2
        $aMsgReturn = _StringSize($txt, $i, $iWeight, $iAttrib, $sFont)
        If $aMsgReturn[2]<$pos[2] AND $aMsgReturn[3]<$pos[3] Then ExitLoop
    Next
    $iSize = $i
    GUICtrlSetFont($b, $iSize, $iWeight, $iAttrib, $sFont)
Next
   
While GUIGetMsg()<>-3  
WEnd

;-----------------------------------------------------------------------

Func _StringSize($sText, $iSize = Default, $iWeight = Default, $iAttrib = Default, $sName = Default, $iWidth = 0)
   
    Local $hWnd, $hFont, $hDC, $oFont, $tSize, $hGUI, $hText_Label, $sTest_Line
    Local $iLine_Width, $iWrap_Count, $iLast_Word, $iLine_Count
    Local $asLines[1], $avSize_Info[4], $aiPos[4]
    If Not IsString($sText) Then Return SetError(1, 1, 0)
    If Not IsNumber($iSize) And $iSize <> Default   Then Return SetError(1, 2, 0)
    If Not IsInt($iWeight)  And $iWeight <> Default Then Return SetError(1, 3, 0)
    If Not IsInt($iAttrib)  And $iAttrib <> Default Then Return SetError(1, 4, 0)
    If Not IsString($sName) And $sName <> Default   Then Return SetError(1, 5, 0)
    If Not IsNumber($iWidth) Then Return SetError(1, 6, 0)

    $hGUI = GUICreate("", 1200, 500, 10, 10)
        If $hGUI = 0 Then Return SetError(2, 0, 0)
        GUISetFont($iSize, $iWeight, $iAttrib, $sName)
    $avSize_Info[0] = $sText
    If StringInStr($sText, @CRLF) = 0 Then StringRegExpReplace($sText, "[x0a|x0d]", @CRLF)
    $asLines = StringSplit($sText, @CRLF, 1)
    $hText_Label = GUICtrlCreateLabel($sText, 10, 10)
    $aiPos = ControlGetPos($hGUI, "", $hText_Label)
    GUICtrlDelete($hText_Label)
    $avSize_Info[1] = ($aiPos[3] - 8)/ $asLines[0]
    $avSize_Info[2] = $aiPos[2]
    $avSize_Info[3] = $aiPos[3] - 4; Reduce margin
    If $aiPos[2] > $iWidth And $iWidth > 0 Then
         $avSize_Info[0] = ""
        $avSize_Info[2] = $iWidth
         $iLine_Count = 0
         For $j = 1 To $asLines[0]
             $hText_Label = GUICtrlCreateLabel($asLines[$j], 10, 10)
            $aiPos = ControlGetPos($hGUI, "", $hText_Label)
            GUICtrlDelete($hText_Label)
            If $aiPos[2] < $iWidth Then
                 $iLine_Count += 1
                $avSize_Info[0] &= $asLines[$j] & @CRLF
            Else
                $hText_Label = GUICtrlCreateLabel("", 0, 0)
                $hWnd = ControlGetHandle($hGui, "", $hText_Label)
                $hFont = _SendMessage($hWnd, $WM_GETFONT)
                $hDC = _WinAPI_GetDC($hWnd)
                $oFont = _WinAPI_SelectObject($hDC, $hFont)
                If $oFont = 0 Then Return SetError(3, 0, 0)
                $iWrap_Count = 0

                While 1
                     $iLine_Width = 0
                     $iLast_Word = 0
                    For $i = 1 To StringLen($asLines[$j])
                        If StringMid($asLines[$j], $i, 1) = " " Then $iLast_Word = $i - 1
                         $sTest_Line = StringMid($asLines[$j], 1, $i)
                        GUICtrlSetData($hText_Label, $sTest_Line)
                        $tSize = _WinAPI_GetTextExtentPoint32($hDC, $sTest_Line)
                        $iLine_Width = DllStructGetData($tSize, "X")
                        If $iLine_Width >= $iWidth - Int($iSize / 2) Then ExitLoop
                    Next
                     If $i > StringLen($asLines[$j]) Then
                        $iWrap_Count += 1
                        $avSize_Info[0] &= $sTest_Line & @CRLF
                        ExitLoop
                    Else
                        $iWrap_Count += 1
                        If $iLast_Word = 0 Then
                            GUIDelete($hGUI)
                            Return SetError(4, 0, 0)
                        EndIf
                        $avSize_Info[0] &= StringLeft($sTest_Line, $iLast_Word) & @CRLF
                        $asLines[$j] = StringTrimLeft($asLines[$j], $iLast_Word)
                        $asLines[$j] = StringStripWS($asLines[$j], 1)
                    EndIf
                WEnd
                $iLine_Count += $iWrap_Count
                _WinAPI_ReleaseDC($hWnd, $hDC)
                GUICtrlDelete($hText_Label)
            EndIf
        Next
        $avSize_Info[3] = ($iLine_Count * $avSize_Info[1]) + 4
    EndIf
    GUIDelete($hGUI)
    Return $avSize_Info
EndFunc; => _StringSize
 

[Amesamana]

Bonjour mikell,

Désolé pour la réponse tardive.
J'ai fait quelques test avec la dernière solution et ça fonctionne très bien sur de petites GUI.
Il me reste juste à adapter tout ceci à ma GUI

GetLogPixels :

► Afficher le texte

Code : Tout sélectionner

MsgBox(0, "GetLogPixels", "Resultat  " & _GetLogPixels())

Func _GetLogPixels()
        $objWMIService = ObjGet("winmgmts:\\.\root\CIMV2")
         $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_DisplayConfiguration")
        For $objItem In $colItems
              $ppp = $objItem.LogPixels
          Next
          Return $ppp
EndFunc

Effectivement le résultat est de 96 sur les deux PC
96 c'est bien la taille de la police par défaut ?
Je ne comprends pas pourquoi je me retrouve avec la même et deux écran différent ?
L'écran n'a rien à voir tu vas me dire.
Mais cette fonction sert à quoi au juste ?
Si elle ne traite pas la dimension par rapport à la résolution ?
Y a un truc que j'ai pas pigé !

Merci pour cet échange !
Je mets le sujet en résolu car le redimensionnement de la police fonctionne
Bonne fêtes de fin d'année.