[..] Modifier un fichier sur un FTP.

[Wardow]

Bonjour à tous !
Je créer ce sujet pour faire appel à vos talents de programmeurs.
J'aurais besoin d'un script qui se connecte au FTP de mon serveur minecraft, modifie plusieurs fichiers en remplaçant "Visiteur" par "Membre" dans ses 3 fichiers.

Voici l'emplacement des 3 fichiers :

Code : Tout sélectionner

/game/minecraft_cb/plugins/Permissions/world/users.yml
/game/minecraft_cb/plugins/Permissions/world_nether/users.yml
/game/minecraft_cb/plugins/Permissions/world_the_end/users.yml

Les fichiers de configurations se présentent comme ceci :

► Afficher le texteFichier de configuration

Code : Tout sélectionner

users:
    wardow59:
        permissions: []
        groups:
        - Admin
    staigher:
        permissions:
        groups:
        - Noble
    EmoraX:
        permissions:
        groups:
        - Noble
    Niico:
        permissions:
        groups:
        - Membre
    kamper:
        permissions:
        groups:
        - Noble
    Nykooolas:
        permissions:
        groups:
        - Membre
    coocoo:
        permissions:
        groups:
        - Membre
    delta:
        permissions:
        groups:
        - Membre
    LB59:
        permissions:
        groups:
        - Membre
    nosmagier:
        permissions:
        groups:
        - Membre
    ted59:
        permissions:
        groups:
        - Visiteur
    Riwas:
        permissions:
        groups:
        - Visiteur

Si possible, je souhaiterais une GUI qui comporte une case ou j’écrirais le pseudo, une ou j’écrirais quoi supprimer et une autre ou j’écrirais quoi mettre à la place (le plus souvent sa seras Visiteur et Membre mais sa pourrais changer) et aussi un bouton pour lancer l’opération.

J’espère que vous avez compris ma demande et que vous m'aiderais =) .

[PandiPanda]

Bonsoir,
Si quelque chose comme ceci vous convient ^^,
j'ai pas de serveur ftp je n'ai pas pu test le script, j'attendrai vos retours.

► Afficher le texte

Code : Tout sélectionner

#include <FTPEx.au3>
#Include <File.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#region variable globale
Global _
    $server = 'xxxx.ftp.xxxx', _ ; votre serveur
    $username = 'xxxxxxx', _    ; votre username
    $pass = 'xxxxxxxx', _   ; votre mot de passe
    $Open , _
    $Conn, _
    $fichier[3]=["/game/minecraft_cb/plugins/Permissions/world/users.yml", _
    "/game/minecraft_cb/plugins/Permissions/world_nether/users.yml", _
    "/game/minecraft_cb/plugins/Permissions/world_the_end/users.yml"], _
    $aReplace="", _
    $replace="", _
    $pseudo =""
    #Region ### START Koda GUI section ### Form=
        Global $Form1 = GUICreate("Wardow", 337, 185, 192, 124)
        Global $pseudoG = GUICtrlCreateInput("", 8, 32, 129, 21)
        Global $labPseudo = GUICtrlCreateLabel("Pseudo", 8, 8, 40, 17)
        Global $aDel = GUICtrlCreateInput("", 8, 88, 129, 21)
        Global $labAdel = GUICtrlCreateLabel("Quoi Delete ?", 8, 64, 69, 17)
        Global $aReplaceG = GUICtrlCreateInput("", 8, 141, 129, 21)
        Global $labReplace = GUICtrlCreateLabel("Replace Par ?", 8, 117, 72, 17)
        Global $GO = GUICtrlCreateButton("GO", 160, 32, 169, 129, $WS_GROUP)
        GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###
#endregion variable globale

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GO
            $aReplace = GUICtrlRead($aDel)
            $replace = GUICtrlRead($aReplaceG)
            $pseudo = GUICtrlRead($pseudoG)
            If $aReplace <> "" And $replace <> "" And $pseudo <> "" Then
                _WardowGo()
            Else
                MsgBox(64,"erreur","veuillez remplir tout les champs")
            EndIf
    EndSwitch
