[..] AdlibRegiter

[Jerome]

Coucou,



Et oui, parfois besoin d'aide et de lumière de la part de mes confrères ainsi que des membres


Voici le binz :


J'ai une première fonction déclarer avec AdLibRegister comme ceci :

Code : Tout sélectionner

AdlibRegister("status",1000)

Et la fonction :

Code : Tout sélectionner

Func status()
    $time = TimerDiff($timer)
    $string = StringFormat("min: %03u  sec: %02u", $time/1000/60, Mod($time/1000,60))
    GUICtrlSetData($label_stat, $string)
EndFunc

En gros, j'initialise un Timer en debut de programme, puis j'update ce timer dans ma GUI, en gros je fait un défilement en minute / seconde de mon programme.

Bref, cette fonction marche nickel, update bien ect.


Or, je voudrait maintenant enregistrer une autre Adlib.

Donc en dessous de l'autre (déclarer au debut du script), je met :

Code : Tout sélectionner

AdlibRegister("debug",3600000)

Cette fonction Debug se lance toutes les heures.
Pour des raisons de confidentialité du programme, je ne donnerai pas la fonction debug, mais il n'y pas a pas de sleep(), ni de pause ou quoi que ce soit. Il passe dedans, check quelque chose (tester et approuvé), puis sort de l'adlib.



Vous me direz, nickel, sa roule, sa marche comme sur des patinettes.
Et bien non, une fois passer dans ma fonction Debug, la première AdlibRegister (celle Statut) n'update plus (en gros, le temps est figé sur la GUI, alors que les autres label continu d'être updater, ce qui prouve que le programme tourne toujours.)


Bref, j'ai test plusieurs chose.

Style une seul Adlib statut qui était :

Code : Tout sélectionner

Func status()
    $time = TimerDiff($timer)
    $string = StringFormat("min: %03u  sec: %02u", $time/1000/60, Mod($time/1000,60))
    GUICtrlSetData($label_stat, $string)
        If @hour = 15 AND @MIN = 10 AND @SEC = 12 then
                Debug()
        Endif
        If @hour = 16 AND @MIN = 12 AND @SEC = 54 then
                Debug()
        Endif
EndFunc

La fonction Statut passe nickel, or dés que sa passe dans le IF, sa s'arrete (pourtant le programme continu de tourner).


J'ai aussi test AdlibUnregiter (mise dans ma fonction Debug) puis de la réactiver a la fin de la fonction Statut, sa donne rien....


Bref, need help




Cordialement,
Jérôme

[jchd]

Peut-être lié à ce bug et/ou à cet autre.

[matwachich]

J'ai remarqué il y a longtemps que Adlib n'est pas super fiable

Si j'étai toi, je ferai comme ça:

Code : Tout sélectionner

; Debut programme
Global $__Timer_Status, $__Timer_Update, $__Timer_Debug

; ...

$__Timer_Status = TimerInit()
$__Timer_Update = TimerInit()
$__Timer_Debug = TimerInit()

While 1 ; Boucle principale
    ; ---
    If TimerDiff($__Timer_Update) >= 1000 Then
        $timer = TimerDiff($__Timer_Status)
        $string = StringFormat("min: %03u  sec: %02u", $time/1000/60, Mod($time/1000,60))
        GUICtrlSetData($label_stat, $string)
        $__Timer_Update = TimerInit()
    EndIf
    ; ---
    If TimerDiff($__Timer_Debug) >= 3600000 Then
        _Debug()
        $__Timer_Debug = TimerInit()
    EndIf
    ; ---
    ; reste du programme
WEnd

[mikell]

Dans l'idée de matwachich, pourquoi pas un seul timer ?
Quelque chose comme ça (approximativement) :

► Afficher le texte

Code : Tout sélectionner

Opt("GUIOnEventMode", 1)
GuiCreate("", 200, 100)
$label = GUICtrlCreateLabel("", 10, 10, 120, 40)
GuiSetState()
GUISetOnEvent (-3, "_Exit")
$Timer = TimerInit()

While 1
   If Mod(Round(TimerDiff($Timer),2), 100) = 0 Then
        $time = TimerDiff($Timer)
        $string = StringFormat("min: %03u  sec: %02u", $time/1000/60, Mod($time/1000,60))
        GUICtrlSetData($label, $string)
    EndIf
  ;  If Mod(TimerDiff($Timer), 3600000) = 0 Then
  ;      _Debug()
   ; EndIf
WEnd

Func _Exit()
Exit
EndFunc

Edit : Mais c'est lourd... en fait AdLib ça semble mieux, parce que plus besoin de timer, un compteur suffit :

► Afficher le texte

Code : Tout sélectionner

GuiCreate("", 200, 100)
$label = GUICtrlCreateLabel("", 10, 10, 120, 40)
GuiSetState()

$count = 0
AdlibRegister("status",1000)

While GuiGetMsg()<>-3
WEnd

Func status()
   $string = StringFormat("min: %03u  sec: %02u", Floor($count/60), $count)
   GUICtrlSetData($label, $string)

  ;  If Mod($count, 3600) = 0 Then _Debug() 

    $count += 1
EndFunc

 

[bloodwolff]

Essaye de mettre une autre fonction à la place de débug pour voir si le problème vient de là

[Tlem]

En étant un peut chercheur de mer.., j'ai testé ceci avec succès !!!

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

AdlibRegister("Update_1",1000)
AdlibRegister("Update_2",5000)
AdlibRegister("Update_3",10000)

$timer = TimerInit()

#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Ma GUI", 400, 200, 190, 125)

Global $Label1 = GUICtrlCreateLabel("Toutes les 01 secondes : ", 16, 25, 210, 24)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
Global $Label1_1 = GUICtrlCreateLabel("XXXXX", 230, 25, 130, 24)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")

Global $Label2 = GUICtrlCreateLabel("Toutes les 05 secondes : ", 15, 70, 210, 24)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
Global $Label2_1 = GUICtrlCreateLabel("XXXXX", 230, 70, 130, 24)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")

Global $Label3 = GUICtrlCreateLabel("Toutes les 10 secondes : ", 15, 120, 210, 24)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
Global $Label3_1 = GUICtrlCreateLabel("XXXXX", 230, 120, 130, 24)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func Update_1()
    Local $time = TimerDiff($timer)
    Local $string = StringFormat("%03u:%02u", $time/1000/60, Mod($time/1000,60))
    GUICtrlSetData($label1_1, $string)
    Debug("Fonction 1 à : " & StringRight($string, 2))
EndFunc

Func Update_2()
    Local $time = TimerDiff($timer)
    Local $string = StringFormat("%03u:%02u", $time/1000/60, Mod($time/1000,60))
    GUICtrlSetData($label2_1, $string)
    Local $RightSec = StringRight($string, 1)
    If $RightSec = "5" Or $RightSec = "0" Then
        Debug("Fonction 2 à : " & StringRight($string, 2))
    EndIf
EndFunc

Func Update_3()
    Local $time = TimerDiff($timer)
    Local $string = StringFormat("%03u:%02u", $time/1000/60, Mod($time/1000,60))
    GUICtrlSetData($label3_1, $string)
    Local $RightSec = StringRight($string, 1)
    If $RightSec = "0" Then
        Debug("Fonction 3 à : " & StringRight($string, 2))
    EndIf
EndFunc

Func Debug($Data)
    ConsoleWrite($Data & @CRLF)
EndFunc

Donc j'en conclu (peut être à tord) à un problème sur ta fonction debug.
Regarde si tu ne touche pas des variables.