[R] _RecFileListToArray() Problème de compréhension

[TopXm]

Bonjour

J'ai un souci de compréhension de l'UDF _RecFileListToArray() sur le paramètre suivante:

Code : Tout sélectionner

$iReturn : 0 = Retourne fichier et répertoire (défaut), 1 = Retourne que les fichiers, 2 = Retourne que les répertoires.

Voici un bout de code, relatant mon problème :

► Afficher le texteTest _RecFileListToArray

Code : Tout sélectionner

#include <RecFileListToArray.au3>
#include <array.au3>

Local Const $DirGlob = "C:\Test"
Local Const $SubDir1 = "C:\Test\Bob1"
Local Const $SubDir2 = "C:\Test\Bob1\plop"
Local Const $SubDir3 = "C:\Test\Bob1\plop1"
Local Const $FileName = "MonFichier.txt"
Local $I, $nFile

; Création des dossier de test C:\Test\bob1 jusqu'à C:\Test\Bob15
For $I = 0 to 15
    If Not FileExists($DirGlob & "\Bob" & $I) Then DirCreate($DirGlob & "\Bob" & $I)
Next

;Création des sous-dossiers qui comporteront le fichier MonFichier.txt
If Not FileExists($SubDir1) Then DirCreate($SubDir1)
If Not FileExists($SubDir2) Then DirCreate($SubDir2)
If Not FileExists($SubDir3) Then DirCreate($SubDir3)