WEnd

Func _WardowGo()
    $Open = _FTP_Open('MyFTP Panda')
    If @error Then
        _ErrorOpen()
    Else
        $Conn = _FTP_Connect($Open, $server, $username, $pass)
        If @error Then
            _ErrorOpen()
        Else
            For $i=0 To UBound($fichier)-1
                modifFileFTP($Conn,$fichier[$i],$aReplace,$replace,@TempDir&"\"&@AutoItPID&$i)
            Next
        EndIf
        _FTP_Close($Open)
    EndIf
EndFunc

Func modifFileFTP($Conn,$remoteFile,$stringAmodif,$stringModif,$localFile)
    _FTP_FileGet($Conn,$remoteFile,$localFile)
    If @error Then
        _ErreurFTPGet($Conn)
    Else
        _ReplaceStringInFile($localFile,$stringAmodif,$stringModif,1,1)
        If @error Then
            _ErreurModifFile($Conn)
        Else
            _FTP_FileDelete($Conn,$remoteFile)
            If @error Then
                _ErreurDeleteFileFTP($Conn)
            Else
                _FTP_FilePut($Conn,$localFile,$remoteFile)
                If @error Then
                    _ErreurDeleteFileFTP($Conn)
                Else
                    FileDelete($localFile)
                EndIf
            EndIf
        EndIf
    EndIf
EndFunc
#region ERREUR
    Func _ErrorOpen()
        MsgBox(64,"erreur","erreur avec le ftp fichier non modifié")
    EndFunc

    Func _ErreurFTPGet($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur de recuperation du fichier sur le ftp, vérifier le chemin ...")
    EndFunc

    Func _ErreurModifFile($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur de modification du fichier")
    EndFunc

    Func _ErreurDeleteFileFTP($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur de suppresion de l'ancien fichier sur le FTP")
    EndFunc

    Func _ErreurPUTFileFTP($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur d'ajout du nouveau fichier sur le FTP")
    EndFunc
#endregion ERREUR

[Wardow]

C'est très bizarre mais quand je l'enregistre et que je fais F5 pour tester, j'ai une erreur :

C:\Users\carrefour\Desktop\123.au3(11,1) : ERROR: syntax error

^
C:\Users\carrefour\Desktop\123.au3 - 1 error(s), 0 warning(s)

EDIT : Oui bon je l'ai appeler 123 mais sa ne fonctionne pas non plus avec abc

[PandiPanda]

Des espaces en trop, j'ai fait les espace avant de vérifié, mea culpa :p

j'ai edit plus haut !

[Wardow]

Je n'ai pas trop compris d'ou venais l'erreur mais sa marche !! Merci beaucoup =)

[PandiPanda]

l'erreur d'avant etais simplement ceci

ceci fonctionne;

Code : Tout sélectionner

Global _
$main="main", _
$main2="main2"

MsgBox(0,'',$main&" "&$main2)

ceci cause une erreur;

Code : Tout sélectionner

Global _
$main="main", _

$main2="main2"

MsgBox(0,'',$main&" "&$main2)

j'avais mit des espaces pour aérer un peu, m'enfin rien de grave ^^

[Wardow]

Ah .... ok ....
C'est vraiment stupide comme erreur en plus !
Saletés d'ordinateurs

[Wardow]

Désolé du double post
Est-ce que quelqu'un pourrais commenter le script svp =) comme sa je comprendrais un peut mieux.

EDIT : En fait, c'est pas la peine, garce à l'aide d'AutoIt j'ai compris.

EDIT 2 : En fait sa ne fonctionne pas très bien : le script ne prend pas en compte le pseudo, et donc par exemple si je souhaite remplacer Membre par Admin au joueur Niico, tout les "Membres" vont êtres remplacées pas "Admin" ce qui n'est vraiment pas top . si quelqu'un pouvait faire quelque chose pour corriger ce problème svp.

[PandiPanda]

Bonsoir,
tout les "Membres" vont êtres remplacées pas "Admin" tout simplement parceque je l'ai codé comme ceci ^^
si vous pouviez laissé différent exemple de résultat escompté, cella facileterai la chose !!

[Wardow]

Oups, petite erreure qui fait toute la différence :

les "Membres" vont êtres remplacées par "Admin"

Et donc je souhaiterais que uniquement le "Membre" situé en dessous de "Niico" soit modifié.



EDIT : Je réplique mon problème :

Les fichiers de configuration, au départ, se présentent ainsi :

► Afficher le textefichier original

Code : Tout sélectionner

users:
    wardow59:
        permissions: []
        groups:
        - Admin
    staigher:
        permissions:
        groups:
        - Noble
    EmoraX:
        permissions:
        groups:
        - Noble
    Niico:
        permissions:
        groups:
        - Membre
    kamper:
        permissions:
        groups:
        - Noble
    Nykooolas:
        permissions:
        groups:
        - Membre
    coocoo:
        permissions:
        groups:
        - Membre
    delta:
        permissions:
        groups:
        - Membre
    LB59:
        permissions:
        groups:
        - Membre
    nosmagier:
        permissions:
        groups:
        - Membre
    ted59:
        permissions:
        groups:
        - Visiteur
    Riwas:
        permissions:
        groups:
        - Visiteur

Maintenant, si grâce au script de PandiPanda, je met dans la case pseudo "staigher" dans la case remplacer "Noble" et dans la case remplacer par je met "admin" logiquement le premier noble de la liste devra être changé en admin car il est juste en dessous de staigher mais le problème est que tout les nobles de la liste vont êtres changés, pas uniquement celui de staigher ce qui donnerais :

► Afficher le textefichier modifié

Code : Tout sélectionner

users:
    wardow59:
        permissions: []
        groups:
        - Admin
    staigher:
        permissions:
        groups:
        - [color=#BF0000]Admin[/color]
    EmoraX:
        permissions:
        groups:
        - [color=#BF0000]Admin[/color]
    Niico:
        permissions:
        groups:
        - Membre
    kamper:
        permissions:
        groups:
        - [color=#BF0000]Admin[/color]
    Nykooolas:
        permissions:
        groups:
        - Membre
    coocoo:
        permissions:
        groups:
        - Membre
    delta:
        permissions:
        groups:
        - Membre
    LB59:
        permissions:
        groups:
        - Membre
    nosmagier:
        permissions:
        groups:
        - Membre
    ted59:
        permissions:
        groups:
        - Visiteur
    Riwas:
        permissions:
        groups:
        - Visiteur

J’espère que vous avez compris d'où viens mon problème.

[PandiPanda]

Bonsoir,
j'ai mit un peu de temps avant de répondre a ceci, un peu oublié à vrai dire :p

m'enfin ! j'ai pu ajouter une petite fonction qui fera ce que vous désirez, je l'espere du moins ^^

voici le script au complet :

► Afficher le texte

Code : Tout sélectionner

#include <FTPEx.au3>
#Include <File.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#region variable globale
Global _
    $server = 'xxxx.ftp.xxxx', _ ; votre serveur
    $username = 'xxxxxxx', _    ; votre username
    $pass = 'xxxxxxxx', _   ; votre mot de passe
    $Open , _
    $Conn, _
    $fichier[3]=["/game/minecraft_cb/plugins/Permissions/world/users.yml", _
    "/game/minecraft_cb/plugins/Permissions/world_nether/users.yml", _
    "/game/minecraft_cb/plugins/Permissions/world_the_end/users.yml"], _
    $aReplace="", _
    $replace="", _
    $pseudo =""
    #Region ### START Koda GUI section ### Form=
        Global $Form1 = GUICreate("Wardow", 337, 185, 192, 124)
        Global $pseudoG = GUICtrlCreateInput("", 8, 32, 129, 21)
        Global $labPseudo = GUICtrlCreateLabel("Pseudo", 8, 8, 40, 17)
        Global $aDel = GUICtrlCreateInput("", 8, 88, 129, 21)
        Global $labAdel = GUICtrlCreateLabel("Quoi Delete ?", 8, 64, 69, 17)
        Global $aReplaceG = GUICtrlCreateInput("", 8, 141, 129, 21)
        Global $labReplace = GUICtrlCreateLabel("Replace Par ?", 8, 117, 72, 17)
        Global $GO = GUICtrlCreateButton("GO", 160, 32, 169, 129, $WS_GROUP)
        GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###
#endregion variable globale

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GO
            $aReplace = GUICtrlRead($aDel)
            $replace = GUICtrlRead($aReplaceG)
            $pseudo = GUICtrlRead($pseudoG)
            If $aReplace <> "" And $replace <> "" And $pseudo <> "" Then
                _WardowGo()
            Else
                MsgBox(64,"erreur","veuillez remplir tout les champs")
            EndIf
    EndSwitch
WEnd

Func _WardowGo()
    $Open = _FTP_Open('MyFTP Panda')
    If @error Then
        _ErrorOpen()
    Else
        $Conn = _FTP_Connect($Open, $server, $username, $pass)
        If @error Then
            _ErrorOpen()
        Else
            For $i=0 To UBound($fichier)-1
                modifFileFTP($Conn,$fichier[$i],$pseudo,$aReplace,$replace,@TempDir&"\"&@AutoItPID&$i)
            Next
        EndIf
        _FTP_Close($Open)
    EndIf
EndFunc

Func modifFileFTP($Conn,$remoteFile,$user,$groups,$modifGroups,$localFile)
    _FTP_FileGet($Conn,$remoteFile,$localFile)
    If @error Then
        _ErreurFTPGet($Conn)
    Else
        _ReplaceStringInFile2($localFile,$user,$groups,$modifGroups)
        If @error Then
            _ErreurModifFile($Conn)
        Else
            _FTP_FileDelete($Conn,$remoteFile)
            If @error Then
                _ErreurDeleteFileFTP($Conn)
            Else
                _FTP_FilePut($Conn,$localFile,$remoteFile)
                If @error Then
                    _ErreurDeleteFileFTP($Conn)
                Else
                    FileDelete($localFile)
                EndIf
            EndIf
        EndIf
    EndIf
EndFunc

#cs _ReplaceStringInFile2($pathFile,$regexAModif,$modif)
    @PARAM:
        # $pathFile : le fichier
        # $user : le nom, ex : Niico, ...
        # $groups : le groupe a modifier, ex : 'Membre'
        # $modifGroups : Par quoi modifier le groupe, par ex : 'Admin'
    @ERROR | @EXTEND:
        # 1 | 1 : erreur ouverture de fichier pour la lecture
        # 1 | 2 : erreur lors de la lecture
        # 1 | 3 : erreur ouverture pour l'ecriture
        # 1 | 4 : erreur lors de l'ecriture
#ce
Func _ReplaceStringInFile2($pathFile,$user,$groups,$modifGroups)
    Local $hfile = FileOpen($pathFile,0)
    If $hfile = -1 Then Return SetError(1,1,"")
    Local $readFile = FileRead($hfile)
    If @error = 1 Then Return SetError(1,2,"")
    Local $whereIsUser = StringInStr($readFile,$groups,0,1,StringInStr($readFile,$user))
    Local $left = StringLeft($readFile,$whereIsUser-1) ; partie a gauche du texte
    $readFile = $left&$modifGroups&StringRight($readFile,StringLen($readFile)-StringLen($left)-StringLen($groups))
    FileClose($hfile)
    $hfile = FileOpen($pathFile,2)
    If $hfile = -1 Then Return SetError(1,3,"")
    FileWrite($hfile,$readFile)
    If @error = 1 Then Return SetError(1,4,"")
    FileClose($hfile)
    Return SetError(0,0,"")
EndFunc

#region ERREUR
    Func _ErrorOpen()
        MsgBox(64,"erreur","erreur avec le ftp fichier non modifié")
    EndFunc

    Func _ErreurFTPGet($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur de recuperation du fichier sur le ftp, vérifier le chemin ...")
    EndFunc

    Func _ErreurModifFile($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur de modification du fichier")
    EndFunc

    Func _ErreurDeleteFileFTP($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur de suppresion de l'ancien fichier sur le FTP")
    EndFunc

    Func _ErreurPUTFileFTP($Conn)
        _FTP_Close($Open)
        MsgBox(0,'erreur',"erreur d'ajout du nouveau fichier sur le FTP")
    EndFunc
#endregion ERREUR
 

la fonction que j'ai ajoutée est celle ci;

► Afficher le texte

Code : Tout sélectionner

#cs _ReplaceStringInFile2($pathFile,$regexAModif,$modif)
    @PARAM:
        # $pathFile : le fichier
        # $user : le nom, ex : Niico, ...
        # $groups : le groupe a modifier, ex : 'Membre'
        # $modifGroups : Par quoi modifier le groupe, par ex : 'Admin'
    @ERROR | @EXTEND:
        # 1 | 1 : erreur ouverture de fichier pour la lecture
        # 1 | 2 : erreur lors de la lecture
        # 1 | 3 : erreur ouverture pour l'ecriture
        # 1 | 4 : erreur lors de l'ecriture
#ce
Func _ReplaceStringInFile2($pathFile,$user,$groups,$modifGroups)
    Local $hfile = FileOpen($pathFile,0)
    If $hfile = -1 Then Return SetError(1,1,"")
    Local $readFile = FileRead($hfile)
    If @error = 1 Then Return SetError(1,2,"")
    Local $whereIsUser = StringInStr($readFile,$groups,0,1,StringInStr($readFile,$user))
    Local $left = StringLeft($readFile,$whereIsUser-1) ; partie a gauche du texte
    $readFile = $left&$modifGroups&StringRight($readFile,StringLen($readFile)-StringLen($left)-StringLen($groups))
    FileClose($hfile)
    $hfile = FileOpen($pathFile,2)
    If $hfile = -1 Then Return SetError(1,3,"")
    FileWrite($hfile,$readFile)
    If @error = 1 Then Return SetError(1,4,"")
    FileClose($hfile)
    Return SetError(0,0,"")
EndFunc

Pour la fonction ajoutée, il est très possible de l'améliorer via des "regex", mais n'étant pas un expert dans cette matière, j'ai du "bricoler" avec les fonction de stringXXXX de base ^^

Voilou, Voilou !

[Wardow]

Ah merci bien =)
Il est fonctionnel la ? il faut juste que j’enlève le mode commentaire de la nouvelle fonction ? ou pas ?
Je croyais que vous m'aviez abandonné

[PandiPanda]

Bonsoir,
je pense qu'il devrai etre fonctionnel ^^ j'ai pas pu le tester, mais je n'ai modifié qu'une seule fonction par rapport a avant !

il est inutile d'enlever les commentaire, sont la simplement pour dire ce que fait la fonction, les parametre qu'il recoit et les erreurs, si il y'a !

non non je n'abandonne personne ! ^^

[Wardow]

J'ai fais un premier test, sa à l'air e fonctionner, merci bien =) mais par contre, pendant la modification, il y a 3 msgbox qui souvent à la suite, qui contiennent le fichier de configuration avant qu'il ai été modifier... Pourquoi ??

[PandiPanda]

Je les avait laissé pour faire les test, attendez je vais re-édité
il suffit de dévoilé ce qui est mit en "spoiler" ci dessus