[R] Test click sur GUI

[pierrotm777]

Bon , cela fait plusieurs jours que je cherche sur les différents forums et sur le net le moyen de tester le click souris sur une gui est retourner une action (aller, un message par exemple) .
J'utilise la fonction suivante pour le test du click gauche:

► Afficher le texte

Code : Tout sélectionner

GUIRegisterMsg($WM_LBUTTONDOWN, "_WM_LBUTTONUP")

... 
mon script
...

;======================================================================================================
;Test if the mouse click on a gui of an indicator
;======================================================================================================
Func _WM_LBUTTONUP($hWnd, $iMsg, $wParam, $lParam)
    ; Action the dummy control
    GUICtrlSendToDummy($hLeftClick)
    msgbox(0,"",$hWnd&@crlf&$iMsg&@crlf&$wParam&@crlf&$lParam)
;   msgbox(0,"",WinGetHandle("[active]",""))
EndFunc

Je joins l'ensemble de mon exemple pour mieux comprendre.
Le but est donc de cliquer sur l'un des trois logos en haut à droite et d'obtenir une action différente pour chaque logo !

Merci encore une fois pour votre aide

[Tlem]

Liez une action pour chaque logo.

Koda is your friend.

[pierrotm777]

Puff, je n'ai pas de tête, j'ai mis à jour le post 1 avec les fichiers nécessaires.

désolé

[pierrotm777]

Alors , j'ai essayé koda et j'ai obtenu un peu la même chose que j'avais imaginé à savoir utiliser la function GUICtrlCreateDummy(), que je ne connaissait pas avant hier ! Encore une

Ca me donne donc cet exemple:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 451, 192, 124)
$Dummy1 = GUICtrlCreateDummy()
GUISetState(@SW_SHOW)
Dim $Form1_AccelTable[1][2] = [["{F1}", $Dummy1]]
GUISetAccelerators($Form1_AccelTable)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Mais cela fonctionne encore moins que mon exemple
Je n'avais pas vue l'option GUISetAccelerators($Form1_AccelTable), et aprés lecture de l'aide, il fallait ajouter aux lignes de koda un test sur $Dummy1:

Code : Tout sélectionner

        Case $Dummy1
            MsgBox(0,"","Test",2)

Et là cela fonctionne, il me reste à voir si cela convient à mon script !

[pierrotm777]

Bon, j'ai testé, mais cela ne convient pas avec le click de la souris !
De plus, le premier appuie sur une touche est bien testé mais pas le suivant .

[Tlem]

