[R] Aide sur la traduction d'une boucle

[lerin57]

Bonjour à tous.

Je travaille actuellement sur un projet de conception de mails préformaté dans outlook.

Dans le cadre de ce projet, Ayuckers (membre du forum), m'a véritablement mâché le travail en me fournissant un exemple (que je trouve génial):

► Afficher le texte

Code : Tout sélectionner

#include <Constants.au3>
#include <String.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Global $MonModel = ""

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 332, 152)
$Label1 = GUICtrlCreateLabel("Nom", 16, 8, 26, 17)
$Label2 = GUICtrlCreateLabel("Prenom", 16, 32, 40, 17)
$Label3 = GUICtrlCreateLabel("Produit", 16, 56, 37, 17)
$Label4 = GUICtrlCreateLabel("Commande", 16, 80, 57, 17)

$InputNom = GUICtrlCreateInput("CHIWAWA", 112, 8, 153, 21)
$InputPrenom = GUICtrlCreateInput("Henri", 112, 32, 153, 21)
$InputProduit = GUICtrlCreateInput("Ordinateur", 112, 56, 153, 21)
$InputCommande = GUICtrlCreateInput("0023AZ45567VV", 112, 80, 153, 21)
$ButtonMail = GUICtrlCreateButton("Generer Mail", 104, 112, 129, 33, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $ButtonMail

            IniWrite ( @ScriptDir & "\Data.ini", "DATA", "@Nom@", GUICtrlRead($InputNom) )
            IniWrite ( @ScriptDir & "\Data.ini", "DATA", "@Prenom@", GUICtrlRead($InputPrenom) )
            IniWrite ( @ScriptDir & "\Data.ini", "DATA", "@Produit@", GUICtrlRead($InputProduit) )
            IniWrite ( @ScriptDir & "\Data.ini", "DATA", "@RefCommande@", GUICtrlRead($InputCommande) )

            Global $Tags = IniReadSection(@ScriptDir & "\Data.ini", "DATA")

            _CreateMail("Toto", "moi", "mail de test", "testcommande.html","",0,@ScriptDir & "\")

    EndSwitch
WEnd

Func _CreateMail($From, $To, $Subject, $Model, $sAttachments = "", $AutoSend = 0, $ModelDirectory = "C:\")

    ; ********* constantes de modèle objet Outlook **************
    Local $asAttachments
    Local $olMailItem = 0
    Local $olFormatHTML = 1
    local $i

    ; Lecture du model celui ci est placé dans une variable
    $MonModel = _ReadModel($Model,$ModelDirectory)


    ;*********************************************************************************
    ; ici Faire une fonction qui va remplacer les tags dans $MonModel
    ; avec la fonction StringReplace
        For $i = 1 To $Tags[0][0]
            $MonModel = StringReplace($MonModel, $Tags[$i][0], $Tags[$i][1])
        Next
    ;*********************************************************************************
    $oOApp = ObjCreate("Outlook.Application")
    $oOMail = $oOApp.CreateItem($olMailItem)

    With $oOMail

        .SentOnBehalfOfName = ($From) ; Envoyé en tant que...
        .To =($To) ; destinataire
        .Subject = $Subject ; Sujet du mail
        .BodyFormat = $olFormatHTML ; format HTML
        ;.Importance = $olImportanceHigh
        ;.Body = "email message"
        .HTMLBody = $MonModel ; model en HTML

        If $sAttachments <> "" Then
            $asAttachments = StringSplit($sAttachments, ";")
            For $iNumOfAttachments = 1 To $asAttachments[0]
                .Attachments.Add($asAttachments[$iNumOfAttachments]) ; pour Attacher un ou plusieur fichier
            Next
        EndIf

        .Display ; Affichage du mail

        If $AutoSend = 1 Then
            .Send
        EndIf

    EndWith

EndFunc   ;==>_CreateMail

Func _ReadModel($ModelMail,$ModelDirectory)

    $file = FileOpen($ModelDirectory & $ModelMail, 0)
    ; Verifie si le fichier a bien ete ouvert avant de le lire
    If $file = -1 Then
        MsgBox(0, "Erreur", "Impossible d'ouvrire le fichier.")
        Exit  ; Dans certain cas sortir brusquemment du programme peut etre problematique.
    Else
        Return FileRead($file) ; on copie le contenu du fichier dans une variable
    EndIf

EndFunc   ;==>_ReadModel
 

Je précise d'abord les points suivants :
testcommande.html est un exemple créé via kompozer, contenant les valeurs cibles @Nom@, @Prenom@, @Produit@ et @RefCommande@
Les memes valeurs sont renseignée dans un fichier *.ini.

Voici Mon probleme : j'ai bien assimilé les fonction de lecture et le principe de renseignement du fichier *.ini.
Toutefois, j'aurais besoin d'explication concernant la boucle suivante :
For $i = 1 To $Tags[0][0]
$MonModel = StringReplace($MonModel, $Tags[$i][0], $Tags[$i][1])
Next

En fait j'aimerais comprendre la signification de la syntaxe $Tags[0][0], $Tags[$i][0], et $Tags[$i][1].

Par cette requète, je précise que j'ai déja parcourue les tutos et l'aide de autoit, et que j'ai bien compris le principe de la boucle.
Je désire juste appréhender ce concept de manière un peu plus claire.

[Tlem]

$Tags[0][0] est un tableau à deux dimensions.
Ce qui est entre crochet représente 'les coordonnées' dans le tableau de la valeur que l'on souhaite atteindre.

Donc $Tags[0][0] signifie que l'on utilise la valeur qui ce trouve colonne 0 et ligne 0 et en l'occurrence, cette 'case' contient le nombre d'élément (de ligne) du tableau (Attention ceci n'est pas toujours vrai, cela dépend des cas ).

Donc dans le code que vous présentez, le principe de la boucle et de partir de la ligne 1 (For $i = 1) jusqu'à la dernière ligne du tableau ($Tags[0][0]).

Ensuite, avec la ligne $MonModel = StringReplace($MonModel, $Tags[$i][0], $Tags[$i][1]) on remplace dans la chaine $MonModel la chaine qui ce trouve dans la valeur $Tags[$i][0] (ligne $i colonne 0) par la chaine qui ce trouve dans la valeur $Tags[$i][1] (ligne $i colonne 1) et on met tout ce petit monde dans la variable $MonModel.

Voilà, j'espère que les choses sont un peut plus claire maintenant.

[lerin57]

Merci pour cette explication, c'est effectivement beaucoup plus clair.

J'arrive au bout de mon projet.

J'ai un autre post que je vais pouvoir mettre en résolu.

Merci en core pour ton aide.

(ps : je n'avais pas pensé à l'explication du tableau, je vais la garder dans un coin pour les prochaines fois ... )