[R] Programme de tri alphabétique des lignes d'un .txt

[ThomasM]

Bonjour , j'ai essayé de créer un programme qui tri les lignes du fichier texte qui lui est passé en argument.

Le voici :

Code : Tout sélectionner

#include <File.au3>

$file = $CmdLine[1]
$read = FileRead($file);on lit tout le fichier texte.
$line = StringSplit($read, @CR);on le separe suivant le caractere saut de ligne, le resultat est le tableau $line.
$n = $line[0]; $line[0] designe le nombre d'autre elements du tableau $line, soit le nombre de lignes du fichier texte.

For $i = 2 To $n
    For $j = $i To 2 Step -1
        If StringLen($line[$j-1]) = 0 Then 
            $stock = $line[$j-1]
            $line[$j-1] = $line[$j] ; on les echange. 
            $line[$j] = $stock
        Else
            If StringLen ($line[$j]) = 0 Then 
                
            Else
                If $line[$j-1] > $line[$j]  Then;Si la ligne en j est est devant celle en j-1 alphabetiquement, 
                    $stock = $line[$j-1]
                    $line[$j-1] = $line[$j] ; on les echange. 
                    $line[$j] = $stock
                EndIf
            EndIf
        EndIf       
    Next    
Next

$file = FileOpen($CmdLine[1],2)
For $c = 1 To $n
    FileWrite($file, $line[$c])
    FileWrite($file, @CR)
Next
 

Mais plusieurs problèmes subsistent :
- Le premier est que la première ligne se retrouve systématiquement placée en dernière,
- Les lignes vides se retrouvent placées au début.

J'ai chercher des solutions en vain. Que faire ?

[matwachich]

J'aurai fait comme ça: (Sans aucune prise de tête!)

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>
#Include <File.au3>

If $CmdLine[0] = 0 Then Exit

For $i = 1 To $CmdLine[0]
    _TrierFichier($CmdLine[$i])
Next

Func _TrierFichier($sFile)
    Local $array
    _FileReadToArray($sFile, $array)
    _ArraySort($array, 0, 1)
    FileDelete($sFile)
    _FileWriteFromArray($sFile, $array, 1)
EndFunc
 

[ThomasM]

Oui, question de goût. J'aime bien savoir ce que je fais et j'évite de trop faire appel aux fonctions prédéfinies quand je peux, surtout que je programme occasionnellement, et donc je ne me rappelle pas beaucoup de ces fonctions, et après c'est coton de se relire.

Par exemple, _FileReadToArray, je connaissais pas. J'ai réécrit le programme pour l'intégrer et paf ! Ca marche nickel. Merci beaucoup