[R] Reprendre la main dans une boucle

[wello]

Bonjour

Bon alors sortir d'une boucle je sais faire, mais lorsque qu'un son est joué, il m'est difficile de reprendre la main dans le script tant que celui-ci est actif.

Pour comprendre, je me suis fait une petite alarme qui fonctionne dès que l'heure et les minutes entrées correspondent à l'heure qu'il est, jusque là rien d'exceptionnel , et joue le son en boucle tant que la minute n'est pas différente.

voici mon code :

► Afficher le texte

Code : Tout sélectionner

Global $F_main, $hr, $mn, $btn, $btn1, $filein, $set, $vide, $son

$F_main = GUICreate("Alarme", 310, 65, -1, -1)
GUISetBkColor(0x00E0FFFF)
GUISetOnEvent($GUI_EVENT_CLOSE, "quitter")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "F_mainMinimize")
GUISetState(@SW_SHOW)

    GUICtrlCreateLabel("Heure", 5, 12, 40, 20)
$hr = GUICtrlCreateInput("", 40, 10, 40, 21)
    GUICtrlSetLimit($hr, 2, 2)

    GUICtrlCreateLabel("Min", 90, 12, 40, 20)
$mn = GUICtrlCreateInput("", 115, 10, 40, 21)
    GUICtrlSetLimit($mn, 2, 2)

$btn = GUICtrlCreateButton("Arrêter", 165, 10, 135, 20, $BS_FLAT)
    GUICtrlSetOnEvent($btn, "arreter")

$btn1 = GUICtrlCreateButton("Sonnerie", 230, 39, 70, 20, $BS_FLAT)
    GUICtrlSetOnEvent($btn1, "choisir")

    GUICtrlCreateLabel("Chemin", 5, 42, 50, 20)
$filein = GUICtrlCreateInput($set, 45, 39, 175, 21)

$vide = ""

While 1
        If @HOUR=GUICtrlRead($hr) And @min=GUICtrlRead($mn) Then
            $son = _SoundOpen(GUICtrlRead($filein))
            _SoundPlay($son, 1)
            GUICtrlSetOnEvent($btn, "arreter")
        Else
            ContinueLoop
        EndIf
WEnd

Do
    Local $msg = GUIGetMsg()

Until $msg = $GUI_EVENT_CLOSE

Func _DoubleClik()
    GUISetState ( @SW_SHOW, $F_main)
EndFunc ;==> _DoubleClick()
Func F_mainMinimize()
    GUISetState(@SW_HIDE, $F_main)
EndFunc ;==> F_mainMinimize()
Func arreter()
    _SoundStop($son)
EndFunc ;==> arreter()
Func choisir()
    $set = FileOpenDialog("Choisissez votre fichier", @DesktopDir & "\", "Fichiers musicaux (*.wav;*.mp3)")
    GuiCtrlSetData($filein, $set)
EndFunc ;==>choisir()
Func quitter()
Exit
EndFunc ;==> quitter()

je me suis donc résolu à devoir mettre GUICtrlSetOnEvent du bouton correspondant dans ma boucle pour me permettre d'en sortir...sans succès !!

merci de votre aide

[mikell]

Hum voyons cette boucle ...
- le script compare l'input des minutes et @min
- si égal, ça sonne
- là, tu arrêtes
Donc question à 1000 euros : qu'est-ce qui se passe quand la boucle repart ?

[mode brainstorming : ON]
... tic
... tac
... tic
... tac
[mode brainstorming : OFF]

Cher candidat, les 10 secondes sont écoulées, la solution est :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
Opt("GUIOnEventMode", 1)
;Global $F_main, $hr, $mn, $btn, $btn1, $filein, $set, $vide, $son = 0

$F_main = GUICreate("Alarme", 310, 65, -1, -1)
GUISetBkColor(0x00E0FFFF)
GUISetOnEvent($GUI_EVENT_CLOSE, "quitter")
GUISetState(@SW_SHOW)

    GUICtrlCreateLabel("Heure", 5, 12, 40, 20)
$hr = GUICtrlCreateInput("", 40, 10, 40, 21)
    GUICtrlSetLimit($hr, 2, 2)

    GUICtrlCreateLabel("Min", 90, 12, 40, 20)
$mn = GUICtrlCreateInput("", 115, 10, 40, 21)
    GUICtrlSetLimit($mn, 2, 2)

$btn = GUICtrlCreateButton("Arrêter", 165, 10, 135, 20)
    GUICtrlSetOnEvent($btn, "_arreter")

AdlibRegister("_verification")

While 1
 Sleep(10)
WEnd

;===================================
Func _verification()
    If @HOUR=GUICtrlRead($hr) And @min=GUICtrlRead($mn)  Then 
        AdlibUnRegister("_verification")
        AdlibRegister("_beep", 1000)
    EndIf   
EndFunc  

Func _arreter()
    AdlibUnRegister("_beep")
EndFunc 

Func _beep()
    Beep(294, 500)
EndFunc 

Func quitter()
Exit
EndFunc ;==> quitter()

[wello]

salut et merci de ta rapidité

effectivement c'était tout bête comme quoi même quand on veut faire simple on fait compliquer...ce bon vieil Adlib, alors !!!

nickel mikell

EndFunc ;==> merci ()

[mikell]

Remarque, on peut faire plus simple en mettant un bête interrupteur

Code : Tout sélectionner

$stop = 0
While 1
   If $stop = 0 Then
    If @HOUR=GUICtrlRead($hr) And @min=GUICtrlRead($mn)  Then 
        $stop = 1
        AdlibRegister("_beep", 1000)
    EndIf   
   EndIf
WEnd