[R] Lire l'état d'un bouton radio

[softwater]

Bonjour,

J'ai une application avec un quarantaine de boutons radio. Aucun problème pour exécuter une action après sélection d'un bouton radio.

Mon problème est que pendant l'exécution du traitement l'utilisateur peut le stopper. Ce qui fait que je désire mettre en rouge l'arrière plan du bouton radio qui est sélectionné (ça je sais faire ). Par contre je ne parviens pas à relire quel bouton radio est cocher en utilisant une variable dynamique pour éviter d'écrire autant de lignes qu'il y a de bouton. (voir fonction _checkChecked).

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <array.au3>
;~ Opt('MustDeclareVars', 1)
Global $radio1, $radio2, $listBtn1
Example()
_checkChecked()
Func Example()
    Local $radio1, $radio2, $msg
    GUICreate("My GUI radio") ; will create a dialog box that when displayed is centered

    $radio1 = GUICtrlCreateRadio("Radio 1", 10, 10, 120, 20)
    $radio2 = GUICtrlCreateRadio("Radio 2", 10, 40, 120, 20)
    GUICtrlSetState($radio2, $GUI_CHECKED)

    GUISetState() ; will display an  dialog box with 1 checkbox

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $radio1 And BitAND(GUICtrlRead($radio1), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox(64, 'Info:', 'You clicked the Radio 1 and it is Checked.')
            Case $msg = $radio2 And BitAND(GUICtrlRead($radio2), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox(64, 'Info:', 'You clicked on Radio 2 and it is Checked.')
        EndSelect
    WEnd
EndFunc   ;==>Example
Func _checkChecked()
    Local $listBtn[1]
    For $a = 0 To 1
        _ArrayAdd($listBtn, "$radio" & $a + 1)
    Next
;~     _ArrayDisplay($listBtn)
    For $i = 1 To UBound($listBtn) - 1 ; boucle de test de chaque sosu menu
        If BitAND(GUICtrlRead($listBtn[$i]), $GUI_CHECKED) = $GUI_CHECKED Then
            MsgBox(0, "ok", $listBtn[$i] & " checked")
        EndIf
    Next
    Exit
EndFunc   ;==>_checkChecked

Merci pour vos solutions.

[sylvanie]

Bonjour
Essayez :

Code : Tout sélectionner

_ArrayAdd($listBtn, Eval("radio"& $a + 1))
 

Attention j'insiste sur le fait que "radio" n'est pas précédé de "$", cf fonction Eval

[TommyDDR]

Et dieu inventa les tableaux. (Je n'ai rien contre _Arrayxxx mais dans votre cas, un simple tableau basique suffit amplement)

Voici un code indiquant l'état des radios :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)

Dim $Gui
Dim $Radio[10]

$Gui = GUICreate("test", 100, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
For $i = 0 To UBound($Radio)-1
    $Radio[$i] = GUICtrlCreateRadio("Radio " & $i, 10, 10+$i*25, 80, 20)
Next
$Bouton = GUICtrlCreateButton("Check", 10, 10+UBound($Radio)*25, 80, 20)
GUICtrlSetOnEvent($Bouton, "Check")
GUISetState()

While(True)
    Sleep(10)
WEnd

Func Check()
    Local $Check = ""
    For $i = 0 To UBound($Radio)-1
        $Check &= "Radio " & $i & " : " & _IsChecked($Radio[$i]) & @CRLF
    Next
    MsgBox(0, "", $Check)
EndFunc

Func _IsChecked($ctrl)
    Return BitAND(GUICtrlRead($ctrl), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

Func quit()
    Exit
EndFunc

[zeshrek]

Sinon, même principe mais en utilisant juste un petit tableau pour les $radio, plutot que de leur donner a chacun un nom different

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <array.au3>
Opt('MustDeclareVars', 1)

Global $NbRadio = 2
Global $Radio[$NbRadio]

Example()
_checkChecked()

Func Example()
    Local $radio1, $radio2, $msg
    GUICreate("My GUI radio") ; will create a dialog box that when displayed is centered

    $Radio[0] = GUICtrlCreateRadio("Radio 1", 10, 10, 120, 20)
    $Radio[1] = GUICtrlCreateRadio("Radio 2", 10, 40, 120, 20)
    GUICtrlSetState($Radio[1], $GUI_CHECKED)

    GUISetState() ; will display an  dialog box with 1 checkbox

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        For $i = 0 To $NbRadio - 1
            If $msg = $Radio[$i] And BitAND(GUICtrlRead($Radio[$i]), $GUI_CHECKED) = $GUI_CHECKED Then MsgBox(64, 'Info:', 'You clicked the Radio ' & $i + 1 & ' and it is Checked.')
        Next
    WEnd
EndFunc   ;==>Example
Func _checkChecked()

    For $i = 0 To $NbRadio - 1 ; boucle de test de chaque sosu menu
        If BitAND(GUICtrlRead($Radio[$i]), $GUI_CHECKED) = $GUI_CHECKED Then
            MsgBox(0, "ok Radio", $i + 1 & " checked")
        EndIf
    Next
    Exit
EndFunc   ;==>_checkChecked

Edit : grilled !

[sylvanie]

<mode Stroumpf grognon> Moi j'aime pas les tableaux </mode Stroumpf grognon>

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)

Dim $Gui
$Nbmax=10

$Gui = GUICreate("test", 100, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
For $i = 0 To $Nbmax-1
    Assign("Radio"&$i , GUICtrlCreateRadio("Radio " & $i, 10, 10+$i*25, 80, 20))
Next
$Bouton = GUICtrlCreateButton("Check", 10, 10+$Nbmax*25, 80, 20)
GUICtrlSetOnEvent($Bouton, "Check")
GUISetState()

While(True)
    Sleep(10)
WEnd

Func Check()
    Local $Check = ""
    For $i = 0 To $Nbmax-1
        $Check &= "Radio " & $i & " : " & _IsChecked(Eval("Radio"&$i)) & @CRLF
    Next
    MsgBox(0, "", $Check)
EndFunc

Func _IsChecked($ctrl)
    Return BitAND(GUICtrlRead($ctrl), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

Func quit()
    Exit
EndFunc

 

[softwater]

Hello,
Merci pour vos solutions, ça fonctionne à merveille.
A+