[R] Gui enfant dans Tab lui même dans Gui enfant

[Julien]

Bonjour,

Est il possible de créer un Gui enfant dans un Gui enfant ?

Je n'ai pas de code disponible pour le moment mais dans l'idée :

[GUI_PARENT]
[TREEVIEW]
[GUI_ENFANT1]
[TAB]
[GUI_ENFANT2]

Le code (11h26) :

► Afficher le texte

Code : Tout sélectionner

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

Global $GUI_Parent, $GUI_ENFANT1, $GUI_ENFANT2

_GUI_Parent()

Func _GUI_Parent()
    Global $GUI_Parent = GUICreate("Parent", 753, 606, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    Global $Control = GUICtrlCreateTreeView(7, 8, 193, 513, BitOR($GUI_SS_DEFAULT_TREEVIEW,$WS_BORDER))
    Global $Control_0 = GUICtrlCreateTreeViewItem("Test", $Control)
    GUICtrlSetOnEvent(-1, "_GUI_ENFANT1ON")
    _GUI_ENFANT1()
    GUISetState(@SW_SHOW, $GUI_Parent)
EndFunc

Func _GUI_ENFANT1()
    Global $GUI_ENFANT1 = GUICreate("", 545, 513, 201, 8, BitOr($WS_CHILD,$WS_TABSTOP), -1, $GUI_Parent)
    Global $Tab = GUICtrlCreateTab(7, 0, 520, 514)
    Global $TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
    Global $GUI_ENFANT2 = GUICreate("", 457, 105, 32, 360, $WS_POPUP, $WS_EX_MDICHILD, $GUI_ENFANT1)
    GUISetBkColor(0x3A6EA5)
    GUISetState(@SW_SHOW, $GUI_ENFANT2)
    Global $TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
    GUICtrlCreateTabItem("")
    GUISetState(@SW_HIDE, $GUI_ENFANT1)
EndFunc

Func _GUI_ENFANT1ON()
    GUISetState(@SW_SHOW, $GUI_ENFANT1)
EndFunc

Func _Exit()
    Exit
EndFunc

Ce fonctionnement me permet à partir du treeview de changer le Gui enfant 1 qui contient un tab, lui même contenant le gui enfant 2 afin de pouvoir faire des zones avec scrollbar verticales.

Je bloque uniquement sur le GUI_ENFANT2 que je n'arrive pas à inclure (ou alors si en premier plan mais il ne suit pas mon GUI_PARENT.

Pouvez-vous m'aider ? (si j'ai été assez clair dans ma description)

D'avance merci.

[Julien]

Bonjour,

Après plusieurs test je ne trouve pas la bonne solution.

Si j'indique GUI_ENFANT1 comme parent, GUI_ENFANT2 est bien affiché mais ne suit pas le GUI_Parent malgré $WS_EX_MDICHILD ce que je ne trouve pas logique car il devrait au moins suivre GUI_ENFANT1.

Si j'indique GUI_Parent comme parent il suit bien le GUI_Parent mais le Tab à une position variable en fonction de la direction de GUI_Parent.

Dans tous les cas à partir du moment ou j'affiche GUI_ENFANT2 il n’interprète pas la suite (dans l'exemple il n'affiche pas le deuxième onglet)

Je me dis que soit ce n'est pas possible et dans ce cas la auriez-vous une idée de solution ?
Soit je m'y prend comme un pied et c'est gros comme une maison devant mon nez !

Voila le code de test :

► Afficher le texte

Code : Tout sélectionner

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

Global $GUI_Parent, $GUI_ENFANT1, $GUI_ENFANT2, $Tab

_GUI_Parent()

Func _GUI_Parent()
    Global $GUI_Parent = GUICreate("Parent", 753, 606, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    Global $Control = GUICtrlCreateTreeView(7, 8, 193, 513, BitOR($GUI_SS_DEFAULT_TREEVIEW,$WS_BORDER))
    Global $Control_0 = GUICtrlCreateTreeViewItem("Test", $Control)
    GUICtrlSetOnEvent(-1, "_GUI_ENFANT1_ON")
    GUISetState(@SW_SHOW, $GUI_Parent)
    _GUI_ENFANT1()
EndFunc

Func _GUI_ENFANT1()
    Global $GUI_ENFANT1 = GUICreate("", 545, 513, 201, 8, BitOr($WS_CHILD,$WS_TABSTOP), -1, $GUI_Parent)
    Global $Tab = GUICtrlCreateTab(7, 0, 520, 514)
    GUICtrlSetOnEvent(-1, "_TAB_Change")
    Global $TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
    GUICtrlSetState(-1,$GUI_SHOW)
    Global $TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
    Global $Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 96, 48, 97, 17)
    Global $Button1 = GUICtrlCreateButton("Button1", 112, 88, 75, 25)
    GUICtrlCreateTabItem("")
    GUISetState(@SW_HIDE, $GUI_ENFANT1)
    _GUI_ENFANT2()
