[R] Graphique cliquable dans GUI

[Rapace15]

Bonjour à tous,

Je cherche à faire une GUI avec des boutons personnalisés et là, le problème arrive.

Lorsque je dessine mon graphique, tout va bien, mais la zone cliquable n'est même pas la zone du graphique (ici en blanc).
Voici mon code

► Afficher le texteCliquez pour voir le code

Code : Tout sélectionner

#cs
Réalisation du Nid d'abeille...
#ce
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;#NoTrayIcon
Opt("GUIOnEventMode", 1)

$hMainGUI       = GUICreate("Nid d'abeille",750,450)
GUISetOnEvent($GUI_EVENT_CLOSE, "MenuEvents")

global $chx1 = GUICtrlCreateGraphic(5,5,50,100)
$bouton = grnid($chx1,0,75,25, 0x55ff00)
GUICtrlSetOnEvent(-1, "MenuEvents")
GUISetState()
While 1
    Sleep(10)   
WEnd
Exit

Func grnid($id_gr, $l, $t, $dl, $bk)
    #cs
    Défini une alvéole avec les paramètres
    $id_gr : Identifiant de l'alvéole
    $l : Position horizontale
    $t : position verticale
    $dl : le biais
    $bk : Couleur de fond
    #ce
    GUICtrlSetBkColor($id_gr, 0xffffff)
    GUICtrlSetGraphic($id_gr, $GUI_GR_COLOR, 0x00, $bk)
    GUICtrlSetGraphic($id_gr, $GUI_GR_MOVE, $l, $t)
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, $l, ($t-(2*$dl)))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+(1*$dl)), ($t-(3*$dl)))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+(2*$dl)), ($t-(2*$dl)))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+(2*$dl)), $t)
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+$dl), ($t+$dl))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, $l, $t)
    ;GUICtrlSetGraphic(-1, $GUI_GR_LINE, -10, 0)
EndFunc

Func MenuEvents()
    Local $Msg = @GUI_CtrlID
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $chx1
            MsgBox(0,"Click, Click", "Le graphique est cliqué")
    EndSwitch
EndFunc
 

Je souhaite n'avoir que ma zone de couleur qui soit cliquable. Est-ce possible ?

[Tlem]

Il me semble que pour cela, il vous faudra gérer la transparence.
En, l'état, votre image est composée d'un carré blanc dans lequel vous avez une forme verte. Donc l'image est l'ensemble du carré.
Si vous remplacez le blanc par la transparence et que vous gérez l'affichage de votre image correctement, vous ne verrez apparaitre que la forme verte et donc la zone à cliquer sera celle-ci.

Pour la gestion de la transparence, faite des recherches sur le forum, le sujet y a été abordé à plusieurs reprises.

[ZDS]

Bonjour!

Voici un exemple (j'en suis pas fan du tout :s) qui prend en compte le clic dans tout le rectangle, mais n'affiche la MsgBox que si le pixel sous la souris est de la couleur de l'alvéole. Je sais bien que c'est très moche mais pour le moment, je ne crois pas qu'AutoIt puisse gérer ce genre de chose.

► Afficher le texteAlvéole

Code : Tout sélectionner

#cs
Réalisation du Nid d'abeille...
#ce
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;#NoTrayIcon
Opt("GUIOnEventMode", 1)

$hMainGUI       = GUICreate("Nid d'abeille",750,450)
GUISetOnEvent($GUI_EVENT_CLOSE, "MenuEvents")

$chx1 = GUICtrlCreateGraphic(5,5,50,100)
$bouton = grnid($chx1,0,75,25, 0x55FF00)
GUICtrlSetOnEvent(-1, "MenuEvents")
GUISetState()
While 1
    Sleep(10)   
WEnd
Exit

Func grnid(ByRef $id_gr, $l, $t, $dl, $bk)
    #cs
    Défini une alvéole avec les paramètres
    $id_gr : Identifiant de l'alvéole
    $l : Position horizontale
    $t : position verticale
    $dl : le biais
    $bk : Couleur de fond
    #ce
    GUICtrlSetBkColor($id_gr, $GUI_BKCOLOR_TRANSPARENT)
    GUICtrlSetGraphic($id_gr, $GUI_GR_COLOR, 0x00, $bk)
    GUICtrlSetGraphic($id_gr, $GUI_GR_MOVE, $l, $t)
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, $l, ($t-(2*$dl)))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+(1*$dl)), ($t-(3*$dl)))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+(2*$dl)), ($t-(2*$dl)))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+(2*$dl)), $t)
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, ($l+$dl), ($t+$dl))
    GUICtrlSetGraphic($id_gr, $GUI_GR_LINE, $l, $t)
    ;GUICtrlSetGraphic(-1, $GUI_GR_LINE, -10, 0)
EndFunc

