[..] Remplir et valider les formulaires d'une page web

[ThomasM]

Bonjour !

J'aimerais réaliser un petit programme qui lance internet explorer avec l'adresse de mon emploi du temps à la fac (ici)

Voilà ce que j'ai essayé, mais, comme vous vous en doutez, ça ne marche pas.

Code : Tout sélectionner

#include <IE.au3>

$oIE = _IECreate ("http://ade52-savoie.grenet.fr/ade/custom/modules/plannings/direct_planning.jsp?projectId=1&login=ETUDIANT&password=etsa&displayConfName=Consultation%20Portail",0,0)

$oForm = _IEFormGetCollection ($oIE,0) 

$oQuery = _IEFormElementGetObjByName ($oForm, "search")

_IEFormElementSetValue ($oQuery, "L2-S3-MATH-MATH")

_IEFormSubmit($oForm)
 

Voilà, tout est dit, merci d'avance !

[jchd]

A vue de nez, il y a deux frames là-dedans. Suivre la doc IE pour les frames.

[sylvanie]

Et comme ça ^^

► Afficher le texte

Code : Tout sélectionner

$url="http://ade52-savoie.grenet.fr/ade/standard/index.jsp"

#include <IE.au3>

$oIE = _IECreate ($url)

$oForm = _IEFormGetCollection ($oIE,0)

$oQuerylogin = _IEFormElementGetObjByName ($oForm, "login")
_IEFormElementSetValue ($oQuerylogin, "user_toto")

$oQuerypasswd = _IEFormElementGetObjByName ($oForm, "password")
_IEFormElementSetValue ($oQuerypasswd, "super_password")

_IEFormSubmit($oForm)
 

Aujourd'hui Saint Chrome à la fonction via click droit "Inpecter l'élément" qui cible directement dans la source le code de l'élément ainsi que son nom qui nous est précieux pour la suite
Sinon faut chercher dans tout le code source.

[EDIT] bon on laisse tombé, je viesn de constaté que le soucis ne résidait pas dans le login /password ...

[jchd]

A tout haserd, mettre IE9 en mode compatibilité IE8 pour ce site.

[sylvanie]

j'ai testé en IE6 et les frames ne sont pas plus exploitables.
J'ai essayé un bout de temps, mais sans succès. Sauf si on navigue dans l'url du frame lui même; mais là j'ai se dernier en gros dans le navigateur.
Et bien là je dis ... bonne chance

[mikell]

j'ai testé en IE6 et les frames ne sont pas plus exploitables.

De quoi ? et ça alors ?

Code : Tout sélectionner

#include <IE.au3>

$oIE = _IECreate ("http://ade52-savoie.grenet.fr/ade/custom/modules/plannings/direct_planning.jsp?projectId=1&login=ETUDIANT&password=etsa&displayConfName=Consultation%20Portail",1)

$oFrame = _IEFrameGetCollection ($oIE, 0)
$oForm = _IEFormGetObjByName ($oFrame, "search")
$oQuery = _IEFormElementGetObjByName ($oForm, "search")
_IEFormElementSetValue ($oQuery, "L2-S3-MATH-MATH")
_IEFormSubmit ($oForm)
 

Et le petit script de récupération du tableau du planning qui va avec, pour le fun

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>

SplashTextOn ( "", @CRLF&"Loading...", 200, 100)
$oIE = _IECreate ("http://ade52-savoie.grenet.fr/ade/custom/modules/plannings/direct_planning.jsp?projectId=1&login=ETUDIANT&password=etsa&displayConfName=Consultation%20Portail", 0, 0)

$oFrame = _IEFrameGetCollection ($oIE, 0)
$oForm = _IEFormGetObjByName ($oFrame, "search")
$oQuery = _IEFormElementGetObjByName ($oForm, "search")
_IEFormElementSetValue ($oQuery, "L2-S3-MATH-MATH")
_IEFormSubmit ($oForm, 0)
_IELoadWait($oIE)

Do
$oFrame2 = _IEFrameGetCollection ($oIE, 2)
$oImg = _IEImgGetCollection ($oFrame2, 0)
Until $oImg <> 0
Sleep(300)
$src = $oImg.src
$w = $oImg.width
$h = $oImg.height
_IEQuit ($oIE)
SplashOff ( )
InetGet ($src, @tempdir & "\myplanning.gif")

