Aide et conseils concernant AutoIt et ses outils.
AsHardstyle
Niveau 1
Messages : 14 Enregistré le : sam. 30 mai 2009 05:47
Status :
Hors ligne
#1
Message
par AsHardstyle dim. 01 nov. 2009 13:59
Salut à tous,
Oui voila donc je vous explique mon probleme, j'ai créer un Guictrlcreateedit qui lui affiche le texte d'un fichier où celui ci recoit du texte en permanence, et je voudrai que mon Guictrlcreateedit soit mis à jour lui aussi en permanence et qu'il affiche la mis jour par le bas.
Je m'explique, disons que je rentre du texte dans le fichier et donc se que je viens d'entrer s'affiche dans mon Guictrlcreateedit.
Voila voila, si vous avez un exemple de script je suis preneur.
As_Hardstyle
Modifié en dernier par
AsHardstyle le lun. 02 nov. 2009 20:35, modifié 2 fois.
jbnh
Niveau 11
Messages : 1932 Enregistré le : ven. 02 mai 2008 14:54Localisation : Bruxelles
Status :
Hors ligne
#2
Message
par jbnh dim. 01 nov. 2009 16:27
Bonjour,
http://www.autoitscript.com/autoit3/doc ... etData.htm
Attention a votre titre : c'est [..] pas [...] , merci d'éditer
Balise [..] devant votre requête en cours, [R] quand résolu | Pas de message concernant les bots ! Merci
AsHardstyle
Niveau 1
Messages : 14 Enregistré le : sam. 30 mai 2009 05:47
Status :
Hors ligne
#3
Message
par AsHardstyle dim. 01 nov. 2009 16:39
Merci, pour votre réponse, il affiche bien le texte à la suite mais le souci c'est qu'à chaque mis à jour la page remonte donc le texte entré n'est pas au premier plan si vous voyez se que je veux dire.
jbnh
Niveau 11
Messages : 1932 Enregistré le : ven. 02 mai 2008 14:54Localisation : Bruxelles
Status :
Hors ligne
#4
Message
par jbnh dim. 01 nov. 2009 18:04
Code : Tout sélectionner
$edit = guictrlcreateedit (....)
......
guictrlsetdata ($edit, $newline & @CRLF & GUICtrlRead($edit))
Ainsi, la newline est en haut de l'édit et non en bas.
Cela répond-il à votre Q
Balise [..] devant votre requête en cours, [R] quand résolu | Pas de message concernant les bots ! Merci
AsHardstyle
Niveau 1
Messages : 14 Enregistré le : sam. 30 mai 2009 05:47
Status :
Hors ligne
#5
Message
par AsHardstyle dim. 01 nov. 2009 22:10
Euh non pas trop, je vais essayé de mieux m'expliquer donc voici un exemple :
► Afficher le texte
Code : Tout sélectionner
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$NomFenetre = "KBSG v1.0 by As_Hardstyle"
$Fenetre = GuiCreate($NomFenetre, 620, 450)
$Edit = GuiCtrlCreateEdit("", 8, 64, 569, 321)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000044)
$open = FileOpen(@scriptdir & "\Test.txt",0)
$read = FileRead($open)
FileClose($open)
guictrlsetdata ($edit, $read)
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
Et voici le .txt qui recoit en permanence tu texte.
► Afficher le texte
[Name]
Et donc le texte s'ajoute apres la derniere ligne se qui est normal, et je voudrai que dans l'Edit de la GUI le texte s'affiche comme si :
orax
Modérateur
Messages : 1479 Enregistré le : lun. 23 mars 2009 04:50Localisation : ::1
Status :
Hors ligne
#6
Message
par orax dim. 01 nov. 2009 22:37
Si j'ai bien compris il faut que l'ascenseur se trouve en bas ?
Code : Tout sélectionner
#Include <GuiEdit.au3>
...
GUISetState(@SW_SHOW)
_GUICtrlEdit_AppendText(GUICtrlGetHandle($edit),$read) ; à placer après guisetstate()De petits détails peuvent faire toute la différence. — Quand la boule de neige commence à rouler… poussez-la. (Columbo)
AsHardstyle
Niveau 1
Messages : 14 Enregistré le : sam. 30 mai 2009 05:47
Status :
Hors ligne
#7
Message
par AsHardstyle dim. 01 nov. 2009 23:02
Merci pour ta réponse,
oui c'est sa mais je voudrai que le l'edit soit mis à jour en permanence, c'est à dire que si il y a du texte d'ajouté dans le .txt, ca s'affiche dans l'edit aussi.
Et je ne sais pourquoi avec votre commande il ne m'affiche pas tout le contenu du .txt.
AsHardstyle
Niveau 1
Messages : 14 Enregistré le : sam. 30 mai 2009 05:47
Status :
Hors ligne
#8
Message
par AsHardstyle lun. 02 nov. 2009 14:59
Bon apres plusieurs essais je n'y suis toujours pas arrivé.
orax
Modérateur
Messages : 1479 Enregistré le : lun. 23 mars 2009 04:50Localisation : ::1
Status :
Hors ligne
#9
Message
par orax lun. 02 nov. 2009 19:18
Essayez ça alors. Ca Met à jour l'Edit dès que le fichier est modifié.
► Afficher le texte
Code : Tout sélectionner
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiEdit.au3>
#include <ScrollBarConstants.au3>
Global Const $FICHIER = @ScriptDir & "\Test.txt"
Global Const $NomFenetre = "KBSG v1.0 by As_Hardstyle"
Global Const $Fenetre = GUICreate($NomFenetre, 620, 450)
Global Const $Edit = GUICtrlCreateEdit("", 8, 64, 569, 321)
Global Const $hEdit = GUICtrlGetHandle($Edit)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000044)
GUISetState(@SW_SHOW)
_GUICtrlEdit_SetLimitText($hEdit, -1)
_GUICtrlEdit_AppendText($hEdit, FileRead($FICHIER))
; récupère l'heure de la dernière modification sur le fichier
Global $derniereModif = FileGetTime($FICHIER, 0, 1)
Global $modif
While 1
$msg = GUIGetMsg()
; si le fichier a été modifié
$modif = FileGetTime($FICHIER, 0, 1)
If $modif > $derniereModif Then
; met à jour complement l'Edit
;~ _GUICtrlEdit_SetText($hEdit, "")
;~ _GUICtrlEdit_AppendText($hEdit, FileRead($FICHIER))
; ou
; ne met à jour que le texte ajouté dans le fichier
_GUICtrlEdit_AppendText($hEdit, StringTrimLeft(FileRead($FICHIER), _GUICtrlEdit_GetTextLen($hEdit)))
$derniereModif = $modif
EndIf
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
Modifié en dernier par
orax le mar. 03 nov. 2009 19:51, modifié 3 fois.
De petits détails peuvent faire toute la différence. — Quand la boule de neige commence à rouler… poussez-la. (Columbo)
AsHardstyle
Niveau 1
Messages : 14 Enregistré le : sam. 30 mai 2009 05:47
Status :
Hors ligne
#10
Message
par AsHardstyle lun. 02 nov. 2009 20:35
Merci !!!
Grace a toi j'ai pu trouver mon bonheur, cela fonctionne parfaitement.
Encore merci.