Func MenuEvents()
    Local $Msg = @GUI_CtrlID
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $chx1
            If Hex(PixelGetColor(MouseGetPos(0),MouseGetPos(1),$hMainGUI),6) = "55FF00" Then
                MsgBox(0,"Click, Click", "Le graphique est cliqué")
            EndIf
    EndSwitch
EndFunc

Une autre approche serait de faire un graphique cliquable, et de définir des zones par tableau dans le cas où il y aurait plusieurs alvéoles (je suppose qu'au final c'est à ça que ca servira, n'est-ce-pas? ^^). Parce que sinon, certains graphiques se chevaucheront, et l'un sera dominant sur l'autre. même si il est transparent, le composant reste cliquable, et celui qui est en dessous l'aura dans le voila .

Voici un script qui lui, gère l'endroit où le clic a été fait dans le graphique, et y associe le numéro de l'alvéole dans le tableau :

► Afficher le texteAlvéoles

Code : Tout sélectionner

#cs
Réalisation du Nid d'abeille...
#ce
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;#NoTrayIcon
Opt("GUIOnEventMode", 1)

; [x, y, l, h, b] : centre de l'alvéole en [x,y] de taille [l,h] et biseau de b dans les coins
Global $alveoles[14][5] = [ _
    [20,40,40,80,20], _
    [72,40,40,80,20], _
    [124,40,40,80,20], _
    [176,40,40,80,20], _
    [228,40,40,80,20], _
    [46,106,40,80,20], _
    [98,106,40,80,20], _
    [150,106,40,80,20], _
    [201,106,40,80,20], _
    [20,172,40,80,20], _
    [72,172,40,80,20], _
    [124,172,40,80,20], _
    [176,172,40,80,20], _
    [228,172,40,80,20]  _
]

$hMainGUI       = GUICreate("Nid d'abeille",750,450)
GUISetOnEvent($GUI_EVENT_CLOSE, "MenuEvents")

$chx1 = GUICtrlCreateGraphic(5,5,228+40/2,172+80/2)
GUICtrlSetBkColor($chx1, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetOnEvent($chx1, "MenuEvents")
For $i = 0 To UBound($alveoles)-1
    dessinerAlveole($chx1, $alveoles[$i][0],$alveoles[$i][1],$alveoles[$i][2],$alveoles[$i][3],$alveoles[$i][4], 0x55FF00)
Next

GUISetState()

While 1
    Sleep(10)   
WEnd

Exit

Func dessinerAlveole($graphic, $x,$y, $l,$h, $b, $couleur)
    GUICtrlSetGraphic($graphic, $GUI_GR_COLOR, 0x00, $couleur)
    GUICtrlSetGraphic($graphic, $GUI_GR_MOVE, $x-$l/2, $y-$h/2+$b)
    GUICtrlSetGraphic($graphic, $GUI_GR_LINE, $x-$l/2, $y+$h/2-$b)
    GUICtrlSetGraphic($graphic, $GUI_GR_LINE, $x, $y+$h/2)
    GUICtrlSetGraphic($graphic, $GUI_GR_LINE, $x+$l/2, $y+$h/2-$b)
    GUICtrlSetGraphic($graphic, $GUI_GR_LINE, $x+$l/2, $y-$h/2+$b)
    GUICtrlSetGraphic($graphic, $GUI_GR_LINE, $x, $y-$h/2)
    GUICtrlSetGraphic($graphic, $GUI_GR_MOVE, $x-$l/2, $y-$h/2+$b)
EndFunc

Func MenuEvents()
    Local $Msg = @GUI_CtrlID
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $chx1
            Local $opt = Opt("MouseCoordMode")
            Opt("MouseCoordMode",2)
            Local $mouseCoord = MouseGetPos()
            Opt("MouseCoordMode",$opt)
            Local $graphicCoord = ControlGetPos($hMainGUI,"",$chx1)
            For $i = 0 To UBound($alveoles)-1
                If _
                    Abs($mouseCoord[0]-($alveoles[$i][0]+$graphicCoord[0]))<$alveoles[$i][2]/2 And _
                    Abs($mouseCoord[1]-($alveoles[$i][1]+$graphicCoord[1]))<$alveoles[$i][3]/2 And _
                    Abs($mouseCoord[0]-($alveoles[$i][0]+$graphicCoord[0]))+Abs($mouseCoord[1]-($alveoles[$i][1]+$graphicCoord[1]))<$alveoles[$i][2]/2+$alveoles[$i][3]/2-$alveoles[$i][4] Then
                    MsgBox(0,"Click, Click", "Le graphique est cliqué, alvéole n°"&$i)
                EndIf
            Next
    EndSwitch
EndFunc

A bientôt !

[Rapace15]

C'est exactement ce qu'il ma faudrait...

Pour l'instant, je suis tellement pris pas mon boulot que je ne trouve pas le temps de me pencher dessus, mais c'est bien le principe...

Je déchiffrerai ces codes plus tard.

Merci encore