[..] La transparence des images

[Rizotto]

Bonsoir,

Actuellement sur un projet personnel, j'intègre des images en guise de bouton sur une barre. Mes images étant au format .png pour gérer la transparence, j'ai dû passer par un UDF. Jusque là, aucun problème (mise à part une mauvaise qualité d'image, mais c'est autre chose), si mon image est un rond, les angles du bouton seront invisibles.

Mais mon problème vient de la couleur. En effet, mon image est un bouton de forme carré, et qui est blanc transparent (donc c'est la couleur qui est transparente, mais pas totalement pour qu'on puisse distinguer le carré ). Quand je lance mon script, le .png est transparent, mais le fond est noir, et c'est là que je bloque, je ne sais pas comment faire. Mon but c'est que le bouton transparent laisse voir le fond d'écran du bureau (mon script sera une barre de raccourcis).

Il faut savoir que mon bouton se trouve sur une barre transparente.

Merci par avance.

[mikell]

Tu le posterais pas ton png récalcitrant ?

[Rizotto]

Je ne sais pas ce que ça va donner étant donné qu'il est transparent.

[mikell]

Ton png ne pose aucun problème, il marche bien avec ce script trouvé sur le forum

► Afficher le texte

Code : Tout sélectionner

; bande glissante - clic => action, clic droit => exit

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#include <GDIPlus.au3>
Opt("GUIOnEventMode", 1)

Global Const $AC_SRC_ALPHA  = 1
Global $aSP, $gui[5][2]
_GDIPlus_Startup()

$carre = @ScriptDir & "\Z0Vb57a.png"

For $i = 0 to 4
$gui[$i][0] = _CreateGui($i, $carre)
Next
_GDIPlus_Shutdown()

While 1
 Sleep(10)
Wend

;==========================================
Func _CreateGui($n, $img)
Local $hImage = _GDIPlus_ImageLoadFromFile($img)
$iX = _GDIPlus_ImageGetWidth ($hImage)
$iY = _GDIPlus_ImageGetHeight ($hImage)
Local $gui0 =GuiCreate("", $iX/2, $iY/2, @desktopwidth/3+($iX/2+10)*$n, 20, $WS_POPUP, BitOr($WS_EX_LAYERED, $WS_EX_TOPMOST))
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "_GereMoiCeTruc")
GUISetOnEvent($GUI_EVENT_SECONDARYUP, "_Exit")
SetBitMap($gui0, $hImage, 200)
GuiSetState()
_GDIPlus_ImageDispose($hImage)
Return $gui0
EndFunc


Func _GereMoiCeTruc()
    $aSP = MouseGetPos()
    For $i = 0 to 4
    $pos = WinGetPos($gui[$i][0])
    $gui[$i][1] = $pos[0]
    Next
    Do
        $aMP = MouseGetPos()
        $dif = $aMP[0] - $aSP[0]
    For $i = 0 to 4
        If $gui[$i][1]+$dif > @desktopwidth-$pos[2] Then $gui[$i][1] -= @desktopwidth-$pos[2]
        If $gui[$i][1]+$dif < 0 Then $gui[$i][1] += @desktopwidth-$pos[2]
        WinMove($gui[$i][0], "", $gui[$i][1]+$dif, 20)
    Next
    Until Not _IsPressed("01")
    $aNP = MouseGetPos()
    If $aNP[0] = $aSP[0] Then _Events()
EndFunc


Func _Events()
For $i = 0 to 4
   If @GUI_WinHandle = $gui[$i][0] Then Msgbox(0,"", "cliqué " & $i+1)
Next
EndFunc


Func _Exit()
  Exit
EndFunc


Func SetBitmap($hGUI, $hImage, $iOpacity)
  Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend

  $hScrDC  = _WinAPI_GetDC(0)
  $hMemDC  = _WinAPI_CreateCompatibleDC($hScrDC)
  $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
  $hOld    = _WinAPI_SelectObject($hMemDC, $hBitmap)
  $tSize   = DllStructCreate($tagSIZE)
  $pSize   = DllStructGetPtr($tSize  )
  DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth ($hImage)/2)
  DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage)/2)
  $tSource = DllStructCreate($tagPOINT)
  $pSource = DllStructGetPtr($tSource)
  $tBlend  = DllStructCreate($tagBLENDFUNCTION)
  $pBlend  = DllStructGetPtr($tBlend)
  DllStructSetData($tBlend, "Alpha" , $iOpacity    )
  DllStructSetData($tBlend, "Format", $AC_SRC_ALPHA)
  _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
  _WinAPI_ReleaseDC   (0, $hScrDC)
  _WinAPI_SelectObject($hMemDC, $hOld)
  _WinAPI_DeleteObject($hBitmap)
  _WinAPI_DeleteDC    ($hMemDC)
