[R] Double systeme d'onglets

[drov]

Bonjour ! Me voila une fois de plus face à un problème : j'aimerais créer deux système d'onglets dans une même gui.

Je m'explique un peu plus : je fais actuellement un jeu gestion de pirates. Or j'ai fait un onglet "équipage" et je me suis dit "au lieu de faire une fenêtre toute moche avec toutes les professions ( chirurgien , cuisinier, quartier maitre etc) je vais faire un système d'onglets dans le système d'onglet comme ça je suis tranquille ! sauf que quand j'ai créé un autre système d'onglet, horreur ! Il est considéré comme un onglet et viens se placer en haut.

une idée ?

[yayasse]

Tu pourrait nous donner un exemples de code parce que là j'ai du mal à comprendre :/ J'aime que la pratique moi :p

[mikell]

ONLY one Tab control can be created by window. But a script can creates several windows having a tab in.

Donc dans ton 1er onglet tu mets une gui popup, et dans cette gui tu mets ton 2ème système d'onglets
Bon courage ^^

[drov]

C'est ce que je craignais ^^'

qu'entendez vous par gui popup ? une autre gui ?

[ayuckers]

Bonjour,

@DRov : je me suis poser la meme question il y a 2 jours et voici le resultat de mes recherche.

Exemple fonctionnel sur Autoit V3.6

Exemple 1 : Permet d'avoir 2 system d'onglet dans la meme fenetre.

► Afficher le texte

#include <GUIConstants.au3>
#include <WindowsConstants.au3>

$main_GUI = GUICreate("Tab Sample", 600, 300, -1, -1);, BitOr($GUI_SS_DEFAULT_GUI,$WS_CLIPSIBLINGS))
$cancel_button = GUICtrlCreateButton("Cancel", 220, 270, 70, 20)
GUISetState()

$child1 = GUICreate("", 250, 215, 15, 40, BitOr($WS_CHILD,$WS_TABSTOP), -1, $main_GUI)
GUISetBkColor(0x257788)
$child1_tab = GUICtrlCreateTab(5,5, 230, 180)
$child1_tabitem1 = GUICtrlCreateTabItem("Child1Tab1")
$child1_tabitem2 = GUICtrlCreateTabItem("Child1Tab2")
GUICtrlCreateTabItem("")
GUISetState()

$child2 = GUICreate("", 250, 215, 350, 40, BitOr($WS_CHILD,$WS_TABSTOP), -1, $main_GUI)
GUISetBkColor(0x257788)
$child2_tab = GUICtrlCreateTab(5, 5, 230, 180)
$child2_tabitem1 = GUICtrlCreateTabItem("Child2Tab1")
$child2_tabitem2 = GUICtrlCreateTabItem("Child2Tab2")
GUICtrlCreateTabItem("")
GUISetState()

While 1
$msg = GUIGetMsg(1)
Select
Case $msg[0] = $GUI_EVENT_CLOSE Or $msg[0] = $cancel_button
ExitLoop
EndSelect
WEnd

Exemple 2 : permet de metre des onglet dans des onglet (version simplifier de l'exemple du lien si dessous)

► Afficher le texte

#include <GUIConstants.au3>
#include <WindowsConstants.au3>

$main_GUI = GUICreate("Tab Sample", 400, 300, -1, -1);, BitOr($GUI_SS_DEFAULT_GUI,$WS_CLIPSIBLINGS))
$ok_button = GUICtrlCreateButton("OK", 110, 270, 70, 20)
$cancel_button = GUICtrlCreateButton("Cancel", 220, 270, 70, 20)
GUISetState()

; Creates the first child window that is implemented into the main GUI
$child1 = GUICreate("", 170, 215, 15, 40, BitOr($WS_CHILD,$WS_TABSTOP), -1, $main_GUI)
;GUISetBkColor(0x257788); just for dimensing the child
$child1_tab = GUICtrlCreateTab(0, 0, 160, 215)
$child1_tabitem1 = GUICtrlCreateTabItem("Child1Tab1")
$child1_tabitem2 = GUICtrlCreateTabItem("Child1Tab2")
$child1_tabitem3 = GUICtrlCreateTabItem("Child1Tab3")
GUICtrlCreateTabItem("")
GUISetState()

; Creates the second child window that is implemented into the main GUI
$child2 = GUICreate("", 170, 215, 180, 40, BitOr($WS_CHILD,$WS_TABSTOP), -1, $main_GUI)
;GUISetBkColor(0x257788); just for dimensing the child

GUISwitch($child2)
$child2_tab = GUICtrlCreateTab(0, 0, 156, 215)
$child2_tabitem1 = GUICtrlCreateTabItem("Child2Tab1")
$child2_tabitem2 = GUICtrlCreateTabItem("Child2Tab2")
GUICtrlCreateTabItem("")

; Switch back the main GUI and create the tabs
GUISwitch($main_GUI)
$main_tab = GUICtrlCreateTab(10, 10, 380, 250)
$main_tabitem1 = GUICtrlCreateTabItem("MainTab1")
$main_tabitem2 = GUICtrlCreateTabItem("MainTab2")
GUICtrlCreateTabItem("")
GUICtrlSetState($main_tabitem1,$GUI_SHOW)


While 1
$msg = GUIGetMsg(1)
Select
Case $msg[0] = $GUI_EVENT_CLOSE Or $msg[0] = $cancel_button
ExitLoop

Case $msg[0] = $main_tab
$tabidx = GUICtrlRead($main_tab)
Select
Case $tabidx = 0
GUISetState(@SW_HIDE, $child2)
GUISetState(@SW_SHOW, $child1)

Case $tabidx = 1
GUISetState(@SW_HIDE, $child1)
GUISetState(@SW_SHOW, $child2)
EndSelect
EndSelect
WEnd

Voici ma sources :
http://www.autoitscript.com/forum/topic ... ntry448754