EndFunc

Func _GUI_ENFANT2()
    Global $GUI_ENFANT2 = GUICreate("", 457, 105, 32, 360, $WS_POPUP, $WS_EX_MDICHILD, $GUI_ENFANT1) ; Ne suit pas le GUI_Principal
;~  Global $GUI_ENFANT2 = GUICreate("", 457, 105, 32, 360, $WS_POPUP, $WS_EX_MDICHILD, $GUI_Parent) ; Suit pas le GUI_Principal mais position de Tab variable
    GUISetBkColor(0x3A6EA5)
    GUISetState(@SW_HIDE, $GUI_ENFANT2)
EndFunc

Func _TAB_Change()
    If GUICtrlRead($Tab) = 0 Then
        GUISetState(@SW_SHOW, $GUI_ENFANT1)
        GUISetState(@SW_SHOW, $GUI_ENFANT2)
    Else
        GUISetState(@SW_SHOW, $GUI_ENFANT1)
        GUISetState(@SW_HIDE, $GUI_ENFANT2)
    EndIf
EndFunc

Func _GUI_ENFANT1_ON()
    GUISetState(@SW_SHOW, $GUI_ENFANT1)
    GUISetState(@SW_SHOW, $GUI_ENFANT2)
EndFunc

Func _Exit()
    Exit
EndFunc

While 1
    Sleep(1000)
WEnd

D'avance merci.

[Julien]

Bonjour,

J'ai trouvé une réponse :

► Afficher le texte

Code : Tout sélectionner

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

Global $GUI_Parent, $GUI_ENFANT1, $GUI_ENFANT2, $Tab

_GUI_Parent()

Func _GUI_Parent()
    Global $GUI_Parent = GUICreate("Parent", 753, 606, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    Global $Control = GUICtrlCreateTreeView(7, 8, 193, 513, BitOR($GUI_SS_DEFAULT_TREEVIEW,$WS_BORDER))
    Global $Control_0 = GUICtrlCreateTreeViewItem("Test", $Control)
    GUICtrlSetOnEvent(-1, "_GUI_ENFANT1_ON")
    GUISetState(@SW_SHOW, $GUI_Parent)
    _GUI_ENFANT1()
EndFunc

Func _GUI_ENFANT1()
    Global $GUI_ENFANT1 = GUICreate("", 545, 513, 201, 8, BitOr($WS_CHILD,$WS_TABSTOP), -1, $GUI_Parent)
    Global $Tab = GUICtrlCreateTab(7, 0, 520, 514)
    GUICtrlSetOnEvent(-1, "_TAB_Change")
    Global $TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
    GUICtrlSetState(-1,$GUI_SHOW)
    Global $TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
    Global $Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 96, 48, 97, 17)
    Global $Button1 = GUICtrlCreateButton("Button1", 112, 88, 75, 25)
    GUICtrlCreateTabItem("")
    GUISetState(@SW_HIDE, $GUI_ENFANT1)
    _GUI_ENFANT2()
EndFunc

Func _GUI_ENFANT2()
    Global $GUI_ENFANT2 = GUICreate("", 457, 105, 32, 360, $WS_POPUP, $WS_EX_MDICHILD, $GUI_ENFANT1)
    GUIRegisterMsg($WM_MOVE, "MY_WM_MOVE")
    GUISetBkColor(0x3A6EA5)
    GUISetState(@SW_HIDE, $GUI_ENFANT2)
EndFunc

Func _TAB_Change()
    If GUICtrlRead($Tab) = 0 Then
        GUISetState(@SW_SHOW, $GUI_ENFANT1)
        GUISetState(@SW_SHOW, $GUI_ENFANT2)
    Else
        GUISetState(@SW_SHOW, $GUI_ENFANT1)
        GUISetState(@SW_HIDE, $GUI_ENFANT2)
    EndIf
EndFunc

Func _GUI_ENFANT1_ON()
    GUISetState(@SW_SHOW, $GUI_ENFANT1)
    GUISetState(@SW_SHOW, $GUI_ENFANT2)
EndFunc

Func _Exit()
    Exit
EndFunc

Func MY_WM_MOVE($hWnd, $Msg, $wParam, $lParam) ; http://www.autoitscript.fr/forum/viewtopic.php?f=3&t=5111&start=0&hilit=Suivi+de+gui
    Local $nNotifyCode, $nID, $hCtrl, $aGui1
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAND($wParam, 0x0000FFFF)
    $hCtrl = $lParam
    $aGui1 = WinGetPos($GUI_ENFANT1)
    If $nID <> 2 And $nNotifyCode = 0 Then
        WinMove($GUI_ENFANT2, "", $aGui1[0] + 32, $aGui1[1] + 360)
    EndIf
EndFunc   ;==>MY_WM_COMMAND

While 1
    Sleep(1000)
WEnd

[mikell]

Bravo, bien vu