[R] Copie de fichier et contrôle de progression

[Gnifrus]

Bonjour,

Je cherche en vain depuis quelques jours, un moyen de recopier un fichier sur un site distant, et de contrôler la progression de la copie.
Je m'explique, j'ai un fichier de 100 Mo environ.

Je le recopie au moyen de la syntaxe :
FileCopy("C:\temp\fichier","\\192.168.0.170\echange\",1)

Comme le fichier à recopier est assez gros, Autoit "tourne" un bon moment le temps de tout recopier.
En plus, dès la première seconde, la taille du fichier, sur le site distant indique 100 Mo, alors que ce dernier n'est pas encore recopié en totalité !

Je souhaiterai contrôler la taille du fichier déjà recopié, afin de faire patienter l'utilisateur, de 0 Mo à 100 Mo, comme la fenêtre de windows sait le faire.

Je ne cherche pas une barre de progression ou une solution clé en main, mais juste une piste...

Merci à vous tous pour votre aide, j'espère...
@ bientôt,

Gnifrus.

[Yogui]

J'utilise cette fonction récupérer sur le forum Anglophone pour les copies avec progress barre :

A adapter suivant vos besoins (sachant que le changement de couleur pour un seul fichier ne sert à rien)

► Afficher le texte

Code : Tout sélectionner

ProgressCopy("C:\temp\fichier","\\192.168.0.170\echange\",0)

Func ProgressCopy($current, $destination, $UseMultiColour = 0, $attrib = "-R", $overwrite = 1, $Run1 = 0)

    If $Run1 = 0 Then
        Global $OverallQty, $Overall, $source, $overallpercent, $Progress0Text, $progressbar1, $Progress1Text, $progressbar2, $Progress2Text, $LocalPercent
        DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
        If Not FileExists($destination) Then DirCreate($destination); This is why it was failing, the dir did not exist
        $source = $current
        If StringRight($current, 1) = '' Then $current = StringTrimRight($current, 1)
        If StringRight($destination, 1) <> '' Then $destination = $destination & "\"
        $tosearch = $current
        $Overall = DirGetSize($tosearch, 1)
        $OverallQty = $Overall[1]
        Global $PrCopyGui = GUICreate("Copie des Fichiers", 420, 100, -1, -1, -1, $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)
        $Progress0Text = GUICtrlCreateLabel("Veuillez patienter", 10, 5, 400, 20, $SS_LEFTNOWORDWRAP)
        $progressbar1 = GUICtrlCreateProgress(10, 20, 400, 20)
        GUICtrlSetColor(-1, 32250)
        $Progress1Text = GUICtrlCreateLabel("", 10, 44, 400, 20, $SS_LEFTNOWORDWRAP)
        $progressbar2 = GUICtrlCreateProgress(10, 60, 400, 20, $PBS_SMOOTH)
        $Progress2Text = GUICtrlCreateLabel("", 10, 82, 400, 20, $SS_LEFTNOWORDWRAP)
        GUISetFont(10, 600)

        GUICtrlSetColor(-1, 32250); not working with Windows XP Style if not using windows classic style or dllcall above
        GUISetState(@SW_SHOW)
        GUICtrlSetData($Progress1Text, "Répertoire de travail " & $tosearch)
        $Run1 = 1
    EndIf

    $Size = DirGetSize($current, 3)
    $Qty = $Size[1]
    Local $search = FileFindFirstFile($current & "\*.*")
    While 1
        Dim $file = FileFindNextFile($search)
        If @error Or StringLen($file) < 1 Then ExitLoop
        If Not StringInStr(FileGetAttrib($current & "\" & $file), "D") And ($file <> "." Or $file <> "..") Then
            $Qty -= 1
            $LocalPercent = 100 - (($Qty / $Size[1]) * 100)
            $OverallQty -= 1
            $overallpercent = 100 - (($OverallQty / $Overall[1]) * 100)
            GUICtrlSetData($Progress0Text, "Progression Totale " & Int($overallpercent) & "% Completer")
            GUICtrlSetData($progressbar1, $overallpercent)
            GUICtrlSetData($progressbar2, $LocalPercent)
            GUICtrlSetData($Progress2Text, "Copie du Fichier " & $file)

            If $UseMultiColour Then
                GUICtrlSetColor($progressbar2, _ChangeColour($LocalPercent))
                GUICtrlSetColor($progressbar1, _ChangeColour($overallpercent))
            EndIf

            FileCopy($current & "\" & $file, $destination & StringTrimLeft($current, StringLen($source)) & "\" & $file, $overwrite)
            FileSetAttrib($destination & StringTrimLeft($current, StringLen($source)) & "\" & $file, $attrib)
        EndIf
        If StringInStr(FileGetAttrib($current & "\" & $file), "D") And ($file <> "." Or $file <> "..") Then
            DirCreate($destination & StringTrimLeft($current, StringLen($source)) & "\" & $file)
            FileSetAttrib($destination & StringTrimLeft($current, StringLen($source)) & "\" & $file, $attrib)
            GUICtrlSetData($Progress1Text, $current & "\" & $file)
            ProgressCopy($current & "\" & $file, $destination, $UseMultiColour, $attrib, $overwrite, 1)
        EndIf
    WEnd
    FileClose($search)
    ;when overall percent = 100 set end gui text, delete gui and reset run1 to 0
    If $overallpercent = 100 Then
        GUICtrlSetData($Progress0Text, "Progression Totale complètée à 100%")
        GUICtrlSetData($progressbar1, 100)
        GUICtrlSetData($progressbar2, 100)
        GUICtrlSetData($Progress2Text, "Terminer !")
        
        Sleep(1000)
        GUIDelete($PrCopyGui)
        $Run1 = 0
    EndIf
EndFunc   ;==>ProgressCopy

Func _ChangeColour($start)

    $Redness = Int(255 - ($start / 100 * 512))
    If $Redness < 0 Then $Redness = 0

    $Greeness = Int(($start / 100 * 512) - 257)
    If $Greeness < 0 Then $Greeness = 0

    $Blueness = Int(255 - ($Redness + $Greeness))

    Return ($Redness * 256 * 256) + ($Greeness * 256) + $Blueness

EndFunc   ;==>_ChangeColour

[Gnifrus]

Merci Yogui pour ton aide, mais lorsque j'essaie, après un copier-coller, d'exécuter le fichier, autoit me détecte les erreurs ci-dessous :

C:\Documents and Settings\***\Bureau\Essai.au3 (14) : ==> Subscript used with non-Array variable.:
$OverallQty = $Overall[1]
$OverallQty = $Overall^ ERROR

Je précise avoir dû déclarer les variables : $WS_EX_TOOLWINDOW,$WS_EX_TOPMOST,$SS_LEFTNOWORDWRAP,$PBS_SMOOTH

Je ne pige pas ?

Merci encore !

Gnifrus.

[Yogui]

Je ai pas mis les includes dans le menu outils vous trouverez un outils pour vérifier les includes sinon les voilà (je ne pense pas en oublier :

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <ProgressConstants.au3>
 

[Yogui]

Sinon après une recherche rapide vous auriez trouver plusieurs fois ce sujet :

http://www.autoitscript.fr/forum/viewto ... 77&p=26566

[Gnifrus]

J'ai vérifié les includes avec l'outil dont tu m'as parlé, il n'y a plus d'oubli à ce niveau.
Par contre, j'ai toujours le message d'erreur :
C:\Documents and Settings\*****\Bureau\Essai.au3 (20) : ==> Subscript used with non-Array variable.:
$OverallQty = $Overall[1]
$OverallQty = $Overall^ ERROR

Je ne comprends pas le message ?

Merci encore...et désolé....

Gnifrus

[Yogui]

Pouvez vous tester ce code :

Code : Tout sélectionner

$Overall = DirGetSize(@DesktopDir, 1)
MsgBox(0,"",$Overall[1])

Qui va compter les fichiers sur votre bureau

si ça ne fonctionne pas vérifier votre version d'autoit si ça fonctionne alors je ne comprend pas ...

[Yogui]

sinon remplacer cette ligne :

Code : Tout sélectionner

Global $OverallQty, $Overall, $source, $overallpercent, $Progress0Text, $progressbar1, $Progress1Text, $progressbar2, $Progress2Text, $LocalPercent

Par celle-ci

Code : Tout sélectionner

Global $OverallQty, $source, $overallpercent, $Progress0Text, $progressbar1, $Progress1Text, $progressbar2, $Progress2Text, $LocalPercent

[Gnifrus]

Bouhhhhh.....le boulet !!!

J'ai enfin trouvé pourquoi ça ne marchait pas !
En fait, j'indiquais un fichier à copier, alors qu'il fallait copier le contenu d'un dossier !!!

Par contre, c'est pas tout à fait ce que je cherchais à faire.

Je voulais avoir une progression au fur et à mesure que la copie du fichier se faisait...

Mais bon, à défaut, si personne n'a de soluce, je me contenterai (ce qui n'est déjà pas si mal) de ce script...

En tout cas, je vous remercie beaucoup pour votre aide !

Bonne continuation !

Gnifrus.

[Yogui]

Sinon puisque vous voulez du comme windows on peux aussi uitiliser windows ...

► Afficher le texte

Code : Tout sélectionner

_FileCopyEx("C:\temp\fichier", "\\192.168.0.170\echange\")
Func _FileCopyEx($s_File, $s_newFile)

    Local $SHFILEOPSTRUCT = DllStructCreate("hwnd hwnd;uint wFunc;ptr pFrom;ptr pTo;int fFlags;int fAnyOperationsAborted;hwnd hNameMappings;ptr lpszProgressTitle")

    Local $SHFILEOPSTRUCT_From = DllStructCreate("char pFrom[" & StringLen($s_File) + 2 & "]")
    DllStructSetData($SHFILEOPSTRUCT_From, "pFrom", $s_File)
    Local $SHFILEOPSTRUCT_To = DllStructCreate("char pTo[" & StringLen($s_newFile) + 2 & "]")
    DllStructSetData($SHFILEOPSTRUCT_To, "pTo", $s_newFile)

    DllStructSetData($SHFILEOPSTRUCT, "wFunc", 2)
    DllStructSetData($SHFILEOPSTRUCT, "pFrom", DllStructGetPtr($SHFILEOPSTRUCT_From))
    DllStructSetData($SHFILEOPSTRUCT, "pTo", DllStructGetPtr($SHFILEOPSTRUCT_To))
    DllStructSetData($SHFILEOPSTRUCT, "fFlags", 16)

    Local $i_State = DllCall("shell32.dll", "int", "SHFileOperation", "ptr", DllStructGetPtr($SHFILEOPSTRUCT))

    $SHFILEOPSTRUCT = 0

    If Not $i_State[0] Then
        SetError(1)
        Return 0
    EndIf

    SetError(0)
    Return 1

EndFunc   ;==>_FileCopyEx