Heuu, j'ai du mal à comprendre votre raisonnement.
Est-ce que ceci correspond à votre demande ?

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Form1", 198, 142, 192, 124)
Global $Label1 = GUICtrlCreateLabel("Cliquez ce message", 24, 16, 144, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
Global $Icon1 = GUICtrlCreateIcon("C:\WINDOWS\system32\shell32.dll", -7, 80, 56, 32, 32, BitOR($SS_NOTIFY,$WS_GROUP))
Global $Label2 = GUICtrlCreateLabel("Cliquez cet icône", 56, 88, 85, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

    Case $Label1
        MsgBox(64, 'Info', 'Vous avez cliqué sur le message')

    Case $Icon1
        MsgBox(64, 'Info', 'Vous avez cliqué sur l''icône')

 EndSwitch
WEnd

[pierrotm777]

Merci de votre aide Tlem,
Cela pourrait me convenir, si la gui principale ainsi que les logos n'étaient pas des .png chargés grâce à GDI+ .

[pierrotm777]

Avec la fonction du post 1, j'arrive à lire le handel de chaque logo , mais je ne sais pas les tester dans mon exemple !
j'ai mis à jour le fichier zip du post 1 dans lequel il manquait le .png de la fenêtre principale !

[Tlem]

Ce n'est pas un problème de GDI+, c'est juste que vous créez des objets graphique, mais ne stockez pas le control ID de chacun d'eux.

1 contrôle = 1 control ID
1 control ID = gestion du contrôle qui en dépend.

Ensuite, si je regarde votre code :

• 1 - Vous stockez la liste des images à afficher dans un tableau par la ligne :

  Code : Tout sélectionner

  _FileReadToArray(@ScriptDir&"\liste.txt",$avarray)

  2 - Vous faites une boucle For/next afin d'afficher chaque image.
  
  3 - Dans cette boucle, vous lancez autant de fois que vous avez d'image, la fonction MySplash()

Le problème, c'est que la fonction MySplash ne renvois rien d'utilisable et que dans celle-ci vous créez à chaque fois une GUI ($GUI) que vous passez au premier plan de surcroit.

Revoyez votre manière de peupler votre GUI avec vos éléments et cela devrait le faire.

[pierrotm777]

Bon , j'ai essayé de travailler le sujet mais sans succes:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <File.au3>


$hGUI2 = GUICreate("OverLayMenu", 200, 200, -1, -1, $WS_POPUP, $WS_EX_LAYERED + $WS_EX_TOPMOST)

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST"); déplacement du menu possible

_GDIPlus_Startup()
$hImage =  _GDIPlus_ImageLoadFromFile(@ScriptDir & "\GTA_MenuV_off.png")
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)
$w = _GDIPlus_ImageGetWidth($hImage)
$h = _GDIPlus_ImageGetHeight($hImage)
_SetBitMap($hGUI2, $hImage, 255, $w, $h)
GUISetState()

Dim $avarray, $Xpos = 150, $Var, $Blink, $GUI
_FileReadToArray(@ScriptDir&"\liste.txt",$avarray)

For $i = 1 to $avarray[0]
    $Var = StringSplit($avarray[$i],",")
    $Logo = $Var[1]
    $Blink = $Var[2];clignotement si = 1
    $Speed = $Var[3];vitesse de clignotement en ms
    MySplash($Logo,@ScriptDir&"\"&$Logo, $Speed, $Blink , $Xpos,2,30,30)
    $Xpos = $Xpos+32
Next

while 1
    $msg = GUIGetMsg()
    For $i = 1 to $avarray[0]
        If $msg = $Logo Then MsgBox(0,"","Click on the logo :"&$Logo,2)
    Next
    sleep(100)
Wend

Func MySplash($IndName,$Path_Logo, $Time_Splash, $Blink, $Xlogo, $Ylogo, $newW, $newH)
    $GUI = GUICreate($IndName, $newW, $newH, $Xlogo, $Ylogo, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD),$hGUI2)
    $hImage = _ImageResize($Path_Logo,  $newW, $newH)
    _SetBitMap($GUI, $hImage, 255,  $newW, $newH)
    GUISetState()
    WinSetOnTop($GUI, "", 1)
EndFunc   ;==>MySplash

Func _ImageResize($sInImage, $newW, $newH)
    Local $oldImage, $GC, $newBmp, $newGC
    _GDIPlus_Startup()
    $oldImage = _GDIPlus_ImageLoadFromFile($sInImage)
    $GC = _GDIPlus_ImageGetGraphicsContext($oldImage)
    $newBmp = _GDIPlus_BitmapCreateFromGraphics($newW, $newH, $GC)
    $newGC = _GDIPlus_ImageGetGraphicsContext($newBmp)
    _GDIPlus_GraphicsDrawImageRect($newGC, $oldImage, 0, 0, $newW, $newH)
    _GDIPlus_GraphicsDispose($GC)
    _GDIPlus_GraphicsDispose($newGC)
    _GDIPlus_ImageDispose($oldImage)
    Return $newBmp ;
EndFunc   ;==>_ImageResize

Func _SetBitmap($hGUI, $hImage, $iOpacity, $n_width, $n_height)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", $n_width)
    DllStructSetData($tSize, "Y", $n_height)
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", 1)
    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>_SetBitmap

; ====================================================================================================
; Handle the WM_NCHITTEST for the layered window so it can be dragged by clicking anywhere on the image.
; ====================================================================================================
Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    If ($hWnd = $hGUI2) And ($iMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

[zeshrek]

C'est normal.
Tu n'identifie nulle part de facon pérenne tes icones (je comprend pas pkoi tu les mets dans des GUI filles... ce qui aide pas a les gerer depuis la mere.) du coup dans ta boucle qui prend le $msg, je vois mal comment tu pourras les récupérer.

Du coup il faut gérer ca avec les coordonnées de a souris. Tu sais ce que tu as déposé et en quelle coordonnées, donc quand tu cliques a un endroit, tu dois pouvoir séduire sur quoi se trouve la souris

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <File.au3>

Opt("WinTitleMatchMode", 1)

$hGUI2 = GUICreate("OverLayMenu", 200, 200, -1, -1, $WS_POPUP, $WS_EX_LAYERED + $WS_EX_TOPMOST)

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST"); déplacement du menu possible

_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\GTA_MenuV_off.png")
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)
$w = _GDIPlus_ImageGetWidth($hImage)
$h = _GDIPlus_ImageGetHeight($hImage)
_SetBitMap($hGUI2, $hImage, 255, $w, $h)
GUISetState()

Dim $avarray, $Xpos = 150, $Var, $Blink, $GUI
_FileReadToArray(@ScriptDir & "\liste.txt", $avarray)

Dim $LogoID[$avarray[0] + 1]
For $i = 1 To $avarray[0]
    $Var = StringSplit($avarray[$i], ",")
    $Logo = $Var[1]
    $LogoID[$i] = $Logo
    $Blink = $Var[2];clignotement si = 1
    $Speed = $Var[3];vitesse de clignotement en ms
    MySplash($Logo, @ScriptDir & "\" & $Logo, $Speed, $Blink, $Xpos, 2, 30, 30)
    $Xpos = $Xpos + 32
Next

$LeftClickDown = -7
$LeftClickUp = -8
$SensibiliteClick = 150 ; durée pendant laquelle un appui du bouton de la souris est pris comme un click (évite le déplacement pendant le click)
While 1
    $WinPos = WinGetPos("OverLayMenu")
    $msg = GUIGetMsg()
    If $msg = $LeftClickDown Then $click = TimerInit()
    If $msg = $LeftClickUp Then
        If TimerDiff($click) < $SensibiliteClick Then
            If MouseGetPos(1) >= $WinPos[1] + 2 And MouseGetPos(1) <= $WinPos[1] + 32 Then
                $IdLogo = Int((MouseGetPos(0) - $WinPos[0] - 150) / 32) + 1
                If $IdLogo >= 0 And $IdLogo <= $avarray[0] Then
                    MsgBox(0, "", "Click on the logo :" & $LogoID[$IdLogo], 2)
                EndIf
            EndIf
        EndIf
    EndIf
    Sleep(100)
WEnd

Func MySplash($IndName, $Path_Logo, $Time_Splash, $Blink, $Xlogo, $Ylogo, $newW, $newH)
    $GUI = GUICreate($IndName, $newW, $newH, $Xlogo, $Ylogo, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $hGUI2)
    $hImage = _ImageResize($Path_Logo, $newW, $newH)
    $bitmapID = _SetBitMap($GUI, $hImage, 255, $newW, $newH)
    GUISetState()
    WinSetOnTop($GUI, "", 1)
EndFunc   ;==>MySplash

Func _ImageResize($sInImage, $newW, $newH)
    Local $oldImage, $GC, $newBmp, $newGC
    _GDIPlus_Startup()
    $oldImage = _GDIPlus_ImageLoadFromFile($sInImage)
    $GC = _GDIPlus_ImageGetGraphicsContext($oldImage)
    $newBmp = _GDIPlus_BitmapCreateFromGraphics($newW, $newH, $GC)
    $newGC = _GDIPlus_ImageGetGraphicsContext($newBmp)
    _GDIPlus_GraphicsDrawImageRect($newGC, $oldImage, 0, 0, $newW, $newH)
    _GDIPlus_GraphicsDispose($GC)
    _GDIPlus_GraphicsDispose($newGC)
    _GDIPlus_ImageDispose($oldImage)
    Return $newBmp ;
EndFunc   ;==>_ImageResize

Func _SetBitmap($hGUI, $hImage, $iOpacity, $n_width, $n_height)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", $n_width)
    DllStructSetData($tSize, "Y", $n_height)
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", 1)
    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>_SetBitmap

; ====================================================================================================
; Handle the WM_NCHITTEST for the layered window so it can be dragged by clicking anywhere on the image.
; ====================================================================================================
Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    If ($hWnd = $hGUI2) And ($iMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

[pierrotm777]

Je n'ai trouvé que cette solution pour visualiser mes logo, mais vous avez une solution plus simple , je suis preneur .

Je teste de suite votre proposition !

C'ets ce que je souhaite mais le temps de réponse est trés lent .

Si vous avez une une solution pour créer les logo et tester un click sur chacun d'eux , je suis preneur !

[Tlem]

Franchement, je ne pense pas que pierrotm777 cherche à faire des tas de GUI fille.
Ce sont simplement les fonctions MySplash et _SetBitmap qui ne vont pas.

Créez la GUI ($GUI) en dehors de la fonction MySplash et en dehors de votre boucle For/Next (juste avant, c'est bien ).
Ensuite, vous devrez trouver une solution pour récupérer de la fonction _SetBitmap l'ID ou le handle du contrôle image (sans quoi vous ne pourrez rien gérer). Au pire, surchargez votre image par un contrôle transparent pour lequel vous pourrez obtenir un control ID ou un handle.

Sans control ID ou handle, ce n'est pas la peine de chercher à faire quoi que ce soit !!!

Si vous arrivez à trouver une solution pour avoir ce control ID ou handle, stockez les dans un tableau. Et oui, je dit 'les' parce que vous avez plusieurs images et donc plusieurs control ID ou handle.
Ce n'est qu'à ces conditions que vous pourrez continuer votre code.

[zeshrek]

Sans control ID ou handle, ce n'est pas la peine de chercher à faire quoi que ce soit !!!

Bon, sur le principe, je suis 100% d'accord avec toi boss.
Mais...
Bin en fait on peut tres bien se débrouiller sans handle
C'est lourd et peu performant, mais il est tout a fait possible de faire une GUI sans le moindre controle. Il suffit pour ca de récupérer les coordonnées de la souris, et a partir de la savoir sur quelle zone l'utilisateur a cliqué.

Anyway, je ne comprend toujours pas l'interet de faire une gui fille juste pour y cloquer une image.
Il est possible de faire une GUI sans bordure ni fond, donc transparente.
Il est possible de mettre ensuite dans cette GUI une image qui servira de fond (et il existe des moyens de la rendre semi transparente si il vaut garder cet effet), et d'y mettre des boutons avec une image (pour garder le design tout arrondi)
Et du coup, la gui se gère tout a fait normalement.

A part ca, moi je dis rien...

[Tlem]

C'est lourd et peu performant

C'est peut de le dire. Et puis ce n'est franchement pas une approche raisonnable dans cette situation, car il faudra calculer la position des contrôles par rapport à la fenêtre, puis de la fenêtre par rapport au bureau + la résolution d'écran et enfin gérer les coordonnées de la souris ...

Non, là, franchement, je te le laisse.

[pierrotm777]

J'ai essayé cela mais cela ne marche pas non plus !

► Afficher le texte

Code : Tout sélectionner

GUIRegisterMsg($WM_LBUTTONDOWN, "_WM_LBUTTONDOWN")

...

Func _WM_LBUTTONDOWN($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iX = BitAND($ilParam, 0xFFFF), $iY = BitShift($ilParam, 16)
    ConsoleWrite("!Double click on: [" & $iX & "," & $iY & "]" & @CRLF)
;   MsgBox(0,"",$hWnd&@CRLF&$iMsg&@CRLF&$iwParam&@CRLF&$ilParam)
;   Return $GUI_RUNDEFMSG
    For $Ln = 1 To $Skin[0]
        If StringLeft($Skin[$Ln], 2) = "I," Then
            $Var = StringSplit($Skin[$Ln], ",")
            $Logo = StringReplace($Var[9],'"','')
            $LogoID[$Ln] = $Logo
            $Xpos = $Var[2]
            $Ypos = $Var[3]
            $Width = $Var[4]
            $Height = $Var[5]
            If $iX > $Xpos and $iX < $Xpos+$Width and $iY > $Ypos and $iY < $iY+$Height Then
                MsgBox(0,"","Je click sur le logo : "&$Logo)
            EndIf
        EndIf
    Next
    Return $Logo
EndFunc

Je suis d'accord avec Tlem, le système avec la position de la souris a un temps de réponse trés long.

Nota:
Le format de ma liste de logo a un peu changé (les coordonnéspuis la taille sont incluses,I,$x,$y$,$w,$h,,1500,1500,"Logo"):

Code : Tout sélectionner

I,150,5,30,30,"gpsvalid:b",1500,1500,"Skype.png"
I,182,5,30,30,"gpsvalid",1500,1500,"gimp.png"
I,214,5,30,30,"online",1500,1500,"arrow.png"

Là je suis perdu !

[Tlem]

Là je suis perdu !

Reprenez la construction de votre interface.

Regardez si vous avez la nécessité d'avoir 2 GUI superposées, ou si vous pouvez en garder une seule.

Ensuite, faites en sorte d'avoir le contol ID ou le handle de chaque éléments et en dernier étudiez la manière de stocker puis cliquer sur chaque élément.

[pierrotm777]

Mon besoin est:
Une GUI et des logo capables de clignoter ou pas selon la présence ou pas d'un :B dans leur ligne de définition !
Aprés le plus simple est toujours le mieux !

[pierrotm777]

Bon , j'ai réussi à adapter un code d'un ami à mon besoin, il manque juste la fonction de création des logo et celle de clignotement.
Je n'ai donc absolument pas le mérite de ce code !

Cliquez sur le haut droit du menu, un splash text doit apparaître

Pour info le fichier de définition est ainsi:

Code : Tout sélectionner

I,150,5,30,30,"skype:B",1500,500,"Skype.png"
I,182,5,30,30,"phone",1500,500,"Phone.png"
I,214,5,30,30,"online",1500,500,"Online.png"

Où 1500 est le délais où le logo reste allumé et 500 celui où il est éteint .
Le logo ne doit clignoter que si un :b est présent dans la ligne !

Je joins les logo on off où _00.png = logo état off et _01.png = état on

[pierrotm777]

Bon , je suis têtu, il y a surement mieux ou plus simple et je suis preneur, mais voici ma solution qui fonctionne trés bien cette fois ci

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <File.au3>

Opt("WinTitleMatchMode", 3)

$hGUI2 = GUICreate("OverLayMenu", 200, 200, -1, -1, $WS_POPUP, $WS_EX_LAYERED + $WS_EX_TOPMOST)

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST"); déplacement du menu possible
GUIRegisterMsg($WM_LBUTTONDOWN, "_WM_LBUTTONDOWN");test if the left mouse button click on an Indicator

_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\GTA_MenuV_off.png")
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)
$w = _GDIPlus_ImageGetWidth($hImage)
$h = _GDIPlus_ImageGetHeight($hImage)
_SetBitMap($hGUI2, $hImage, 255, $w, $h)
GUISetState()

;définition des indicators comme boutons
Dim $Indicator[1][1][1]
$NumInd = ""
$Indicator[0][0][0] = ""

Dim $Skin, $Xpos, $Height, $Width, $Height, $Var, $Blink, $GUI
_FileReadToArray(@ScriptDir & "\liste.txt", $Skin)
if @error then Exit


Dim $LogoID[$Skin[0] + 1]
for $Ln = 1 to $Skin[0]
    if StringLeft($Skin[$Ln], 2) = "I," Then                  ;indicators
        $Var = StringSplit($Skin[$Ln], ",")
        If StringInStr($Var[9],"_") Then
            $Logo = StringSplit(StringReplace($Var[9],'"',''),"_")
            $LogoID[$Ln] = $Logo[1]
            $Ind = "_01"
            $Logo = $LogoID[$Ln]&$Ind&".png"
        Else
            $Logo = StringReplace($Var[9],'"','')
            $LogoID[$Ln] = $Logo
            $Ind = ""
            $Logo = $LogoID[$Ln]&$Ind
        EndIf
        $Speed = 1500;vitesse de clignotement en ms
        If $Var[7] <> "" and $Var[8] <> "" Then
            $IndBlink =1
        EndIf
;       MsgBox(0,"",$Logo)
        MySplash($Logo,@ScriptDir&"\"&$Logo, $Speed, $IndBlink, $Var[2] ,$Var[3], $Var[4] ,$Var[5])

    EndIf
Next


While 1
    $msg = GUIGetMsg()
    Sleep(100)
WEnd

;======================================================================================================
; Build a Gui for each indicator
;======================================================================================================
Func MySplash($LnndName, $Path_Logo, $Time_Splash, $Blink, $Xlogo, $Ylogo, $newW, $newH)
    $GUI = GUICreate($LnndName, $newW, $newH, $Xlogo, $Ylogo, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $hGUI2)
    $hImage = _ImageResize($Path_Logo, $newW, $newH)
    $bitmapID = _SetBitMap($GUI, $hImage, 255, $newW, $newH)
    GUISetState()
    WinSetOnTop($GUI, "", 1)
EndFunc   ;==>MySplash

Func _ImageResize($sInImage, $newW, $newH)
    Local $oldImage, $GC, $newBmp, $newGC
    _GDIPlus_Startup()
    $oldImage = _GDIPlus_ImageLoadFromFile($sInImage)
    $GC = _GDIPlus_ImageGetGraphicsContext($oldImage)
    $newBmp = _GDIPlus_BitmapCreateFromGraphics($newW, $newH, $GC)
    $newGC = _GDIPlus_ImageGetGraphicsContext($newBmp)
    _GDIPlus_GraphicsDrawImageRect($newGC, $oldImage, 0, 0, $newW, $newH)
    _GDIPlus_GraphicsDispose($GC)
    _GDIPlus_GraphicsDispose($newGC)
    _GDIPlus_ImageDispose($oldImage)
    Return $newBmp ;
EndFunc   ;==>_ImageResize

Func _SetBitmap($hGUI, $hImage, $LnOpacity, $n_width, $n_height)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", $n_width)
    DllStructSetData($tSize, "Y", $n_height)
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $LnOpacity)
    DllStructSetData($tBlend, "Format", 1)
    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>_SetBitmap


; ====================================================================================================
; Handle the WM_NCHITTEST for the layered window so it can be dragged by clicking anywhere on the image.
; ====================================================================================================
Func WM_NCHITTEST($hWnd, $LnMsg, $LnwParam, $LnlParam)
    If ($hWnd = $hGUI2) And ($LnMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

;======================================================================================================
;Test if the mouse click on a gui of an indicator and test if the handel is the same as the gui clicked
;======================================================================================================
Func _WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
;   msgbox(0,"",$hWnd&@crlf&$iMsg&@crlf&$wParam&@crlf&$lParam,2)
$var = WinList()
For $i = 1 to $var[0][0]
    If $var[$i][0] <> "" Then
        If $var[$i][1] = $hWnd Then
            For $Ln = 1 to $Skin[0]
                If StringLeft($Skin[$Ln], 2) = "I," Then
                    $Var2 = StringSplit($Skin[$Ln], ",")
                    $Ind = "_01"
                    $Logo2 = StringReplace(StringReplace($Var2[9],'"',''),"_*.png",$Ind&".png")
                    $CMDtoExecute = StringReplace($Var2[6],'"','')
;                   MsgBox(0, "Details",$Logo2,2)
                    If $Logo2 = $var[$i][0] Then
;                       MsgBox(0, "Details", "I click on the logo : " & $var[$i][0],2)
                        MsgBox(0, "Details", "I click on the logo : " & $Logo2,2)
                    EndIf
                EndIf
            Next
        EndIf
    EndIf
Next
EndFunc

Il ne me manque que la fonction de clignotement , alors si vous avez une idée !

Je suis preneur de toute simplification