[R] Création de checkboxS " dynamiques "avec fichier txt

[Gigli]

Bonjour à tous

Mon titre n'est pas très parlant, alors je vais expliquer ici ce que je souhaite faire, avec les exemples ci-joints.

Tout d'abord (fichier "CheckBoxStatique.au3" ci joint), voici un exemple (très simple) avec des données "en dure" dans le code.
Les CheckBox sont créés dans le code au3 et on peut avec les boutons, cocher les cases grâce aux boutons.
En effet, chaque CheckBox à un variable que je peux retrouver et en prendre le contrôle.

Maintenant, ce que j'essaye de faire (fichiers "CheckBoxDynamique.au3" et "fichier.csv" ci joints).
Une GUI qui se met à jour selon le contenu d'un fichier "fichier.csv".
Donc, le nombre de ligne dans le fichier "fichier.csv" conditionne le nombre de CheckBox.
J'aimerais pouvoir par contre creer dynamiquement donc, des contrôles du même nombre que les CheckBox. Mais je ne sais pas comment faire.
En effet, en mettant $CheckBox comme valeur au GUICtrlCreateCheckbox, je peux créer un bouton mais qui n'interagit que sur le dernier (logique).
Peut être il y a une autre façon que j'ignore pour s'y prendre ?


Pas très clair peut être mon récit ? J'invite les plus curieux à tester les au3 joints ça sera (je l’espère) plus clair


Merci d'avance

[PandiPanda]

ceci peut être? ^^

► Afficher le texte

Code : Tout sélectionner

#Include <File.au3>
#include <GUIConstants.au3>

Global $fichier=""
$fichier=@ScriptDir&"\fichier.csv"

$Form1 = GUICreate("Form1", 633, 454, 193, 115)
$checkBoxS=_CheckBoxDynamic($fichier)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _CheckBoxDynamic($fichier)
    If FileExists($fichier) Then
        Dim $read
        If _FileReadToArray($fichier,$read) = 1 Then
            If $read[0] <> 0 then
                Dim $arrayCheckBoxS[$read[0]]
                For $i=0 To $read[0]-1
                    $arrayCheckBoxS[$i]=GUICtrlCreateCheckbox($read[$i+1],56,20*$i,68,17)
                Next
            EndIf
        Else
            MsgBox(64,"error","erreur n°"&@error)
        EndIf
    Else
        MsgBox(64,"error","fichier pas trouvé")
        Exit
    EndIf
    Return $arrayCheckBoxS
EndFunc

Code editer ^^ petite faute d'innatention :p

[Gigli]

Super PandiPanda Merci.

Je vais avoir la même question que précedement, mais cette fois ci avec une base SqlLite.

Je reviendrais poster sous peu un exemple en pièce jointe, en quémandant de nouveau votre aide.

Merci encore.

[PandiPanda]

Si votre Post est résolu, metez la balise [R] ^^
1 topic par question ! ^^
Pour le SQLite , faites une seconde demande, dans un autre sujet :p

Pour le fun, un petit script pour les ChecBoxs Plus haut et comment tester si ils sont "check" ou pas

► Afficher le texte

Code : Tout sélectionner

#Include <File.au3>
#include <GUIConstants.au3>

Global $fichier=""
$fichier=@ScriptDir&"\fichier.csv"

$Form1 = GUICreate("Form1", 633, 454, 193, 115)
$checkBoxS=_CheckBoxDynamic($fichier)
GUISetState(@SW_SHOW)
Local $t0=TimerInit()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    If TimerDiff($t0)> 3000 Then
        MsgBox(0,'test ?',"Voici un petit Test"&@CRLF&"apres 3 sec, je verifie quel checbox a été activée :p")
        Local $str="Le(s) CheckBox n°> "&@CRLF
        For $i=0 To UBound($checkBoxS)-1
            If isChecked($checkBoxS[$i]) Then $str&="- "&$i+1&@CRLF
        Next
        MsgBox(0,"Test fini ^^",$str&" ont été 'Checked'")
        $t0=TimerInit()
    EndIf
WEnd

Func isChecked($ctrlId)
    Return BitAND(GUICtrlRead($ctrlId),$GUI_CHECKED)= $GUI_CHECKED
EndFunc

Func _CheckBoxDynamic($fichier)
    If FileExists($fichier) Then
        Dim $read
        If _FileReadToArray($fichier,$read) = 1 Then
            If $read[0] <> 0 then
                Dim $arrayCheckBoxS[$read[0]]
                For $i=0 To $read[0]-1
                    $arrayCheckBoxS[$i]=GUICtrlCreateCheckbox($read[$i+1],56,20*($i+1),68,17)
                Next
            EndIf
        Else
            MsgBox(64,"error","erreur n°"&@error)
        EndIf
    Else
        MsgBox(64,"error","fichier pas trouvé")
        Exit
    EndIf
    Return $arrayCheckBoxS
EndFunc

[Gigli]

Si votre Post est résolu, metez la balise [R] ^^
1 topic par question ! ^^
Pour le SQLite , faites une seconde demande, dans un autre sujet :p

Ok très bien

Créé ici

[mikell]

Pour le fun aussi (puisque le sujet est résolu), le script sans array

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Global $nb
$fichier = @ScriptDir & "\fichier.csv"

$Form1 = GUICreate("Form1", 633, 454, 193, 115)
$file = FileOpen($fichier, 0)
If  @error Then 
    MsgBox(64,"erreur","erreur")
    Return
EndIf
$nb = 1
While 1
    $line = FileReadLine($file)
    If @error = -1 Then ExitLoop
    Assign("Checkbox" & $nb, GUICtrlCreateCheckbox($line, 56, 20*$nb, 70, 18))
    Assign("Button" & $nb, GUICtrlCreateButton($nb, 200, 20*$nb, 20, 20))
    $nb += 1
Wend
FileClose($file)
GUISetState()

While 1
$nMsg = GUIGetMsg()
For $i = 1 to $nb
    If $nMsg = Eval("Button" & $i) Then GUICtrlSetState(Eval("Checkbox" & $i), $GUI_CHECKED)
Next
If $nMsg = $GUI_EVENT_CLOSE Then Exit
WEnd
 

[Gigli]

Wah mikell merci !

La commande Assign est celle que je cherchais !
Merci beaucoup... à vous deux bien sur