[..] AU3Info.exe / Connaitre class et nom d'une fenêtre

[pierrotm777]

Aprés avoir parcouru le forum , je constate que AU3Info.exe fait exactement ce que je veux.
Seulement, je voudrais intégrer la fonction 'Finder Tool' dans un de mes scripts.
Existe t-il un source auoit de cet exe ?

Si non, comment puis je connaitre titre et class d'une fenêtre quand la souris se place sur la fenêtre choisie ?

Merci de votre aide

[pierrotm777]

Bon,
J'ai trouvé une solution pour la 'class name' mais pour le 'titre' je dois clicker sur la fenêtre ce que je n'aime pas trop !

voici le code trouvé sur le forum anglais !

► Afficher le texte

Code : Tout sélectionner

#include <WinAPI.au3>

HotKeySet("{ESC}", "On_Exit")

Func On_Exit()
    Exit
EndFunc

$hCurr_HhWnd = 0

While 1

    If @AutoItX64 Then
        Local $tPoint = DllStructCreate("int X;int Y")
        DllStructSetData ( $tPoint, "X", MouseGetPos(0))
        DllStructSetData ( $tPoint, "Y", MouseGetPos(1))
        Local $tPoint64 = DllStructCreate("int64", DllStructGetPtr($tPoint))
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "int64", DllStructGetData($tPoint64, 1))
    Else
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
    EndIf

    If $aHwnd[0] <> $hCurr_HhWnd Then
        ConsoleWrite("Title : "&WinGetTitle("[ACTIVE]")&" **  ClassName" & _WinAPI_GetClassName($aHwnd[0]) & @CRLF)
        $hCurr_HhWnd = $aHwnd[0]
    EndIf

WEnd

Merci de votre aide

[pierrotm777]

Bon j'ai fini par trouver la solution toujours sur le forum anglais:

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StructureConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Dim $hCurr_HhWnd = 0

$MainGUI = GUICreate("Skinner Tool ", 500, 603, -1, -1)
$WindowInfo = GUICtrlCreateButton("Tools", 430, 30, 60, 30, $BS_ICON, BitOR($WS_EX_CLIENTEDGE,$WS_EX_STATICEDGE))
GUISetState()

;Window Info Gui
$WindowInfoGUI = GUICreate("Window Info", 496, 170, -3, -205,BitOR($WS_SYSMENU,$WS_DLGFRAME,$WS_POPUP,$WS_CLIPSIBLINGS),bitor($WS_EX_MDICHILD,$WS_EX_CLIENTEDGE),$MainGUI)
$windowtitle = GUICtrlCreateLabel("Title : ",10, 10, 490, 20)
;GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$windowclass = GUICtrlCreateLabel("Class : ",10, 40, 490, 100)
;GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUISetState(@SW_HIDE,$WindowInfoGUI)
$WindowInfoGUIStatus = False

While 1
    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            If WinActive($MainGUI) Then
                Exit
            ElseIf WinActive($WindowInfoGUI) Then
                GUISetState(@SW_HIDE,$WindowInfoGUI)
            EndIf
;Info fenêtre
        Case $WindowInfo
            GUISwitch($WindowInfoGUI)
            if $WindowInfoGUIStatus = true Then
                GUISetState(@SW_HIDE,$WindowInfoGUI)
                $WindowInfoGUIStatus = False
            Else
                GUISetState(@SW_SHOW,$WindowInfoGUI)
                $WindowInfoGUIStatus = True
            EndIf
    EndSwitch

;donne la classe et le nom d'une fenêtre cliquée
        If $WindowInfoGUIStatus = True Then
            Opt("MouseCoordMode", 1) ;1=absolute, 0=relative, 2=client
            If @AutoItX64 Then
                Local $tPoint = DllStructCreate("int X;int Y")
                DllStructSetData ( $tPoint, "X", MouseGetPos(0))
                DllStructSetData ( $tPoint, "Y", MouseGetPos(1))
                Local $tPoint64 = DllStructCreate("int64", DllStructGetPtr($tPoint))
                Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "int64", DllStructGetData($tPoint64, 1))
            Else
                Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
            EndIf

            If $aHwnd[0] <> $hCurr_HhWnd Then
                GUICtrlSetData($windowclass,"Class : "&_WinAPI_GetClassName($aHwnd[0]) & @CRLF)
                Local $stPoint=DllStructCreate($tagPOINT),$hControl,$hWin,$aLastPos[2]=[-1,-1],$sLastStr='',$sStr
                DllStructSetData($stPoint,1,MouseGetPos(0))
                DllStructSetData($stPoint,2,MouseGetPos(1))
                $hControl=_WinAPI_WindowFromPoint($stPoint)
                $hWin=_WinAPI_GetAncestor($hControl,2)
                GUICtrlSetData($windowtitle,"Title : "&WinGetTitle($hWin))
                $hCurr_HhWnd = $aHwnd[0]
            EndIf
        EndIf
