[..] Problème d'utilisations de ComboBox

Telni · #1

J'suis en train de faire un petit soft pas bien compliqué, ni même bien utile, pour une présentation orale devant un jury, histoire de passer mon BTS.
C'est une feuille de calculs simplifiée, pour les lancers de dés à D&D. Oui, c'est loin d'être complet, et ça doit déjà exister. Mais bon... Faut bien débuter ^^;

Bref. Lorsque je définis la combobox pour le choix des armes, j'ai plusieurs soucis :

1-Création de la box :

Code : Tout sélectionner

Global $CBarme = GUICtrlCreateCombo("Choisir une arme", 40, 112, 105, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
            GUICtrlSetData(-1,"1d2|1d4|1d6|1d8|1d10|1d12|2d4|2d6")

(le Global et la fin de la première ligne sont générés par Koda, je ne sais pas si je dois les laisser ? )
Sinon, à l'affichage, tout se passe bien.

2-Utilisation des valeurs:
Évidemment, la valeur "1d4" (par exemple) n'est pas exploitable. Je ne sais ni comment prendre le "1" et le "4" (pour arriver à quelque chose du genre $total = $nombreDeDés * Random($valeurDuDé) ). L'autre soucis, relativement majeur, c'est que je ne sais pas attribuer une valeur associée à la sélection.

Code : Tout sélectionner

        Case $Bdeg
            ;Choix de l'arme
            If Not ($CbArme = "Choisir une arme") Then  ;Pour vérifier que le choix n'est pas celui par défaut
                $x = 
                                $y=
                $degatArme = $y * Random($x)
                        Else
                                MsgBox(48, "Attention", "Vous n'avez pas choisi d'arme.")
            EndIf

Une autre erreur que je retrouve, et que lorsque je tombe dans le cas du message d'erreur, le programme quitte complètement. Y a-t-il une alternative moins violente qu'un "quit" ou un "break" ?

Merci de votre patience et d'avoir lu jusque là. Je vais resté scotché au pc toute la journée et une bonne partie de la nuit, donc je devrais être relativement réactif.
-Telni-

#2

Bonjour,

Le traitement de ta ComboBox te permettra pas de récupérer séparément les valeurs. Par contre, tu peux toujours chercher les valeurs dans la chaine "XdY".

► Afficher le texteValeurs des dés

Utilise la fonction avec ce que tu récupères par un GuiCtrlRead, tu obtiens alors un tableau. Index [1], tu as le nombre de dés, index [2], tu as le nombre de faces.

A bientôt !

Telni · #3

Merci ZDS, j'vais tester ça de suite, et je reviendrai par la suite pour le compte-rendu. Même si ça marche ^^

#4

Je profite de ton post pour corriger ton précédent code : $CbArme est l'identifiant de ta comboBox, pas son contenu. Pour le contenu, il faut utiliser GuiCtrlRead :

Code : Tout sélectionner

Case $Bdeg
    ;Choix de l'arme
    Local $CbArme_values = getValuesFromDice(GuiCtrlRead($CbArme))
    If Not @error Then
        $x = $CbArme_values[1]
        $y = $CbArme_values[2]
        $degatArme = $y * Random($x)
    Else
        MsgBox(48, "Attention", "Vous n'avez pas choisi d'arme.")
    EndIf

Telni · #5

Couper le résultat en tronquant les morceaux utiles, et mettre ça dans un tableau, j'aurais dû y penser ><
Merci encore, ZDS !

J'ai encore un petit soucis d'affichage :$
Voici à quoi ça ressemble.

Sur la partie inférieure, le résultat s'affiche comme il faut dans la petite boîte de texte à droite.
Par contre, lorsque que je fais un calcul de dégâts, ou d'attaque, ça me ferme immédiatement la fenêtre.
Le code d'affichage d'un lancer de dé divers :

Code : Tout sélectionner

        Case $Bd2
            $total = Random(1,2,1)
            GUICtrlSetData($ResDes, $total)

(ResDes = Résultat Dés)
Le code d'affichage d'un des autres lancers :

► Afficher le texte

($Bdeg = Bouton de dégâts ; $ResDeg = Résultat des dégâts)

Désolé de t'embêter autant. Mais après, j'ai fini.
Me restera juste à afficher un duplicatat de chaque résultat dans la zone de texte à l'extrême droite, pour faire un petit historique.

#6

J'aperçois pas mal d'erreurs dans ton code (ne pas oublier qu'un Guictrlread te retourne un résultat un peu "commun"; pour le traiter comme un nombre, mieux vaut l'associer à un Number(...)).

Par contre, avec un si petit bout de code, il est impensable de trouver d'où vient ton problème majeur, comme l’arrêt intempestif du script. Si tu souhaites de l'aide, poste ton code en entier (pas besoin des images, juste le code et les ressources nécessaires - #includes persos notamment). Si tu me fournis ça dans la soirée, j'essayerai de te répondre rapidement, au plus tard demain matin.

A bientôt !

Telni · #7

► Afficher le texte

Voici le code en entier. J'vais vérifier mes GUICtrlRead, ainsi que les conversions en entier.
Merci ZDS, vraiment, tu me sauves <3

#8

Je n'ai pas d'arrêt intempestif du script

A part cette petite modif à faire

► Afficher le texte

tout fonctionne bien chez moi

Telni · #9

Merci Mikell.
Les actions sur les boutons des 2 premiers groupes me faisaient fermer l'appli é_è
C'est réglé, même si je n'ai pas d'explication.

Il faut juste que je trouve comment stack les résultats les un sous les autres dans la zone d'edit à gauche, et j'ai fini.
J'suis un poil à la bourre ^^;

#10

Telni a écrit :Les actions sur les boutons des 2 premiers groupes me faisaient fermer l'appli é_è
C'est réglé, même si je n'ai pas d'explication

Dans les 2 'Case' correspondant à ces boutons il y a

Code : Tout sélectionner

$total = $bonusArme + $bonSou + $bonusAtt + $bonusDeg

or dans le script la variable $bonusArme peut ne pas avoir été définie quand les boutons sont pressés => erreur
Un "Global $bonusArme" en tête de script règle le problème

#11

Je me suis permis de modifier ton code (indenté pour que ce soit plus facile à lire, et quelques corrections de variables à instancier, et des erreurs de conceptions : $CkMal2 est l'identifiant d'une checkbox donc un nombre arbitraire comme un numéro de sécu, pas True/False selon qu'elle soit cochée ou non)

Bref, il reste deux ou trois choses à faire, mais voila une première mouture :

► Afficher le textecode

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

AutoIt Version : 3.3.8.1
Auteur: Pierre LIEGEOIS, BTS IG, session 2012

Fonction du Script :
Alléger les calculs de lancer de dés pour Donjon et Dragon

#ce ----------------------------------------------------------------------------

; Début du script

;Bibliothèques
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Func getValuesFromDice($string)
    If Not StringRegExp($string, "^\d+d\d+$") Then Return SetError(1)
    Local $result = StringSplit($string, "d")
    $result[1] = Number($result[1])
    $result[2] = Number($result[2])
    Return $result
EndFunc

Func isState($controlState, $state)
    Return BitAND($controlState, $state) = $state
EndFunc

;Interface graphique
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Calcul des lancers de dés", 821, 289, 192, 124)

;Groupe attaque
Global $Group1 = GUICtrlCreateGroup("Attaque", 24, 16, 537, 73)
Global $CBdegArme = GUICtrlCreateCombo("Degré de l'arme", 40, 56, 105, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "0|1|2|3|4|5|6|8|9")
Global $Label1 = GUICtrlCreateLabel("(basée sur un d20)", 40, 32, 92, 17)
Global $RBonFor1 = GUICtrlCreateRadio("Bonus force", 160, 32, 75, 17)
Global $RBonDex1 = GUICtrlCreateRadio("Bonus dex", 160, 56, 75, 17)
Global $BonFor1 = GUICtrlCreateInput("", 248, 32, 25, 21)
GUICtrlSetData(-1, "0")
Global $BonDex1 = GUICtrlCreateInput("", 248, 56, 25, 21)
GUICtrlSetData(-1, "0")
Global $Label2 = GUICtrlCreateLabel("Bonus à l'attaque", 288, 32, 86, 17)
Global $CBonAtt = GUICtrlCreateCombo("", 288, 56, 41, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "0|1|2|3|4|5|6|8|9")
Global $CkMal1 = GUICtrlCreateCheckbox("Malus", 336, 56, 50, 17)
Global $ResAtt = GUICtrlCreateInput("", 480, 32, 60, 50, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlSetLimit(-1, 2)
GUICtrlSetFont(-1, 25, 400, 0, "Copperplate Gothic Light")
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Batt = GUICtrlCreateButton("Attaquer", 400, 32, 59, 49)
GUICtrlCreateGroup("", -99, -99, 1, 1)

;Groupe dégât
Global $Group2 = GUICtrlCreateGroup("Dégâts", 24, 96, 537, 73)
Global $CBarme = GUICtrlCreateCombo("Choisir une arme", 40, 112, 105, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1,"1d2|1d4|1d6|1d8|1d10|1d12|2d4|2d6")
Global $CkSou = GUICtrlCreateCheckbox("Sournoise", 40, 136, 65, 17)
Global $CBsou = GUICtrlCreateCombo("", 112, 136, 41, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "0|1|2|3|4|5|6|8|9", "0")
GUICtrlSetState(-1, $GUI_DISABLE)
Global $RBonFor2 = GUICtrlCreateRadio("Bonus force", 160, 112, 75, 17)
Global $RBonDex2 = GUICtrlCreateRadio("Bonus dex", 160, 144, 75, 17)
Global $BonFor2 = GUICtrlCreateInput("", 248, 112, 25, 21)
GUICtrlSetData(-1, "0")
Global $BonDex2 = GUICtrlCreateInput("", 248, 136, 25, 21)
GUICtrlSetData(-1, "0")
Global $Label3 = GUICtrlCreateLabel("Bonus aux dégâts", 288, 112, 89, 17)
Global $CBonDeg = GUICtrlCreateCombo("", 288, 136, 41, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "0|1|2|3|4|5|6|8|9")
Global $CkMal2 = GUICtrlCreateCheckbox("Malus", 336, 136, 50, 17)
Global $Bdeg = GUICtrlCreateButton("Dégâts", 400, 112, 59, 49)
Global $ResDeg = GUICtrlCreateInput("", 480, 112, 60, 50, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlSetLimit(-1, 2)
GUICtrlSetFont(-1, 25, 400, 0, "Copperplate Gothic Light")
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateGroup("", -99, -99, 1, 1)

;Groupe divers
Global $Group3 = GUICtrlCreateGroup("Lancers divers", 24, 176, 537, 81)
Global $Bd2 = GUICtrlCreateButton("dé 2", 32, 192, 60, 25)
Global $Bd3 = GUICtrlCreateButton("dé 3", 104, 192, 60, 25)
Global $Bd4 = GUICtrlCreateButton("dé 4", 176, 192, 60, 25)
Global $Bd6 = GUICtrlCreateButton("dé 6", 248, 192, 60, 25)
Global $Bd8 = GUICtrlCreateButton("dé 8", 320, 192, 60, 25)
Global $Bd10 = GUICtrlCreateButton("dé 10", 32, 224, 60, 25)
Global $Bd12 = GUICtrlCreateButton("dé 12", 104, 224, 60, 25)
Global $Bd20 = GUICtrlCreateButton("dé 20", 176, 224, 60, 25)
Global $Bd24 = GUICtrlCreateButton("dé 24", 248, 224, 60, 25)
Global $Bd100 = GUICtrlCreateButton("dé 100", 320, 224, 60, 25)
Global $Pic1 = GUICtrlCreatePic("D:\PTI\DD\img\de20.jpg", 408, 192, 57, 57)
Global $ResDes = GUICtrlCreateInput("", 480, 192, 60, 50, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
GUICtrlSetLimit(-1, 2)
GUICtrlSetFont(-1, 25, 400, 0, "Copperplate Gothic Light")
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateGroup("", -99, -99, 1, 1)

;Groupe historique des lancers
Global $Group4 = GUICtrlCreateGroup("Derniers résultats", 568, 16, 177, 241)
Global $ZER = GUICtrlCreateEdit("", 576, 32, 161, 217)
GUICtrlSetData(-1, "")
GUICtrlSetFont(-1, 8, 400, 0, "Calibri")
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateGroup("", -99, -99, 1, 1)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
        Exit
    Case $Batt ;=====================================Partie attaque================================================================
        ;Bonus à l'attaque de l'arme
        Local $bonusArme = 0
        If StringRegExp(GUICtrlRead($CBdegArme), "^\d+$") Then
            $bonusArme = Number(GUICtrlRead($CBdegArme))
        Else
            MsgBox (48, "Attention", "Veuillez choisir le degré de l'arme utilisée")
        EndIf
        ;Choix du bonus de Force ou de Dextérité
        Local $bonusAtt = 0
        If isState(GUICtrlRead($RBonFor1), $GUI_CHECKED) Then
            $bonusAtt = Number(GUICtrlRead($BonFor1))
        ElseIf isState(GUICtrlRead($RBonDex1), $GUI_CHECKED) Then
            $bonusAtt = Number(GUICtrlRead($BonDex1))
        Else
            MsgBox (48, "Attention", "Veuillez choisir le bonus de Force ou de Dextérité")
        EndIf
        ;Ajout d'un bonus -ou malus- éventuel
        Local $BonAtt = Number(GUICtrlRead($CBonAtt))
        If isState(GUICtrlRead($CkMal1), $GUI_CHECKED) Then $BonAtt = -$BonAtt
        ;Calcul du total d'attaque
        Local $total = $bonusArme + $bonusAtt + $BonAtt + Random(1,20,1)
        afficher($ResAtt, "Attaque", $total)
    Case $Bdeg ;====================================Partie dégâts================================================================
        ;Choix de l'arme
        Local $degatArme = 0, $ArmeValeur = getValuesFromDice(GuiCtrlRead($CbArme))
        If Not @error Then
            $degatArme = $ArmeValeur[2] * Random(1,$ArmeValeur[1],1)
        Else
            MsgBox(48, "Attention", "Vous n'avez pas choisi de dé.")
        EndIf
        ;Attaque sournoise
        Local $bonSou = 0
        If isState(GUICtrlRead($Cksou), $GUI_CHECKED) Then $bonSou = Number(GUICtrlRead($CBsou))
        ;Choix du bonus de Force ou de Dextérité
        Local $bonusAtt = 0
        If isState(GUICtrlRead($RBonFor2), $GUI_CHECKED) Then
            $bonusAtt = Number(GUICtrlRead($BonFor2))
        ElseIf isState(GUICtrlRead($RBonDex2), $GUI_CHECKED) Then
            $bonusAtt = Number(GUICtrlRead($BonDex2))
        Else
            MsgBox (48, "Attention", "Veuillez choisir le bonus de Force ou de Dextérité")
        EndIf
        ;Ajout d'un bonus -ou malus- éventuel
        Local $bonusDeg = Number(GUICtrlRead($CBonDeg))
        If isState(GUICtrlRead($CkMal2), $GUI_CHECKED) Then $bonusDeg = -$bonusDeg
        ;Calcul du total de dégâts
        Local $total = $degatArme + $bonSou + $bonusAtt + $bonusDeg
        afficher($ResDeg, "Dégâts", $total)
    Case $Bd2
        Local $total = Random(1,2,1)
        afficher($ResDes, "1D2", $total)
    Case $Bd3
        Local $total = Random(1,3,1)
        afficher($ResDes, "1D3", $total)
    Case $Bd4
        Local $total = Random(1,4,1)
        afficher($ResDes, "1D4", $total)
    Case $Bd6
        Local $total = Random(1,6,1)
        afficher($ResDes, "1D6", $total)
    Case $Bd8
        Local $total = Random(1,8,1)
        afficher($ResDes, "1D8", $total)
    Case $Bd10
        Local $total = Random(1,10,1)
        afficher($ResDes, "1D10", $total)
    Case $Bd12
        Local $total = Random(1,12,1)
        afficher($ResDes, "1D12", $total)
    Case $Bd20
        Local $total = Random(1,20,1)
        afficher($ResDes, "1D20", $total)
    Case $Bd24
        Local $total = Random(1,24,1)
        afficher($ResDes, "1D24", $total)
    Case $Bd100
        Local $total = Random(1,100,1)
        afficher($ResDes, "1D100", $total)
    EndSwitch
WEnd

Func afficher($control, $type, $texte)
    GUICtrlSetData($control, $texte)
    GUICtrlSetData($ZER, "["&$type&"] : "&$texte&@CRLF&GUICtrlRead($ZER))
EndFunc

A tout à l'heure !

AutoIt Français

[..] Problème d'utilisations de ComboBox

[..] Problème d'utilisations de ComboBox

Re: [..]Problème d'utilisations de combo box

Re: [..]Problème d'utilisations de combo box

Re: [..]Problème d'utilisations de combo box

Re: [..]Problème d'utilisations de combo box

Re: [..]Problème d'utilisations de combo box

Re: [..]Problème d'utilisations de combo box

Re: [..] Problème d'utilisations de combo box

Re: [..] Problème d'utilisations de ComboBox

Re: [..] Problème d'utilisations de ComboBox

Re: [..] Problème d'utilisations de ComboBox