ObjCreate("WMPlayer.OCX.7") playlist ?

Aide et conseils concernant AutoIt et ses outils.
Règles du forum
.
Répondre
Mickdu59
Niveau 2
Niveau 2
Messages : 27
Enregistré le : ven. 06 déc. 2019 06:56
Status : Hors ligne

ObjCreate("WMPlayer.OCX.7") playlist ?

#1

Message par Mickdu59 »

Coucou :lol:
je reviens encore une fois vers vous car je voudrais savoir si avec WMPLAYER.OCX

je peux lire plusieurs fichiers en playlist ?
je me sert de ça mais c est piste par piste
With $oRP; Object tag pool
    .fullScreen = True
    .windowlessVideo = True
    .stretchToFit = True
    .URL = $url
    .enableContextMenu = True
    .enabled = True
    .Controls.currentPosition = 0; move to location in movie
;~  .Controls.Play / pause and Stop
    .uiMode = "Full"; none / mini full
    .settings.autostart = True
    .settings.mute = False
    .settings.volume = 100; 0 - 100
    .settings.Balance = 0; -100 to 100
   .Controls.duration
EndWith
Avatar du membre
walkson
Modérateur
Modérateur
Messages : 1020
Enregistré le : ven. 12 août 2011 19:49
Localisation : Hurepoix
Status : Hors ligne

Re: ObjCreate("WMPlayer.OCX.7") playlist ?

#2

Message par walkson »

Bonjour,
ça serait sympa de mettre du code complet !...
Pour lire une playlist avec possibilité d'avancer ou de reculer dans la lecture
HotKeySet("a","suivant")
HotKeySet("z","precedent")
$wmp = ObjCreate("wmplayer.OCX")

$wmp.settings.autoStart = True
$wmp.settings.volume = 50
$wmp.URL = @UserProfileDir & "\Music\ListMusique.m3u"
ConsoleWrite("Nom de la playliste " & $wmp.currentPlaylist.Name & @CR)
ConsoleWrite("Nombre de morceaux " & $wmp.currentPlaylist.count & @CR)
Sleep(1000)
For $i = 0 To $wmp.currentMedia.attributeCount - 1
   ConsoleWrite($wmp.currentMedia.getAttributeName($i) & " : " & $wmp.currentMedia.getItemInfo($wmp.currentMedia.getAttributeName($i)) & @CR)
Next
Global $nbItem = $wmp.currentPlaylist.count

PauseAndResume()

While $wmp.Playstate <> 1
    Sleep(100)
WEnd

Func PauseAndResume()
    Sleep(20000)
    $wmp.controls.pause()
    ConsoleWrite("Paused" & @CRLF)
    Sleep(5000)
    $wmp.controls.play()
    ConsoleWrite("Playing" & @CRLF)
    Sleep(5000)
    $wmp.controls.stop()
    ConsoleWrite("Stopped" & @CRLF)
EndFunc
Func suivant()
   $wmp.Controls.Next
   $Cible = $wmp.Controls.currentItem.Name
   If $Cible = "ListMusique" Then $wmp.Controls.playItem($wmp.currentPlaylist.Item(0));si $cible est le nom de la playliste "ListMusique", on revient à l'item 0
   $Cible = $wmp.Controls.currentItem.Name
   For $i = 0 To $nbItem - 1
      If $Cible = $wmp.currentPlaylist.item($i).Name Then ExitLoop
   Next
   ConsoleWrite($wmp.currentPlaylist.item($i).Name &" >> "& $i + 1 &"/"& $nbItem & @CR)
EndFunc
Func precedent()
   $wmp.Controls.Previous
   $Cible = $wmp.Controls.currentItem.Name
   For $i = 0 To $nbItem - 1
      If $Cible = $wmp.currentPlaylist.item($i).Name Then ExitLoop
   Next
   ConsoleWrite($wmp.currentMedia.getItemInfo("title") &" >> "& $i + 1 &"/"& $nbItem & @CR)
EndFunc


Plus d'info à https://silkyroad.developpez.com/VBA/Wi ... diaPlayer/ C'est en VBA mais c'est facilement convertible en Autoit
Cordialement,
Walkson
"Horas non numero nisi serenas " Le canon de midi
(Je ne compte que les heures heureuses)
Répondre