Wend

Si vous avez plus court , je suis preneur !!!

[matwachich]

Ton code se complique grave la vie!!!
Je l'ai simplifié

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StructureConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Dim $hCurr_HhWnd = 0

$MainGUI = GUICreate("Skinner Tool ", 500, 200, -1, -1)
$WindowInfo = GUICtrlCreateButton("Tools", 430, 30, 60, 30, $BS_ICON, BitOR($WS_EX_CLIENTEDGE, $WS_EX_STATICEDGE))
GUISetState()

;Window Info Gui
$WindowInfoGUI = GUICreate("Window Info", 496, 170, -3, -205, BitOR($WS_SYSMENU, $WS_DLGFRAME, $WS_POPUP, $WS_CLIPSIBLINGS), BitOR($WS_EX_MDICHILD, $WS_EX_CLIENTEDGE), $MainGUI)
$windowtitle = GUICtrlCreateLabel("Title : ", 10, 10, 490, 20)
    GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$windowclass = GUICtrlCreateLabel("Class : ", 10, 40, 490, 100)
    GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUISetState(@SW_HIDE, $WindowInfoGUI)
$WindowInfoGUIStatus = False

While 1
    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            If WinActive($MainGUI) Then
                Exit
            ElseIf WinActive($WindowInfoGUI) Then
                GUISetState(@SW_HIDE, $WindowInfoGUI)
            EndIf
            ;Info fenêtre
        Case $WindowInfo
            GUISwitch($WindowInfoGUI)
            If $WindowInfoGUIStatus = True Then
                GUISetState(@SW_HIDE, $WindowInfoGUI)
                $WindowInfoGUIStatus = False
            Else
                GUISetState(@SW_SHOW, $WindowInfoGUI)
                $WindowInfoGUIStatus = True
            EndIf
    EndSwitch

    ;donne la classe et le nom d'une fenêtre cliquée
    If $WindowInfoGUIStatus = True Then
;~      Opt("MouseCoordMode", 1) ;1=absolute, 0=relative, 2=client
        $point = _TagPoint()
        $aHwnd = _WinAPI_WindowFromPoint($point)

        If $aHwnd <> $hCurr_HhWnd Then
            GUICtrlSetData($windowtitle, "Title : " & WinGetTitle(_WinAPI_GetAncestor($aHwnd, 2))) ; Titre de la fenêtre parente du control en cours de survol
            GUICtrlSetData($windowclass, "Class : " & _WinAPI_GetClassName($aHwnd) & @CRLF) ; Class du control en cours de survol
            $hCurr_HhWnd = $aHwnd
        EndIf
    EndIf
WEnd

Func _TagPoint()
    Local $stPoint = DllStructCreate($tagPOINT)
    Local $mousePos = MouseGetPos()
    DllStructSetData($stPoint, 1, $mousePos[0])
    DllStructSetData($stPoint, 2, $mousePos[1])
    Return $stPoint
EndFunc   ;==>_TagPoint

[pierrotm777]

Merci beaucoup, en effet c'est plus simple.
Une question , pourquoi'n'ai-je plus besoin de 'Opt("MouseCoordMode", 1)' pour être en coordonnées absolues ?

[matwachich]

Extrait de l'aide d'AutoIt

Code : Tout sélectionner

MouseCoordMode Sets the way coords are used in the mouse functions, either absolute coords or coords relative to the current active window:
0 = relative coords to the active window
1 = absolute screen coordinates [b][u](default)[/u][/b]
2 = relative coords to the client area of the active window

[pierrotm777]

Oui, bien-sûre, ma question était pourquoi par défaut les coordonnées était en absolu !
En fait , pour une autre autre application, j'ai besoin d'être en relatif , c'est donc la raison pour laquelle j'avais bien besoin de cette option !

Merci encore