AutoIt Français

jchd a écrit : ↑mer. 12 juin 2019 22:33 Dans SciTeUser.properties pour passer la console intégrée en UTF8, mettre :

Code : Tout sélectionner

code.page=65001
output.code.page=65001

Pour afficher de l'UTF8 depuis du code AutoIt lancé via Scite, utiliser ceci :

Code : Tout sélectionner

Global $CW = @Compiled ? __ConsoleWrite : _ConsoleWrite

Func __ConsoleWrite(ByRef $s)
	Local Static $hCon = __ConsoleInit()
	DllCall("kernel32.dll", "bool", "WriteConsoleW", "handle", $hCon, "wstr", $s & @LF, "dword", StringLen($s) + 1, "dword*", 0, "ptr", 0)
	Return
EndFunc

Func __ConsoleInit()
	DllCall("kernel32.dll", "bool", "AllocConsole")
	Return DllCall("kernel32.dll", "handle", "GetStdHandle", "int", -11)[0]
EndFunc

; Unicode-aware ConsoleWrite
Func _ConsoleWrite($s)
	ConsoleWrite(BinaryToString(StringToBinary($s & @LF, 4), 1))
EndFunc   ;==>_ConsoleWrite

et utiliser cette fonction au lieu de ConsoleWrite :

Code : Tout sélectionner

$CW("Καλησπέρα στο σπίτι!")

L'intérêt de la redirection via une variable est que ça fonctionne en CUI ou GUI, depuis Scite ou compilé.