[R] Spliter une chaine pour les 5 caractères

[Laddy]

Bonjour à tous

Jessaie de créer une fonction qui serait capable de spliter une chaine de caractère en groupe de 5x5

Si je saisis : FRDF73R44T6ZG5RCFG3DED87Z


j'aimerai le transformer en groupe de 5x5 séparé par un tiret.
FRDF7-3R44T-6ZG5R-CFG3D-ED87Z

Auriez vous des idées ?

Pour compter le nombre de caractère ça va, je sais faire mais apres je bloque.

Code : Tout sélectionner

$key = "FRDF73R44T6ZG5RCFG3DED87Z"
$nb = StringLen($key)
If $nb = "25" Then
msgbox(0,"Comptage", $nb)
EndIf

Func SplitKey()
;que mettre ???
EndFunc
 

Je ne vois pas comment m'y prendre.
Quelqu'un aurait une idée ?

[mikell]

Code : Tout sélectionner

$string = "FRDF73R44T6ZG5RCFG3DED87Z"
Msgbox(0, "", StringRegExpReplace($string, '(\w{5})(\w{5})(\w{5})(\w{5})(\w{5})', "$1-$2-$3-$4-$5") )

Tu as aussi la fonction _StringInsert avec une boucle "For $i = 5 to 20 step 5" pour la position

[TT22]

Mais si par la suite tu as besoins d'utiliser tes chaines de 5 caractères indépendamment, tu peux utiliser un StringRegExp :

Code : Tout sélectionner

 StringRegExp("FRDF73R44T6ZG5RCFG3DED87Z", "(.{1,5})", 3)

Ce qui donne avec les traits d'union :

► Afficher le texte

Code : Tout sélectionner

$string = "FRDF73R44T6ZG5RCFG3DED87Z"

$Exp = StringRegExp($string, "(.{1,5})", 3)

$Return = ""
For $i = 0 To UBound($Exp) - 1 Step 1
    If UBound($Exp) - 1 <> $i Then
        $Return &= $Exp[$i]&"-"
    Else
        $Return &= $Exp[$i]
    EndIf
Next

Msgbox(0, "", $Return)

[Laddy]

Mes sauveurs je navais pas pensé au StringRegEx.

Je dois l'appliquer sur plusieurs inputs y a t il moyen de faire une fonction qui l'applique à m'importe quel champ ?

Code : Tout sélectionner

StringRegExpReplace(GuictrlRead($input1), '(\w{5})(\w{5})(\w{5})(\w{5})(\w{5})', "$1-$2-$3-$4-$5"))
StringRegExpReplace(GuictrlRead($input2)
, '(\w{5})(\w{5})(\w{5})(\w{5})(\w{5})', "$1-$2-$3-$4-$5"))
StringRegExpReplace(GuictrlRead($input3)
, '(\w{5})(\w{5})(\w{5})(\w{5})(\w{5})', "$1-$2-$3-$4-$5"))

[TopXm]

Hello Laddy

Je dois l'appliquer sur plusieurs inputs y a t il moyen de faire une fonction qui l'applique à m'importe quel champ ?

C'est ce que t'a proposé Mikell

Code : Tout sélectionner

ConsoleWrite(_RegExpLaddy(GuictrlRead($input1) & @CRLF)
ConsoleWrite(_RegExpLaddy(GuictrlRead($input2) & @CRLF)
ConsoleWrite(_RegExpLaddy(GuictrlRead($input3) & @CRLF)

Func _RegExpLaddy($String)
    Return StringRegExpReplace($string, '(\w{5})(\w{5})(\w{5})(\w{5})(\w{5})', "$1-$2-$3-$4-$5")
EndFunc
 

[Laddy]

Super Merci TopXm je n'ai jamais fait encore de "fonctions guidées", je pense avoir compris maintenant reste à tester dès que possible.

[Tlem]

C'est une partie du gratin qui vous a répondu, donc vous pouvez y aller les yeux fermés.

N'oubliez pas la balise [R] dans le titre de votre premier message si votre sujet est résolu.

[TommyDDR]

Bonjour laddy, si ça peut vous aider (même si c'est déjà résolu ^^), j'avais fait une fonction qui me permettait d'insérer un caractère dans une chaine tout les x caractères.

(Je voulais transformer 12345678 en 12 345 678 pour plus de lisibilité)

► Afficher le textecode

Code : Tout sélectionner

PutChar("FRDF73R44T6ZG5RCFG3DED87Z", "-", 5, 1) ; Donnera FRDF7-3R44T-6ZG5R-CFG3D-ED87Z

Func PutChar($String, $Char, $Pos, $Sens = 1)
    Local $Retour = ""
    Local $Debut = 1
    Local $Fin = StringLen($String)
    Local $Mod = 0
    If($Sens = -1) Then
        $Mod = Mod(StringLen($String), $Pos)
    EndIf
    For $i = 0 To StringLen($String)
        $Retour &= StringMid($String, $i, 1)
        If($i <> 0 And $i < StringLen($String) And Mod($i, $Pos) = $Mod) Then
            $Retour &= $Char
        EndIf
    Next
    Return $Retour
EndFunc

$Sens permet d'indiquer par quel bout on commence à traiter la chaine (1 = gauche à droite, -1 = droite à gauche)

Code : Tout sélectionner

PutChar("12345678", " ", 3, 1) ; = 123 456 78
PutChar("12345678", " ", 3, -1) ; = 12 345 678

En espérant vous aider.

[Laddy]

Merci Tommyddr je vais regarder ton code dès que possible c'est intéressant