;Creation des 3 fichiers MonFichier.txt dans les trois sous-dossiers Bob1, bob1\plop, bob1\plop1
$nFile = FileOpen($SubDir1 & "\" & $FileName, 2)
FileClose($nFile)
$nFile = FileOpen($SubDir2 & "\" & $FileName, 2)
FileClose($nFile)
$nFile = FileOpen($SubDir3 & "\" & $FileName, 2)
FileClose($nFile)

;Je suis en situation je fais donc une série de recherche

; 1/ Recherche MonFichier.txt dans Bob1 + Recursif + Non trié + Chemin relatif (OK j'ai pigé)
Local $Array1 = _RecFileListToArray($SubDir1, $FileName, 1, 1, 0, 1)

If IsArray($Array1) Then _ArrayDisplay($Array1, "Array1")

; 2/ Recherche Monfichier.txt dans C:\Test ==> Pas pigé
; récup des noms de dossiers (Recusif + Non trié + CheminComplet)
Local $Array2 = _RecFileListToArray($DirGlob, $FileName, 2, 1, 0, 1)

if IsArray($Array2) Then _ArrayDisplay($Array2, "Array2")

; 3/ Recherche MonFichier.txt dans C:\Test ==> Pas pigé
; récup tous les dossiers et fichiers (Recusif + Non trié + CheminComplet)
Local $Array3 = _RecFileListToArray($DirGlob, $FileName, 0, 1, 0, 1)

if IsArray($Array3) Then _ArrayDisplay($Array3, "Array3")

; Je supprime le dossier de test
DirRemove($DirGlob, 1)

[/spoiler]

Mes questions :

1. Est-il normal dans la 3ème recherche que je récupère la totalité des dossier/fichiers alors que je filtre sur MonFichier.txt
2. Est-il normal par contre que la seconde recherche ne me retourne rien alors que le fichier recherché existe bien dans un des sous-dossier ?
3. Est-il normal que si je change dans mon bout de code la const $FileName en remplaçant MonFichier.txt par *.Txt , les résultats ne sont plus les mêmes ?

Je me doute bien que quelque chose m'échappe mais je ne vois pas quoi. En fait je voudrais récupérer dans le cas présent, les dossiers / sous-dossiers qui contiennent un fichier bien précis.

Merci d'avance

[Tlem]

Mes réponses :

1. Non, cela n'est absolument pas normal et dénote un bug majeur (je ne l'avais pas vu dans cette version).
2. Oui, cela est tout à fait normal, car avec l'option 2, ce sont les dossiers du nom de MonFichier.txt qui sont recherchés.
3. Non, cela n'est pas normal non plus et dénote un second bug majeur que je n'avais pas vu sur cette dernière version.

Je vous encourage à signaler ces deux problèmes sur le sujet original de la fonction que vous trouverez ici => http://www.autoitscript.com/forum/topic ... -22-may-11

En attendant, je vais rajouter un petit mot dans le sujet sur ce forum afin de signaler ces bugs.

Merci de vos remarques.

[TopXm]

Bonsoir Tlem,

Je vais donc tenter de poster sur le topic histoire de prévenir.

Attendu que mon anglais est plus que limite, ça ne sera peut-être pas dans les minutes qui suivent :siffle:

Merci de m'avoir répondu et bonne soirée

[TT22]

Est-il normal dans la 3ème recherche que je récupère la totalité des dossier/fichiers alors que je filtre sur MonFichier.txt

Ce problème ne viendrait-il pas de :

Code : Tout sélectionner

Func _RecFileListToArray($sPath, $sFilter[color=#FF0000][b] = "*"[/b][/color], $iFlag = 0, $iRecur = 0, $iFullPath = 0)

[Tlem]

Il faudra lire un peut mieux ...

Code : Tout sélectionner

Local Const [color=#FF0000]$FileName = "MonFichier.txt"[/color]
.
.
.
; 3/ Recherche MonFichier.txt dans C:\Test ==> Pas pigé
; récup tous les dossiers et fichiers (Recusif + Non trié + CheminComplet)
Local $Array3 = _RecFileListToArray($DirGlob, [color=#FF0000]$FileName[/color], 0, 1, 0, 1)

Donc ce n'est pas un problème de caractère générique.

[TopXm]

Bonjour,

Bon en fait tout s'explique

Pour la 3ème recherche c'est normal, il fallait juste le savoir, Melba23 m'a bien dit que l'UDF a été faite pour des besoins persos, donc il faut s'adapter.

Réponse de MELBA23 : http://www.autoitscript.com/forum/topic ... _p__933154

Pour le second problème, c'est juste moi, je me suis troué dans mes tests ...
En fait j'utilisais la même variable $Filename
pour créer le fichier et faire les recherches du coup en remplaçant "MonFichier.txt" par "*.Txt" dans mes test
Il est certain que la création au préalable des fichiers fonctionnait beaucoup moins bien ...
Bien joué ...

J'avoue être passé complétement à travers ceci :

Code : Tout sélectionner

$iRecur <> 0 and $iReturn = 0 (Files + Folders) Searches and returns all folders unless explicitly excluded

Je poste mon coup de code du coup avec les corrections.

► Afficher le texte_RecFileListToArray

Code : Tout sélectionner

#include <RecFileListToArray.au3>
#include <array.au3>

Local Const $DirGlob = "C:\Test"
Local Const $SubDir1 = "C:\Test\Bob1"
Local Const $SubDir2 = "C:\Test\Bob1\plop"
Local Const $SubDir3 = "C:\Test\Bob1\plop1"
Local Const $FileName = "MyFile.Txt"
Local const $FileSearch = "MyFile.txt"
Local $I, $nFile

; I create some folders to test UDF
For $I = 0 to 15
    If Not FileExists($DirGlob & "\Bob" & $I) Then DirCreate($DirGlob & "\Bob" & $I)
Next

;I create subfolders who contain a text file i want to retreive
If Not FileExists($SubDir1) Then DirCreate($SubDir1)
If Not FileExists($SubDir2) Then DirCreate($SubDir2)
If Not FileExists($SubDir3) Then DirCreate($SubDir3)

;I create the same file in the tree subfolders
$nFile = FileOpen($SubDir1 & "\" & $FileName, 2)
FileClose($nFile)
$nFile = FileOpen($SubDir2 & "\" & $FileName, 2)
FileClose($nFile)
$nFile = FileOpen($SubDir3 & "\" & $FileName, 2)
FileClose($nFile)

; 1/ MyFile.Txt => Bob1
; $iReturn : 1 (FileOnly)
; $iRecurs : 1 (Search in subfolders)
; (NoOrder / Relative)
Local $Array1 = _RecFileListToArray($SubDir1, $FileSearch, 1, 1, 0, 1)
If IsArray($Array1) Then _ArrayDisplay($Array1, "Array1")

; 2/ MyFile.Txt => C:\Test
; $iReturn : 1 (FileOnly)
; $iRecurs : 1 (Search in subfolders)
; (NoOrder / Relative)
Local $Array2 = _RecFileListToArray($DirGlob, $FileSearch, 1, 1, 0, 1)
if IsArray($Array2) Then _ArrayDisplay($Array2, "Array2")

; 3/ MyFile.Txt => C:\Test !!!!! ==>  Cas particulier, vu que iReturn = 0 et $Recurs <> 0 tout est listé (fichier /sous-dossiers)
; $iReturn : 0 (FileAndFolders)
; $iRecurs : 1 (Search in subfolders)
; (NoOrder / Relative)
Local $Array3 = _RecFileListToArray($DirGlob, $FileSearch, 0, 1, 0, 1)
if IsArray($Array3) Then _ArrayDisplay($Array3, "Array3")

; => MELBA23 : Recherche des dossiers qui contiennent un fichier défini
Local $Array5 = _RecFileListToArray($DirGlob, $FileSearch, 1, 1, 0, 1)
For $i = 1 To $Array5[0]
    $Array5[$i] = StringReplace($Array5[$i], "\" & $FileName, "")
Next
_ArrayDisplay($Array5, "Array5")

; I delete test environment
DirRemove($DirGlob, 1)

Je passe donc le sujet en résolu.

[Tlem]

En ce qui concerne le second problème, j'étais moi aussi passé à coté de l'utilisation incorrecte de variable $Filename ...

Pour la 3ieme recherche, j'avais bien lu le petit message, mais il y avait cette partie : "unless explicitly excluded" qui pouvait présager qu'on pouvait exclure tout ou partie des dossiers selon un masque. Or, vous ne pouvez exclure tous les dossiers sauf ceux de la recherche explicite est exclue (ce que je trouve très moyen).
Ceci fait qu'il n'est pas possible dans le cas précis de ressortir uniquement les dossiers contenant le fichier recherché ! C'est assez handicapant pour certaines recherches car dans ce cas, il faut rajouter un traitement sur le résultat !