EndFunc
 

Donc c'est probablement le codage des gui

[Rizotto]

Après réflexion je pense que le problème pourrait venir de ma form. Ma form est une barre invisible, sur laquelle il y a des boutons (qui sont des images .png). Il semblerait donc que ce soit ma form qui pose problème, car la couleur qui apparaît quand elle n'est pas invisible est le noir.

Mais il reste toujours un problème, comment faire pour que ma barre soit invisible et que mes .png puissent être transparentes ?

[mikell]

Tu as testé le script de mon post précédent ?

[Rizotto]

Je viens d'essayer ton code (je n'ai pas pu le tester plus tôt), et là ça fonctionne.
Dans ton script, chaque bouton correspond à une form différente, moi j'ai 4 boutons pour une form. Et ma form est transparente. Donc je me demande si ça ne vient pas du fait qu'elle soit transparente, avec les .png transparents ça ne doit pas convenir.

[mikell]

Pas de réponse possible si tu montre pas le code pour ta gui et tes boutons

[Rizotto]

Oui, ça pourrait aider. J'ai enlevé les parties qui ne servaient à rien, et j'ai laissé un exemple avec un bouton. Pour la création du raccourcis, rien ne fonctionne, là c'est juste pour montrer le principe.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include "GUICtrlPic.au3"
#include <WinAPI.au3>
#include <EditConstants.au3>


#Region ### START Koda GUI section ### Barre
Global $Form1 = GUICreate("Raccourcis", 255, 70, -1, @DesktopHeight-120,$WS_POPUP,$WS_SYSMENU + $WS_EX_TOOLWINDOW)
Global $Label1 = GUICtrlCreateLabel("", 0, 5, 50, 17, $SS_CENTER)
GUICtrlSetFont(-1, 8, 400, 0, "TimeNewRoman")
Global $Button1 = _GUICtrlPic_Create("C:\CHEMIN\Carreoff.png" , 0, 20, 50, 50) ;Le bouton pour afficher la fenêtre de raccourcis
GUICtrlSetCursor (-1, 0)
Global $Button1bis = _GUICtrlPic_Create("C:\CHEMIN\Carre.png" , 0, 20, 50, 50) ;Le bouton qui lance le raccourcis
GUICtrlSetCursor (-1, 0)
Global $option = GUICtrlCreateButton("X", 240, 20, 15, 15) ;Le bouton "option"
GUICtrlSetCursor (-1, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

#Region ### START Koda GUI section ### Option
Global $Form2 = GUICreate("Raccourcis - options", 268, 161, -1, -1)
Global $Group1 = GUICtrlCreateGroup("Reset", 16, 8, 113, 145)
Global $Checkbox1 = GUICtrlCreateCheckbox("Raccourcis 1", 24, 24, 97, 17)
Global $Button5 = GUICtrlCreateButton("Reset", 32, 120, 75, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Button6 = GUICtrlCreateButton("Ok", 160, 120, 75, 25)
Global $Group2 = GUICtrlCreateGroup("Quitter", 144, 8, 113, 97)
Global $Button7 = GUICtrlCreateButton("Quitter", 162, 48, 75, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
#EndRegion ### END Koda GUI section ###

#Region ### START Koda GUI section ### R1
Global $Form3 = GUICreate("Créer un raccourcis", 347, 264, -1, -1)
Global $Label5 = GUICtrlCreateLabel("Fenêtre vide, à titre d'exemple", 24, 100, 262, 17)
#EndRegion ### END Koda GUI section ###

Local $color = 0x121314 ;Cette partie sert à mettre le fond invisible
GUISetBkColor($color, $Form1) ; ""
_WinAPI_SetLayeredWindowAttributes($Form1, $color,255) ; ""
GUISetState() ; ""

While 1
 $nMsg = GUIGetMsg(1)
 Switch $nMsg[0]
    Case $GUI_EVENT_CLOSE
        If $nMsg[1] = $Form2 Then ;Si le message de fermer vient de la Form2
            GUISetState(@SW_HIDE,$Form2) ;On la masque
        ElseIf $nMsg[1] = $Form3 Then
            GUISetState(@SW_HIDE,$Form3)
        Else
            Exit
        EndIF
Case $option
    GUISetState(@SW_SHOW,$Form2)
Case $Button7
    Exit
Case $Button6
    GUISetState(@SW_HIDE,$Form2)
Case $Button1
    GUISetState(@SW_SHOW,$Form3)
 EndSwitch
WEnd

Le "GUICtrlPic" est un UDF trouvé sur internet (peut-être sur ce forum ?) pour rendre la form1 invisible.