GuiCreate("planning", $w, $h, -1, -1, $WS_POPUP)
$pic = GUICtrlCreatePic (@tempdir & "\myplanning.gif", 0, 0, $w, $h, -1, $GUI_WS_EX_PARENTDRAG)
$label = GuiCtrlCreateLabel("X", $w-15, 0, 15, 15)
GUICtrlSetBkColor(-1, 0xff0000)
GUICtrlSetState(-1,$GUI_ONTOP)
GuiSetState()

While 1
$msg = GuiGetMsg()
If $msg = $label Then ExitLoop
Wend
 

[ThomasM]

j'ai testé en IE6 et les frames ne sont pas plus exploitables.

De quoi ? et ça alors ?

Code : Tout sélectionner

#include <IE.au3>

$oIE = _IECreate ("http://ade52-savoie.grenet.fr/ade/custom/modules/plannings/direct_planning.jsp?projectId=1&login=ETUDIANT&password=etsa&displayConfName=Consultation%20Portail",1)

$oFrame = _IEFrameGetCollection ($oIE, 0)
$oForm = _IEFormGetObjByName ($oFrame, "search")
$oQuery = _IEFormElementGetObjByName ($oForm, "search")
_IEFormElementSetValue ($oQuery, "L2-S3-MATH-MATH")
_IEFormSubmit ($oForm)
 

Merci, mais ça ne marche toujours pas . Y a-t-il des prérequis (une version d'IE particulière par exemple) ?

[mikell]

Alors là, je sais pas
Tout ce que je peux te dire : je suis sous XP SP3 x86 avec IE6 et ça marche nickel
Pour les autres OS ou les autres versions de IE... je peux pas tester
Mais a priori comme ça, je dirais que ce n'est pas un problème de code (puisque chez moi ça marche...) peut-être des autorisations ou un réglage de sécurité dans IE ? Ya énormément de javascript dans ce site ^^
Faudrait vérifier en faisant la manip manuellement dans IE et en faisant tester le script par d'autres personnes

[sylvanie]

Le script proposé marche bien chez moi sur Win7 + IE9 en accès direct internet.
Mon précédent post était sur XP+IE6 et surtout je passe dans ce cas par un proxy websense. Le corps des 2 frames obtenus étaient alors des liens à suivre (d'où mon histoire de les suivre, mais on arrive alors à l'affichage du frame ciblé en gros sur la page)
ça doit pas mal jouer entre les versions/configurations/types d'accès au net.

[ThomasM]

En gros, je dois changer des options d'IE c'est ça ?

Ok, merci à tous, au final j'ai déjà commencé par faire une version plus simple qui se contente de cliquer sur le champ en question et d'envoyer l'intitulé souhaité.

[sylvanie]

humm je viens de reprendre mon code sur la machine en XP+IE6 et là ça marche >_<'
Du coups je n'en sais plus rien

[mikell]

Bah il ya parfois des choses bizarres
Au début mon script ne marchait pas, et comme j'utilise IE seulement avec autoit et les fonctions IE et généralement en mode hide il m'a fallu un petit moment pour me rendre compte que le souci venait d'une toolbar alakon que j'avais installé pour tester un script et oublié de virer ^^

[mmrad1]

Hello,
pas besoin de prendre forcément le frame IE.au3 (justement à cause des problèmes de compatibilté, probs d'autorisations, etc.).
Tu peux simplement baser ton remplissage de formulaire par un script standard basé sur les dimenssions de ta fenêtre, avec des clics de souris etc.

[mmrad1]

Tu peux par exemple utiliser les fonctions suivantes pour cela:

Code : Tout sélectionner

WinActivate("txt")

(pour activer une fenêtre afin que autoit prenne en compte le bon objet de ta fenêtre )

Code : Tout sélectionner

AutoItSetOption('MouseCoordMode',1)

(1 = coordonées relatives (écran))

Code : Tout sélectionner

MouseClick('secondary', coordonées)

(clique sur les coordonnées indiquées (pour cela, utilise AU3INFO qui est fourni avec le logiciel))