[..] Programme qui lit dans un fichier .txt

[AlapOwner]

Bonjour !
Je ne veux pas réellement un script complet, j'aimerai plutot savoir comment faire pour que mon programme, lise dans un fichier .txt, edite le texte qui y est contenu et écrive a l'interieur !

Ca serait en fait un programme qui retient un ID et un Mot de passe(que l'utilisateur a tapé dans deux Input) qui s'enregistre dans un fichier .txt, ainsi au démarrage du programme la seconde fois, le programme lit dans le fichier texte les informations et restaure ce que l'utilisateur avait inscrit dans les Input la premiére fois !

J'espere que ma requete n'est pas trop compliqué, je vous remercie d'avance de l'aide que j'espere, vous saurez m'apporter !

[Tlem]

L'utilisation d'un fichier .ini serait sans doute plus approprié.
Regardez l'exemple de la documentation de la commande IniWrite, elle devrait vous mettre sur la voie.

[bloodwolff]

pour enregistrer des informations comme cela il serait encore plus simple d'y aller avec un fichier .ini
Les fonctions iniwrite et iniread devraient vous être utile.

Pour ce qui est de vérifier au démarrage une simple conditions avec if et iniread devrait convenir

Code : Tout sélectionner

If IniRead("fichier.ini", "Information de connection","Nom de compte","") <> "" Then _
GUICtrlSetData($id_de_linput, IniRead("fichier.ini", "Information de connection","Nom de compte",""))

PS: Tlem m'a coupé l'herbe sous le pied

[AlapOwner]

Merci pour ses réponses !
Par contre, je n'ai pas les identifiants puisque chaque utilisateur mettra les siens, donc dans ces lignes je ne peux pas dire de chercher dans l'ini des informations qui seront variables.

Edit: Voila plus de précisions ^^'


L'utilisateur ouvre le programme pour la premiére fois, il remplit le premier ou les deux groupes si ils a plusieurs comptes.

Il appuie sur Sauver.
Le logiciel sauvegarde les ID et les mots de passe dans un .ini

Quand il entre sur le jeu, il appuie sur Entrer, et les identifiants de connexion se rentre et le connecte dans le jeu rapidement.
(pour ca il faut que le logiciel reste toujours au premier plan :S )

Deuxieme utilisation, il appuie sur charger, les identifiants du compte un et deux sont lu dans le ou les fichiers ini et remis dans les Inputs, il peux alors refaire comme la premiére fois.
Quand on le dit comme ca c'est facile.

[bloodwolff]

Une petite fonction que j'avais fais pour pouvoir augmenter diminuer le nombre de compte ainsi que le nombre d'éléments enregistré

J'y ai rajouté un exemple ainsi que des commentaires

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


$Form1 = GUICreate("Form1", 305, 98, 192, 124)
$ID_1 = GUICtrlCreateInput("Input1", 16, 16, 121, 21)
$MDP_1 = GUICtrlCreateInput("Input2", 16, 40, 121, 21)
$sauver_1 = GUICtrlCreateButton("Button1", 32, 64, 75, 25)
$ID_2 = GUICtrlCreateInput("Input3", 160, 16, 121, 21)
$MDP_2 = GUICtrlCreateInput("Input4", 160, 40, 121, 21)
$sauver_2 = GUICtrlCreateButton("Button2", 184, 64, 75, 25)
GUISetState(@SW_SHOW)


$nom_section = "Information de connection"
$Nom_ini = "Config.ini"
Dim $liste_input[2][2] = [ _ ;Le premier chiffre représente le nombre de compte et le deuxième le nombre d'élément par compte
["ID_1","MDP_1"], _
["ID_2","MDP_2"]] ;à remplacer par le nom des variable qui contiennent les handles
;ID_1 proviendrait donc de $ID_1 = GUICtrlCreateInput("Input1", 16, 16, 121, 21)
;Ne pas mettre le "$"

For $i=0 to UBound($liste_input)-1
    For $a=0 to UBound($liste_input,2)-1
        GUICtrlSetData(Eval($liste_input[$i][$a]), IniRead($Nom_ini, $nom_section,$liste_input[$i][$a],""))
    Next
Next ;à mettre avant la boucle

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $sauver_1 ; à remplacer par le handle du bouton
            _iniwrite(1) ;Le chiffre signifie le numero de compte
        Case $sauver_2
            _iniwrite(2)
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func _iniwrite($compte)
    For $i=0 to UBound($liste_input,2)-1
        IniWrite($Nom_ini,$nom_section,$liste_input[$compte-1][$i], GUICtrlRead(Eval($liste_input[$compte-1][$i])))
    Next
EndFunc